Eingesperrt!
Out-Break ist ein Grafik-Adventure, bei dem Sie sich aus einem Haus ins Freie retten müssen. Doch das ist nicht so einfach, denn es müssen Bomben entschärft, Spinnen vernichtet und Abgründe überwunden werden.
Im Laufe des Spiels werden Sie feststellen, daß dies nicht die einzigen Hindernisse sind. In das Programm ist ein kleines Videospiel eingebaut und es gibt drei Schwierigkeitsstufen. Bei jedem neuen Start entstehen andere Variationen des Spiels. »OUT-BREAK« ist ein Spiel für den VC 20 mit 16 KByte RAM-Erweiterung.
Hier einige Hilfen zur Lösung des Spiels:
Spinnen können den Schaum von Feuerlöschern nicht vertragen, man sollte es hier mit den Tasten B, N und SHIFT probieren. In blauen Räumen verliert man leicht die Orientierung. Verschlossene Türen lassen sich nur mit einem Schlüssel öffnen. Schier unüberwindliche Abgründe lassen sich mit einer Leiter überwinden. Manchmal findet man auf weggeworfenen Zetteln brauchbare Informationen.
Um im Dunkeln zu sehen, muß man eine Lampe anmachen. Bei Schwierigkeitsgrad 2 und 3 kann die Tür in die Freiheit nur mit einem Spezialschlüssel aus einem Tresor geöffnet werden. Die Freiheit lockt hinter der grünen Tür.
Das Programm besteht aus zwei Teilen. Der erste Teil (Listing 1) ist ein Basic-Lader, der die Daten für den undefinierten Zeichensatz in den Speicher schreibt. Dieser Teil muß immer als erstes geladen und gestartet werden. Vorsicht! Durch den NEW-Befehl in Zeile 140 löscht sich dieser Teil von selbst, nachdem er seine Aufgabe verrichtet hat. Jetzt muß der zweite Teil (Listing 2), das eigentliche Programm, geladen und gestartet werden. Es versteht sich wohl von selbst, daß beide Teile vor dem Ausprobieren sicherheitshalber erst auf Kassette oder Disk gespeichert werden sollten.
(Gudrun Disser/ev)| 160 | = | Rücksetzen aller Variablen und Umschalten in Normalmodus |
| 170 - 220 | = | Festlegen der Konstanten |
| 230 - 300 | = | Anfangsbild |
| 310 - 410 | = | Auswahl des Schwierigkeitsgrades und Starten der Zeit |
| 420 - 840 | = | Festlegen der Stringvariablen |
| 900 - 1010 | = | Starten der Stoppuhr, wenn Tresor oder Bombe gefunden wurden. |
| 1020 - 1380 | = | Abfrage und Auswertung, welcher Befehl eingegeben wurde |
| 1390 - 2420 | = | Auswahl und Definition der Räume |
| 2430 - 3000 | = | Anweisung bei falscher Eingabe oder Spielhinweise |
| 3010 - 3070 | = | Anzeigen der Stoppuhr |
| 3080 - 3230 | = | Schlußbild |
| 3240 - 3740 | = | Spinnenspiel |
| 3750 - 4040 | = | Spielende und Erklärung, warum verloren wurde |
| 4050 - 4480 | = | Definition, welcher Gegenstand sich in welchem Raum befindet. |
100 rem *** out-break teil 1 ***
110 print"{clr}{down}{down}{down}{down}{down}{down}{down}{down}{down} copyright by {down} gudrun disser"
120 fori=7168to7168+391:reada:pokei,a:next
130 print"{clr}{red}{down}{down}{down}{down}{down} laden sie jetzt {down} out-break 2"
140 poke44,30:poke7680,0:new
150 data 0, 0, 0, 0, 0, 0, 0, 0
160 data 1, 1, 3, 7, 15, 15, 63, 63
170 data 0, 192, 192, 224, 240, 240, 252, 252
180 data 63, 63, 63, 63, 31, 15, 7, 7
190 data 252, 252, 252, 252, 248, 240, 224, 224
200 data 3, 4, 8, 48, 64, 128, 128, 128
210 data 0, 96, 156, 14, 252, 12, 30, 63
220 data 51, 55, 51, 55, 55, 63, 63, 55
230 data 55, 55, 55, 51, 63, 63, 63, 33
240 data 0, 0, 0, 0, 0, 0, 0, 12
250 data 0, 0, 0, 0, 0, 48, 112, 240
260 data 255, 139, 219, 217, 255, 0, 0, 0
270 data 240, 240, 240, 240, 240, 112, 48, 0
280 data 255, 255, 255, 255, 255, 126, 48, 0
290 data 255, 255, 243, 161, 0, 0, 0, 0
300 data 255, 255, 255, 255, 98, 0, 0, 0
310 data 3, 3, 3, 15, 31, 23, 103, 157
320 data 192, 192, 192, 240, 248, 252, 215, 77
330 data 3, 3, 3, 3, 3, 3, 3, 3
340 data 192, 192, 192, 192, 192, 192, 192, 192
350 data 101, 63, 53, 85, 93, 43, 51, 17
360 data 4, 15, 18, 28, 63, 55, 77, 95
370 data 240, 40, 124, 204, 214, 250, 86, 124
380 data 164, 246, 188, 208, 152, 232, 144, 144
390 data 165, 218, 151, 109, 89, 146, 75, 181
400 data 255, 254, 252, 252, 248, 200, 192, 128
410 data 255, 127, 127, 63, 63, 23, 3, 1
420 data 1, 2, 2, 12, 48, 64, 128, 128
430 data 255, 199, 215, 199, 239, 231, 239, 231
440 data 0, 0, 0, 124, 131, 0, 0, 0
450 data 0, 0, 0, 0, 195, 60, 0, 0
460 data 0, 0, 0, 0, 255, 0, 0, 0
470 data 0, 0, 0, 0, 0, 0, 0, 0
480 data 255, 255, 255, 255, 255, 255, 255, 255
490 data 0, 0, 0, 0, 0, 0, 0, 0
500 data 16, 40, 40, 16, 16, 24, 16, 24
510 data 129, 66, 60, 165, 126, 24, 36, 195
520 data 1, 1, 31, 17, 1, 1, 1, 1
530 data 64, 64, 64, 224, 16, 236, 60, 0
540 data 16, 16, 16, 16, 56, 124, 254, 0
550 data 16, 16, 16, 16, 16, 16, 16, 0
560 data 255, 136, 218, 216, 217, 218, 255, 255
570 data 255, 145, 183, 145, 189, 145, 255, 255
580 data 255, 17, 85, 81, 83, 21, 255, 255
590 data 255, 247, 213, 227, 193, 227, 213, 247
600 data 127, 85, 106, 53, 42, 53, 26, 21
610 data 254, 170, 86, 172, 84, 172, 88, 168
620 data 26, 13, 10, 13, 10, 13, 10, 15
630 data 88, 176, 80, 176, 80, 176, 80, 240
10 rem ***** out-break 2 ****
20 rem
30 rem
100 rem **********************
110 rem * copyright by *
120 rem * gudrun disser *
130 rem * schulstr. 42 *
140 rem * 6451 mainhausen *
150 rem **********************
160 clr:poke36869,192
170 c=int(rnd(1)*4)+1
180 v=int(rnd(1)*899)+100
190 v2$=str$(v):v2$=right$(v2$,3)
200 v3$=left$(v2$,1):v4$=mid$(v2$,2,1):v5$=right$(v2$,1)
210 f=33792:t=36878:t1=36874:t2=36875:t3=36876:t4=36877
220 ff=int(rnd(1)*7)+24
230 poke36879,25:z$=" {rvon} {rvof}"
240 print"{clr}{wht}"z$:print"{rvon} out-break {rvof}";:printz$
250 print"{down}{down}{down}{rvof}{pur} schwierigkeitsgrad"
260 print"{down}{down} {rvon}{blu} 1 {rvof} {grn}einfach"
270 print"{down} {rvon}{blu} 2 {rvof} {grn}schwer"
280 print"{down} {rvon}{blu} 3 {rvof} {grn}sehr schwer
290 print"{down}{down}{down}{down}{wht}"z$:print"{rvon} bitte waehlen {rvof}";:printz$
300 l6=4557:forh=4096to4160:pokeh+f,2:pokel6+f,2:l6=l6-1:gosub3070:next
310 getg
320 ifg=1thenx=20:goto370
330 ifg=2thenx=10:goto370
340 ifg=3thenx=5:u=2:x2=4:goto370
350 l7=l7+1:ifl7=300thenl7=0:print"{clr}":forh=1to3000:next:goto160
360 goto310
370 goto390
380 l6=4557:forh=4096to4160:pokeh,32:pokel6,32:l6=l6-1:gosub3070:next
390 print"{clr}":a=2:ty=1:ti$="000000"
400 print"{clr}{blk}"
410 poke36869,207
420 a1$="{home}{rvon}M{down}M{down}M{down}M{down}M"
430 a2$="{home}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}N{down}{left}{left}N{down}{left}{left}N{down}{left}{left}N{down}{left}{left}N"
440 b1$="{home}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rvon}O{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}P"
450 b2$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rvon}L{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{SHIFT-@}"
460 b3$="{home}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}"
470 b4$="{home}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-M}{down}{left}{CBM-M}{down}{left}{CBM-M}{down}{left}{CBM-M}{down}{left}{CBM-M}{down}{left}{CBM-M}{down}{left}{CBM-M}{down}{left}{CBM-M}{down}{left}{CBM-M}"
480 a3$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rvon}N{down}{left}{left}N{down}{left}{left}N{down}{left}{left}N{down}{left}{left}N"
490 a4$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}M{down}M{down}M{down}M{down}M"
500 i$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}O{CBM-T}P{down}{left}{left}{left}{CBM-G}{rght}{CBM-M}{down}{left}{left}{left}{CBM-G}{rght}{CBM-M}{down}{left}{left}{left}{CBM-G}{rght}{rvof}%{rvon}{down}{left}{left}{left}{CBM-G}{rght}{CBM-M}{down}{left}{left}{left}L{CBM-@}{SHIFT-@}"
510 j1$="{home}{down}{down}{down}{down}{down}{down}{rvon}{CBM-M}M{down}{left}{left}{CBM-M}{rght}M{down}{left}{left}{left}{CBM-M}{rght}{rght}M{down}{left}{left}{left}{left}{CBM-M}{CBM-T}{CBM-T}P{down}{left}{left}{left}{left}{CBM-M}{rght}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-M}{rght}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-M}{rght}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-M}{rght}{rght}{CBM-M}"
520 j2$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rvon}{CBM-M}{rght}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-M}{rght}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-M}{rght}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-M}{rght}{rght}{CBM-M}"
530 j3$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rvon}{CBM-M}{CBM-T}{CBM-T}{CBM-T}{up}N{down}{left}{down}{left}{left}{left}{left}{CBM-M}{down}{left}{CBM-M}{down}{left}N"
540 k1$="{home}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}N{CBM-G}{down}{left}{left}{left}N{rght}{CBM-G}{down}{left}{left}{left}{left}N{rght}{rght}{CBM-G}{down}{left}{left}{left}{left}O{CBM-T}{CBM-T}{CBM-G}{down}{left}{left}{left}{left}{CBM-G}{rght}{rght}{CBM-G}{down}{left}{left}{left}{left}{CBM-G}{rght}{rght}{CBM-G}"
550 k2$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rvon}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-G}{rght}{rght}{CBM-G}{down}{left}{left}{left}{left}{CBM-G}{rght}{rght}{CBM-G}{down}{left}{left}{left}{left}{CBM-G}{rght}{rght}{CBM-G}{down}{left}{left}{left}{left}{CBM-G}{rght}{rght}{CBM-G}{down}{left}{left}{left}{left}{left}ML{CBM-@}{CBM-@}{CBM-G}"
560 k3$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rvon}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}{down}{left}{CBM-G}{down}{left}M"
570 c1$="{home}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-G}{down}{left}OPM{down}{left}{left}{left}{CBM-G}{CBM-M}{rght}M{down}{left}{left}{left}{left}{CBM-G}{CBM-M}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{CBM-M}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{CBM-M}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{CBM-M}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{CBM-M}{rght}{CBM-M}"
580 c2$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-G}{CBM-M}{rght}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{CBM-M}{rght}N{down}{left}{left}{left}{left}L{SHIFT-@}N{down}{left}{left}{left}{CBM-G}"
590 c3$="{home}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-M}{down}{left}{left}{left}NOP{down}{left}{left}{left}{left}N{rght}{CBM-G}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{rght}{CBM-G}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{rght}{CBM-G}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{rght}{CBM-G}{CBM-M}"
600 c4$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-G}{rght}{CBM-G}{CBM-M}{down}{left}{left}{left}{left}{CBM-G}{rght}{CBM-G}{CBM-M}{down}{left}{left}{left}{left}M{rght}{CBM-G}{CBM-M}{down}{left}{left}{left}ML{SHIFT-@}{down}{left}{CBM-M}"
610 d1$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{down}{left}{left}{left}{left}{left}{left}{left}{CBM-M}M{rght}{rght}{rght}{rght}N{CBM-G}{down}{left}{left}{left}{left}{left}{left}{left}{left}{CBM-M}{rght}M{rght}{rght}N{rght}{CBM-G}{down}{left}{left}{left}{left}{left}{left}{left}{left}{CBM-M}{rght}{rght}OP{rght}{rght}{CBM-G}"
620 d7$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{CBM-@}{down}{left}{left}{left}{left}{left}{left}{left}{CBM-M}M{rght}{rght}{rght}{rght}N{CBM-G}{down}{left}{left}{left}{left}{left}{left}{left}{left}{CBM-M}{rght} {rght}{rght} {rght}{CBM-G}{down}{left}{left}{left}{left}{left}{left}{left}{left}{CBM-M} {rght}{rght}{CBM-G}"
630 d2$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-M}{rght}{rght}L{SHIFT-@}{rght}{rght}{CBM-G}{down}{left}{left}{left}{left}{left}{left}{left}{left}{CBM-M}{rght}N{rght}{rght}M{rght}{CBM-G}{down}{left}{left}{left}{left}{left}{left}{left}{left}{SHIFT-@}N ML"
640 e$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{left}{left}{left}{left}{down}{down}{down}{down}{CBM-@}{CBM-@}{CBM-@}{CBM-@}"
650 f$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvof}{blu}i{red}j{down}{left}{left}{blu}k{red}l{blk}"
660 g1$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rvon}{pur}NO{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}PM{down}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}N{rght}{CBM-G}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{CBM-M}{rght}M"
670 g2$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rvon}{pur}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{blk}"
680 h1$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{pur}{CBM-M}C{CBM-G}{down}{left}{left}{left}{CBM-M}C{CBM-G}{down}{left}{left}{left}{CBM-M}C{CBM-G}{down}{left}{left}{left}{CBM-M}C{CBM-G}{down}{left}{left}{left}{CBM-M}C{CBM-G}{down}{left}{left}{left}{CBM-M}C{CBM-G}{down}{left}{left}{left}{CBM-M}C{CBM-G}{blk}"
690 h2$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{pur}{CBM-M}C{CBM-G}{down}{left}{left}{left}PCO{down}{left}{left}{left}{CBM-M}C{CBM-G}{down}{left}{left}{left}PCO{down}{left}{left}{left}{CBM-M}C{CBM-G}{blk}"
700 m$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvof}{grn}e{blk}{down}{left}{left}ab{down}{left}{left}cd"
710 l$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvof}{red}f{down}{left}g{down}{left}h{blk}"
720 o$="{grn}uxv{down}{left}{left}{left}txxv{down}{left}{left}{left}{left}xxxv{down}{left}{left}{left}{left}txxw{down}{left}{left}{left}{blk}rs{down}{left}{left}rs{down}{left}{left}pq"
730 n$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rvon}{blu}bravo!!!"
740 n1$="{rvon}{blu} du bist frei"
750 p$="{rvon}{red} ohne schluessel geht{down} das nicht"
760 q$="{rvon}{blu}das geht nicht!!!{blk}"
770 r$="{rvon}{yel}im dunkeln findest du {down} dich nicht zurecht"
780 s$="{yel}du konntest die bombe {down} nicht rechtzeitig {down} beseitigen!!!!"
790 t$="{yel}du bist in den schacht{down}gefallen und hast das {down} spiel verloren!!!!"
800 u$="{rvon}{red} sehr gut!! {down}{down}{blu} du hast die bombe {down} beseitigt.{blk}"
810 m1$="{rvon}{pur} das geht nicht du {down} musst erst die bombe {down} loswerden!!"
820 v$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{blu})*+{down}{left}{left}{left}!,!{down}{left}{left}{left}!!!{rvof}{blk}"
830 v1$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{blk}!!!{down}{left}{left}{left}!\!{down}{left}{left}{left}!!!{blu}{left}{left}{left}{left}{up}{up}{rvon}{CBM-L}{down}{left}{CBM-L}{down}{left}{CBM-L}{rvof}{blk}"
840 w$="{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{pur}-.{down}{left}{left}/0"
850 gosub4050
860 b=0:c1=c*a:b$="":a$="":d2=0
870 ifa=15andm=0thengosub2660:gosub4050
880 ifd1=1thenprint"{up}{wht}"
890 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rvon}"chr$(63);chr$(32);chr$(122);
900 ifa<>13thent5=0:x2=4
910 ifm1>0orm=1then930
920 ifa=15thenm1=1:m2=val(ti$):m=3
930 ifm1=1then3010
940 ift5=1then960
950 ifa=13andg=3thent5=1:m4=val(ti$)
960 ift5=1then3030
970 gety$
980 ift5=1andx2=<0thena=int(rnd(1)*17)+1:gosub4050:goto860
990 ifm1=1andx=<0thenz=3:goto3750
1000 ifm3=>(m4+5)andt5=1thenpoke4106+x2,32:x2=x2-1:m4=m3
1010 m3=val(ti$):ifm3=>(m2+5)andm1=1thenpoke4096+x,32:x=x-1:m2=m3
1020 ify$=""then970
1030 printchr$(157)y$chr$(122);
1040 poket,1:poket3,200
1050 ify$=chr$(20)andlen(b$)=0then950
1060 ify$=chr$(20)thenb$=left$(b$,len(b$)-1)
1070 b$=b$+y$
1080 ify$=chr$(20)thenb$=left$(b$,len(b$)-1)
1090 poket,0:poket3,0
1100 ify$=chr$(13)then1120
1110 goto970
1120 print"{clr}"
1130 a$=mid$(b$,6,4):b$=left$(b$,4)
1140 ifb$="farb"thengosub3050:goto1370
1150 ifb$="lamp"andmid$(a$,2,2)="an"andd=1thend2=1:goto1370
1160 ifd1=1andb$<>"zuru"thengosub2530
1170 ifd1=1thengosub1210:goto1370
1180 ifb$="rech"thenb=-1:goto1370
1190 ifb$="link"thenb=1:goto1370
1200 ifleft$(b$,3)="vor"thenb=2:goto1370
1210 ifb$="zuru"thenb=-2:goto1370
1220 ifd1=1thenreturn
1230 ifb$="nimm"anda$="leit"anda=5thenl=1:goto1370
1240 ifb$="lege"anda$="leit"andl=1anda=6thenl=3:goto1370
1250 ifb$="nimm"anda$="lamp"and(c1=3orc1=22orc1=42orc1=56)thend=1:goto1370
1260 ifb$="nimm"anda$="schl"anda=6andl=3thens5=1:goto1370
1270 ifs5=1andl<>3thenx=1:goto3750
1280 ifb$="nimm"anda$="feue"and(c1=11orc1=44orc1=6orc1=9)thenf1=1:goto1370
1290 ifb$="nimm"anda$="bomb"anda=15thenm=1:goto1370
1300 ifb$="wirf"anda$="bomb"anda=6andm=1thenm=2:m1=2:gosub2620:goto1370
1310 ifa=13andleft$(b$,3)=v2$thent6=1:goto1370
1320 ifb$="nimm"anda$="schl"anda=13andt6=1thent6=0:s6=1:goto1370
1330 ifa=10andb$="sieh"anda$="nach"then:z=2:goto2870
1340 ifa=10andb$="nimm"anda$="zett"andz=2thenz=1:goto1370
1350 ifz=1andb$="lies"anda$="zett"thengoto2890
1360 gosub2430
1370 print"{blk}":d1=0
1380 ifa<>13thent5=0:x2=4
1390 onagoto1400,1460,1520,1570,1630,1690,1760,1830,1890,1940,1990,2040,2110,2170,2230,2290,2350
1400 ifb=1thena=14
1410 ifb=-1thena=2
1420 ifb=2thena=6
1430 ifb=-2thengosub2430
1440 gosub4050
1450 goto860
1460 ifb=1thena=1
1470 ifb=-1thena=3
1480 ifb=2thena=8
1490 ifb=-2thengosub2430
1500 gosub4050
1510 goto860
1520 ifb=1thena=2
1530 ifb=-1thena=4
1540 ifb=-2orb=2thengosub2430
1550 gosub4050
1560 goto860
1570 ifb=1thena=3
1580 ifb=-1thena=16
1590 ifb=2thena=5
1600 ifb=-2thengosub2430
1610 gosub4050
1620 goto860
1630 ifb=2ands5=1thena=9
1640 ifb=2ands5=0thengosub2480
1650 ifb=-2thena=4
1660 ifb=1orb=-1thengosub2430
1670 gosub4050
1680 goto860
1690 ifb=2andl=3ands5=1thena=7
1700 ifb=2andl<>3thenz=1:goto3750
1710 ifb=-2thena=1
1720 ifb=2ands5=0thengosub2480
1730 ifb=1orb=-1thengosub2430
1740 gosub4050
1750 goto860
1760 ifb=-1thena=8
1770 ifb=2ands5=1thena=13:gosub2780
1780 ifb=2ands5=0thengosub2480
1790 ifb=-2thena=6
1800 ifb=1thengosub2430
1810 gosub4050
1820 goto860
1830 ifb=1thena=7
1840 ifb=-1thena=9
1850 ifb=2thena=12
1860 ifb=-2thena=2
1870 gosub4050
1880 goto860
1890 ifb=1thena=8
1900 ifb=-2thena=5
1910 ifb=-1orb=2thengosub2430
1920 gosub4050
1930 goto860
1940 ifb=1thena=11
1950 ifb=2thena=16
1960 ifb=-1orb=-2thengosub2430
1970 gosub4050
1980 goto860
1990 ifb=1thena=12
2000 ifb=-1thena=10
2010 ifb=2orb=-2thengosub2430
2020 gosub4050
2030 goto860
2040 ifb=-1thena=11
2050 ifb=2ands5=1thena=15
2060 ifb=2ands5=0thengosub2480
2070 ifb=-2thena=8
2080 ifb=1thengosub2430
2090 gosub4050
2100 goto860
2110 ifb=-2thena=7
2120 ifb=2ands5=0thengosub2480
2130 ifb=2ands5=1thena=14:ty=2
2140 ifb=-1orb=1thengosub2430
2150 gosub4050
2160 goto860
2170 ifb=1thena=1
2180 ifb=-1thena=15
2190 ifb=-2thena=13:gosub2780
2200 ifb=2thengosub2430
2210 gosub4050
2220 goto860
2230 ifb=2thena=17
2240 ifb=-2thena=12
2250 ifb=1thena=14
2260 ifb=-1thengosub2430
2270 gosub4050
2280 goto860
2290 ifb=-1thena=4
2300 ifb=1thena=17
2310 ifb=-2thena=10
2320 ifb=2thengosub2430
2330 gosub4050
2340 goto860
2350 ifb=-1thena=16
2360 ifb=-2thena=15
2370 ifb=2and(m=1orm=3)thengosub2580
2375 ifb=2andg=1ands5=0thengosub2480:goto2400
2376 ifb=2andg=1ands5=1and(m=0orm=2)then3080
2380 ifb=2ands6=0and(m=0orm=2)thengosub2830
2390 ifb=2ands6=1and(m=0orm=2)then3080
2400 ifb=1thengosub2430
2410 gosub4050
2420 goto860
2430 print"{clr}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}";
2440 forq=1tolen(q$):print"{rvon}"mid$(q$,q,1);
2450 ifmid$(q$,q,1)=chr$(32)thennextq
2460 gosub3230:nextq
2470 forh=1to1500:next:return
2480 print"{clr}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
2490 forq=1tolen(p$):print"{rvon}"mid$(p$,q,1);
2500 ifmid$(p$,q,1)=chr$(32)thennextq
2510 gosub3230:nextq
2520 forh=1to2000:next:print"{blk}":return
2530 print"{clr}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
2540 forq=1tolen(r$):print"{rvon}"mid$(r$,q,1);
2550 ifmid$(r$,q,1)=chr$(32)thennextq
2560 gosub3230:nextq
2570 forh=1to2000:next:print"{wht}":return
2580 print"{clr}{down}{down}{down}{down}{down}{down}{down}{down}"
2590 forq=1tolen(m1$):print"{rvon}"mid$(m1$,q,1);
2600 ifmid$(m1$,q,1)=chr$(32)thennextq
2610 gosub3230:nextq:forh=1to1000:next:return
2620 print"{clr}{down}{down}{down}{down}{down}{down}{down}{down}
2630 forq=1tolen(u$):print"{rvon}"mid$(u$,q,1);
2640 ifmid$(u$,q,1)=chr$(32)thennextq
2650 gosub3230:nextq:forh=1to1000:next:return
2660 forh=1to2000:next
2670 ifg=1thenx1=100
2680 ifg=2thenx1=50
2690 ifg=3thenx1=25
2700 print"{clr}{down}{down}{down}{down}{down}{rvon}{wht} vor dir liegt eine {down} bombe. du hast ca. "
2710 ifg=1thenx1=100
2720 print"{rvon}"x1;:print"sekunden zeit um {down} sie in einen schacht {down} zu werfen. nur so{down} "
2730 print"{rvon} kannst du sie {down} beseitigen!!{blk}{rvof}"
2740 fori=1to100
2750 poke36879,10:gosub2770:poke36879,40:gosub2770:nexti
2760 return
2770 poket,6:poket3,250:forh=1to10:next:poket,0:poket3,0:return
2780 ifg<>3thenreturn
2790 print"{clr}{down}{down}{down}{down}{rvon} du hast durch das {down} betreten des raumes "
2800 print"{rvon} die alarmanlage aus- {down} geloest. deine ver- {down} folger sind dir auf "
2810 print"{rvon} der spur. in 20 sec. {down} musst du den raum {down} verlassen."
2820 forh=1to7000:next:return
2830 print"{clr}{down}{down}{down}{rvon} das geht nur mit dem {down} schluessel und einem"
2840 print"{down}{rvon}zusaetzlichen spezial-{down} schluessel"
2850 print"{rvon}{down}{down} er befindet sich in {down} einem tresor"
2860 for h=1to7000:next:return
2870 print"{clr}{down}{down}{down}{down}{down}{down}{rvon} im abfalleimer liegt {down} ein zettel{blk}"
2880 forh=1to2000:next:gosub4050:goto860
2890 print"{clr}{rvon}{down}{down}{down} der code fuer den {down} tresor besteht aus {down} folgenden zahlen,"
2900 print"{down}{rvon} die aber noch in {down} die richtige rei- {down} henfolge gebracht"
2910 print"{down}{rvon} werden muessen:":print"{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}";
2920 w=int(rnd(1)*6)+1
2930 onwgoto2940,2950,2960,2970,2980,2990
2940 printv3$;v4$;v5$:goto3000
2950 printv3$;v5$;v4$:goto3000
2960 printv4$;v3$;v5$:goto3000
2970 printv4$;v5$;v3$:goto3000
2980 printv5$;v4$;v3$:goto3000
2990 printv5$;v3$;v4$:goto3000
3000 print"{blk}":forh=1to9000:next:gosub4050:goto860
3010 forh=4097to4096+x:pokeh+f,2:pokeh,33:next
3020 goto940
3030 forh=4107to4106+x2:pokeh+f,4:pokeh,33:next
3040 goto970
3050 ff=ff+1:ifff=32thenff=24
3060 return
3070 poket,1:poket2,250:fors=1to20:nexts:poket2,0:poket,0:return
3080 poket,5:forr=128to255step.2:poket3,r:next:poket,0:poket3,0
3090 poke36879,152:print"{clr}"
3100 print"{home}{down}{rght}{rght}{rght}{rght}"o$:print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}"o$:print"{rght}{rght}"o$
3110 print"{home}{down}{down}{down}{down}{down}{down}{blk} ^^]^{rght}{rght}{rght}^^]]^^^]"spc(30)"^]^]]^^^"
3120 print"{down}{down}{down}{down}"spc(13)"]]]^{rght}{rght}{rght}^^"spc(58)"^^^^]]^]"
3130 print"{down}{down}{down} ^]{rght}{rght}{rght}]]]^^]"
3140 forq=1to2000:next
3150 printn$:print
3160 forp=1to15:print"{rvon}"mid$(n1$,p,1);
3170 o=o+1
3180 ifmid$(n1$,p,1)=chr$(32)thennextp
3190 gosub3220:nextp
3200 forq=1to800:next:forr=4373to4360step-1:poker,32:next
3210 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}":goto3160
3220 ifo>60thenprint"{clr}":goto160
3230 poket,2:poket3,150:fors=1to20:nexts:poket3,0:poket,0:return
3240 s1=4454:s2=4459:s3=4464:s4=4478:f=33792:k=4585
3250 ifm1=1andf1=1thenx=x-4:goto3270
3260 ifm1=1thenx=x-2
3270 pokes1,36:pokes1+f,0:pokes2,36:pokes2+f,0:pokes3,36:pokes3+f,0
3280 iff1=0then3300
3290 pokes4,36:pokes4+f,0:pokek,39:pokek+f,2
3300 poket,4:fori=170to200:poket1,i:next:poket,0:poket1,0
3310 ifs1>4580ors2>4580ors3>4580ors4>4580thenz=2:goto3750
3320 iff1=0then3380
3330 ifk>4595then3350
3340 ifpeek(197)=28thenpokek,32:k=k+1:pokek+f,2:pokek,39
3350 ifk<4586then3370
3360 ifpeek(197)=35thenpokek,32:k=k-1:pokek+f,2:pokek,39
3370 ifpeek(653)=1thengosub3730:gosub3610
3380 ife5=1thene6=e6+1
3390 ife6=90then3690
3400 ife1>2ande2>2ande3>2ande4>2thene5=1:goto3310
3410 j=j+1:ifj=3thenj=0:goto3430
3420 goto3310
3430 s=int(rnd(1)*4)+1
3440 onsgoto3450,3490,3530,3570
3450 ifpeek(s1)=32thens1=4454:e1=e1+1
3460 ife1=5then3300
3470 pokes1,32:s1=s1+22:pokes1,36:pokes1+f,0
3480 goto3300
3490 ifpeek(s2)=32thens2=4478:e2=e2+1
3500 ife2=5then3300
3510 pokes2,32:s2=s2+22:pokes2,36:pokes2+f,0
3520 goto3300
3530 ifpeek(s3)=32thens3=4459:e3=e3+1
3540 ife3=5then3300
3550 pokes3,32:s3=s3+22:pokes3,36:pokes3+f,0
3560 goto3300
3570 ifpeek(s4)=32thens4=4464:e4=e4+1
3580 ife4=5then3300
3590 pokes4,32:s4=s4+22:pokes4,36:pokes4+f,0
3600 goto3300
3610 h=k:fori=h-22toh-132step-22:pokei+f,5:pokei,40
3620 ifpeek(i-22)=36thengosub3660:goto3640
3630 nexti
3640 forj1=h-22toh-132step-22:pokej1+f,1:pokej1,32:nextj1
3650 return
3660 ife5=1thenreturn
3670 poke4455,36:poke4455+f,0:poke4457,36:poke4457+f,0:poke4462,36:poke4462+f,0
3680 return
3690 fori1=4582to4605:pokei1,32:nexti1:poke198,0
3700 fori2=4448to4580:ifpeek(i2)=36thenz=2:goto3750
3710 nexti2
3720 e=0:e1=0:e2=0:e3=0:e4=0:e5=0:e6=0:e7=0:goto860
3730 poket,4:forh=250to220step-2:poket2,h:next:poket2,0
3740 return
3750 forh=1to1000:next
3760 ifz=3then3780
3770 poke36869,192:poke36879,8:poke198,0
3780 onzgoto3790,3840,3950
3790 print"{clr}{down}{down}{down}{down}{down}{down}{down}":forq=1tolen(t$):printmid$(t$,q,1);
3800 ifmid$(t$,q,1)=chr$(32)thennextq
3810 gosub3230:nextq
3820 goto4020
3830 rem
3840 u=u+1
3850 print"{clr}{down}{down}{down}{down}{down}{down}{yel} du bist von einer {down} spinne gebissen {down} worden.{down}{down}"
3860 ifg=1then3890
3870 ifu=3then4020
3880 print" der dritte biss ist {down} toedlich."
3890 forh=1to5000:next
3900 print"{clr}{down}{down}{down}{down}{down}{down}{grn} durch das spinnengift{down} bist du verwirrt und {down} weisst nicht wo du"
3910 print"{down} dich befindest.":forh=1to5000:next:poke36869,207:print"{clr}{blk}"
3920 a=int(rnd(1)*17)+1
3930 gosub4050:goto860
3940 rem
3950 poket,15:poket4,130
3960 forh=1to100
3970 poke36879,124:poke36879,143:poke36879,234:next:poket,0:poket4,0
3980 poke36879,8:poke36869,192:print"{clr}{down}{down}{down}{down}{down}{down}{down}"
3990 forq=1tolen(s$):printmid$(s$,q,1);
4000 ifmid$(s$,q,1)=chr$(32)thennextq
4010 gosub3230:nextq
4020 print:print"{down}{down}{down}{cyn} - spielende -{blk}"
4030 forh=1to8000:next:goto160
4040 end
4050 print"{clr}":poket,2:poket2,190:forh=1to60:next:poket,0:poket2,0
4060 c1=c*a
4070 ifa=1ora=4ora=16ora=14thenpoke36879,(ff+160):goto4110
4080 ifd2=0and(c1=13orc1=34orc1=48)thenpoke36879,8:d1=1:goto4110
4090 ifd2=1and(c1=13orc1=45orc1=34orc1=48)thenpoke36879,152:goto4110
4100 poke36879,ff
4110 ifa=1ora=2ora=4ora=8thenty=1
4120 ifa=3ora=11ora=14ora=16thenty=2
4130 ifa=5ora=6ora=13thenty=3
4140 ifa=7ora=12thenty=4
4150 ifa=10ora=15thenty=5
4160 ifa=17thenty=6
4170 ifa=9thenty=7
4180 ontygoto4190,4220,4300,4380,4410,4450,4460
4190 printa1$a2$b1$b2$j1$j2$j3$k1$k2$k3$b3$b4$d1$d2$
4200 if(c=2orc=3)anda=8then3240
4210 return
4220 printa1$a2$a3$a4$c1$c2$c3$c4$e$
4230 ifc1=3andd=0thenprintf$
4240 ifc1=22andd=0thenprintf$
4250 ifc1=42andd=0thenprintf$
4260 ifc1=56andd=0thenprintf$
4270 if(c=1orc=4)anda=11andf1=0thenprintl$
4280 if(c=2orc=3)anda=3andf1=0thenprintl$
4290 return
4300 printa1$a2$a3$a4$b1$b2$b3$b4$i$
4310 ifa=6thenprintg1$g2$
4320 ifl=0anda=5thenprinth1$
4330 ifl=3anda=6thenprinth2$
4340 ifa=6ands5=0thenpoke4352+f,2:poke4352,35
4350 ifg>1anda=13andt6=0thenprintv$
4360 ifg>1anda=13andt6=1thenprintv1$
4370 return
4380 printa1$a2$a3$b1$b2$b3$b4$k1$k2$k3$i$
4390 ifc=4anda=7then3240
4400 return
4410 printa1$a2$a4$j1$j2$j3$b1$b2$b3$b4$d1$d2$
4420 ifa=15and(m=0orm=3)thenprintm$
4430 ifa=10andg>1thenprintw$
4440 return
4450 printa1$a2$a3$b1$b2$b3$b4$k1$k2$k3$:print"{grn}"i$:print"{blk}":return
4460 printa1$a2$a4$b1$b2$b3$b4$j1$j2$j3$
4470 ifc=1then3240
4480 return
Diesen Artikel als PDF herunterladen
Diesen Artikel auf Mastodon teilen