Berechnung periodischer Dezimalbrüche
Wahrscheinlich standen Sie auch schon vor dem Problem, einen periodischen Dezimalbruch in einen echten Bruch umzuwandeln. Dieses Programm berechnet Ihnen den echten Bruch automatisch. Ungenauigkeiten treten nicht auf.
Das Programm ist so geschrieben, daß eine Fehlbedienung so gut wie ausgeschlossen ist. Das Anfangsbild zeigt, wie die periodischen Dezimalbrüche eingegeben werden. Neben dem eigentlichen Ergebnis werden zusätzlich noch die wichtigsten Rechenschritte angezeigt. Nehmen wir doch einmal das Beispiel aus dem Anfangsbild:
Zu berechnen ist der Dezimalbruch
\[0.76\overline{351},\]
Einzugeben ist der Wert 0.76351 und die Länge der Periode = drei. Der Dezimalbruch wird nun wie folgt aufgespaltet:
\[0.76\overline{351} = \frac{76}{100} + \mathrm{Rest}\]
wobei für den Rest gilt,
\[\mathrm{Rest} = \sum_{K=0}^{\infty} \frac{351}{10^{5+3K}}\]
Dieses ist noch recht einfach zu verstehen. Daraus ergibt sich
\[= \frac{351}{10^5} \times \sum_{K=0}^{\infty} \frac{1}{10^{3K}}\]
dieses ist durch vollständige Iteration beweisbar.
\[= \frac{351}{100000} \times \frac{1}{0.999}\]
Somit gilt (siehe auch ersten Zwischenschritt beim Ausdruck):
\[0.76\overline{351} = \frac{76}{100} + \frac{351}{100000} \times \frac{1}{0.999}\]
Dies war der schwierigste Teil der Berechnung und erforderte zum ganzen Verständnis schon einige Grundkenntnisse in höherer Mathematik. Doch zum Glück ist das Verständnis keine Voraussetzung zum Benutzen des Programms.
Sehen wir weiter: Zunächst wird nun versucht, die vorhandenen Brüche so klein wie möglich zu machen. Das geschieht dadurch, daß man jeweils von Zähler und Nenner den GGT (größter gemeinsamer Teiler) berechnet und Zähler und Nenner dadurch dividiert. In unserem Beispiel ist beim ersten Bruch
\[\frac{76}{100}\]
der GGT = 4; nach der Division erhalten wir also
\[\frac{19}{25}\]
Beim anderen Bruch (der zweite Bruch wurde bereits mit dem dritten multipliziert) haben wir den GGT 27, dies führt dann zum Ergebnis
\[\frac{13}{3700}\]
Als zweites Zwischenergebnis steht nun:
\[= \frac{19}{25} + \frac{13}{3700}\]
Im folgenden sind jetzt also nur noch die beiden Brüche zu addieren. Das machen wir, wie in der Schule gelernt, indem wir zuerst das KGV (kleinstes gemeinsames Vielfaches) der beiden Nenner suchen. Da die Funktion GGT schon vorhanden ist und das KGV definiert ist als
\[\mathrm{KGV}(a,b) = \frac{a \times b}{\mathrm{GGT}(a,b)}\]
ist dies kein größeres Problem.
Anschließend muß dann nochmal durch den GGT des jetzt so entstehenden einzigen Bruches dividiert werden und wir erhalten:
\[= \frac{113}{148}\]
Wenn das Programm als Unterprogramm verwendet werden soll, so muß vor dem Aufruf der Dezimalbruch in X$ stehen und die Länge in L$. Zurückgegeben wird dann in Z2$ der Zähler und in N2$ der Nenner. Die Zeilen zum Ausdrucken der Ergebnisse müssen natürlich entfernt werden.
Das Programm wurde zwar für den C 64 geschrieben, kann aber im Prinzip auf jeden anderen Computer übertragen werden, sofern er Stringbefehle verarbeiten kann. Falls diese nicht zur Verfügung stehen, müssen wenige Anpassungs-Routinen geschrieben werden.
(B. Filpe/do)0 rem *********************************
1 rem * *
2 rem * berechnung periodischer *
3 rem * dezimalbrueche *
4 rem * *
5 rem * bernhard filpe *
6 rem * langgasse 28 *
7 rem * 6733 hassloch *
8 rem * *
9 rem *********************************
10 poke53280,6:poke53281,6:printchr$(147),chr$(14),chr$(8)
20 print"Berechnung periodischer Dezimalbrueche"
30 print"{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}"
40 print"{down}{down}{down}Eingabebeispiel:"
45 print"{down} {SHIFT-*}{SHIFT-*}{SHIFT-*}"
50 print"Zu berechnen: 0.76351"
60 print"{down}Eingabe : 0.76351 Laenge 3"
70 print"{down}"
80 input"Dezimalbruch : ";x$
90 input"Laenge der Periode: ";l$
100 l=val(l$):ifl<>int(l)orl<1thener$="Eingabe der Periode falsch":goto2000
105 if val(x$)=0thener$="Falsche Eingabe":goto2000
110 rem test auf korrekte eingabe
120 xl=len(x$)
130 for i=1toxl
140 t$=mid$(x$,i,1):t=val(t$)
150 if(t=>1)and(t<=9)thenfl=1:goto180
160 if t$="0"andfl=0then nu=nu+1:goto180
165 if t$="0"then180
170 if t$="."andpf=0thenfl=1:pf=1:pk=i:goto180
175 er$="Falsche Eingabe":el=i:goto2000
180 next
200 if fl then x$=mid$(x$,nu+1):pk=pk-nu
210 xl=len(x$)
220 if pf=0thener$="Dezimalpunkt fehlt":goto2000
230 if l>xl-pkthener$="Falsche Periodenangabe":goto2000
250 print"{clr}{down}Berechnung periodischer Dezimalbrueche"
260 print"{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}{CBM-T}"
270 print"{down}Dezimalbruch : ";:ifpk=1thenprint"0";
275 printx$
280 print"Laenge der Periode : ";l$
290 print
300 rem berechnung
310 n(1)=10^(xl-l-pk)
320 if pk=1thenv$=mid$(x$,2,xl-l-1):goto337
330 v$=mid$(x$,1,pk-1):vl=len(v$)
335 v$=v$+mid$(x$,pk+1,xl-vl-1-l)
337 z(1)=val(v$)
340 n(2)=10^(xl-pk)
350 z(2)=val(mid$(x$,xl-l+1)):ifz(2)=0thener$="Dezimalbruch trivial":goto2000
360 n(3)=1-10^(-l):z(3)=1
400 gosub3000
410 gosub4000:print
420 if z(1)=0then 450
430 g1=z(1):g2=n(1):gosub5000:rem ggt
440 z(1)=z(1)/gg:n(1)=n(1)/gg
450 z(2)=z(2)*z(3)
460 n(2)=n(2)*n(3)
510 g1=z(2):g2=n(2):gosub5000:rem ggt
520 z(2)=z(2)/gg:n(2)=n(2)/gg
530 gosub3000
540 if z(1)<>0thengosub4300
550 if z(1)=0thengosub4200:end
555 print
560 g1=n(1):g2=n(2):gosub5000
570 gg=n(1)*n(2)/gg:rem kgv
580 z(1)=z(1)*gg/n(1)
590 z(2)=z(2)*gg/n(2)
600 n(2)=gg:z(2)=z(1)+z(2)
610 g1=z(2):g2=n(2):gosub5000
620 z(2)=z(2)/gg:n(2)=n(2)/gg
630 gosub3000:gosub4200
700 end
2000 rem fehleranzeige
2010 print"{down}{down}{down}{rvon} ";er$;" "
2015 if el=0then2030
2017 print"{down}";x$:if el=1thenprint"^":goto2030
2020 forj=1toi-1:print" ";:next:print"^"
2030 for w=1to1000:geta$:ifa$=""then next
2040 run
3000 rem ausgabe der errechneten werte
3005 z(1)=int(z(1)):z(2)=int(z(2)):n(1)=int(n(1)):n(2)=int(n(2))
3010 z1$=str$(z(1)):n1$=str$(n(1))
3020 z2$=str$(z(2)):n2$=str$(n(2))
3030 z3$="1":n3$=str$(n(3))
3040 l1=len(z1$):if l1<len(n1$)then l1=len(n1$)
3050 l2=len(z2$):if l2<len(n2$)then l2=len(n2$)
3060 l3=len(n3$)
3070 if l1>len(z1$)thenz1$=" "+z1$:goto3070
3080 if l1>len(n1$)thenn1$=" "+n1$:goto3080
3090 if l2>len(z2$)thenz2$=" "+z2$:goto3090
3100 if l2>len(n2$)thenn2$=" "+n2$:goto3100
3110 if l3>len(z3$)thenz3$=" "+z3$:goto3110
3120 n3$="0"+mid$(n3$,2)
3130 return
4000 print" ";z1$;" ";z2$;" ";z3$
4010 print"= ";
4020 fori=1tol1:print"{SHIFT-*}";:next:print" + ";:fori=1tol2:print"{SHIFT-*}";:next:print" * ";
4030 for i=1tol3:print"{SHIFT-*}";:next:print
4040 print" ";n1$;" ";n2$;" ";n3$
4050 return
4100 print" ";z2$;" ";z3$
4110 print"= ";
4120 fori=1tol2:print"{SHIFT-*}";:next:print" * ";
4130 for i=1tol3:print"{SHIFT-*}";:next:print
4140 print" ";n2$;" ";n3$
4150 return
4200 print" ";z2$
4210 print"= ";
4230 for i=1tol2:print"{SHIFT-*}";:next:print
4240 print" ";n2$
4250 return
4300 print" ";z1$;" ";z2$
4310 print"= ";
4320 fori=1tol1:print"{SHIFT-*}";:next:print" + ";
4330 for i=1tol2:print"{SHIFT-*}";:next:print
4340 print" ";n1$;" ";n2$
4350 return
5000 rem ggt
5010 g1=int(g1):g2=int(g2)
5020 if g1<g2thenhi=g1:g1=g2:g2=hi
5030 if g1/g2=int(g1/g2)thengg=g2:return
5040 q=g1/g2:ifq>20 then g1=g1-int(q-10)*g2
5050 if g1=g2thengg=g1:return
5060 if g1>g2theng1=int(g1-g2):goto5050
5070 g2=int(g2-g1):goto5050
0 REM ********************************* 1 REM * * 2 REM * BERECHNUNG PERIODISCHER * 3 REM * DEZIMALBRUECHE * 4 REM * * 5 REM * BERNHARD FILPE * 6 REM * LANGGASSE 28 * 7 REM * 6733 HASSLOCH * 8 REM * * 9 REM ********************************* 10 POKE 53280,6:POKE 53281,6:PRINTCHR$ (147),CHR$ (14),CHR$ (8) 20 PRINT"BERECHNUNG PERIODISCHER DEZIMALBRUECHE" 30 PRINT"TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT" 40 PRINT"{3DOWN}EINGABEBEISPIEL:" 45 PRINT"{DOWN,18SPACE}***" 50 PRINT"ZU BERECHNEN: 0.76351" 60 PRINT"{DOWN}EINGABE{SPACE,4SPACE}: 0.76351{3SPACE}LAENGE 3" 70 PRINT"{DOWN}" 80 INPUT"DEZIMALBRUCH{6SPACE}: ";X$ 90 INPUT"LAENGE DER PERIODE: ";L$ 100 L=VAL (L$):IF L<>INT (L)OR L<1 THENER$="EINGABE DER PERIODE FALSCH":GOTO 2000 105 IF VAL (X$)=0 THENER$="FALSCHE EINGABE":GOTO 2000 110 REM TEST AUF KORREKTE EINGABE 120 XL=LEN (X$) 130 FOR I=1 TOXL 140 T$=MID$ (X$,I,1):T=VAL (T$) 150 IF (T=>1)AND (T<=9) THENFL=1:GOTO 180 160 IF T$="0"AND FL=0 THEN NU=NU+1:GOTO 180 165 IF T$="0" THEN180 170 IF T$="."AND PF=0 THENFL=1:PF=1:PK=I:GOTO 180 175 ER$="FALSCHE EINGABE":EL=I:GOTO 2000 180 NEXT 200 IF FL THEN X$=MID$ (X$,NU+1):PK=PK-NU 210 XL=LEN (X$) 220 IF PF=0 THENER$="DEZIMALPUNKT FEHLT":GOTO 2000 230 IF L>XL-PK THENER$="FALSCHE PERIODENANGABE":GOTO 2000 250 PRINT"{CLR,DOWN}BERECHNUNG PERIODISCHER DEZIMALBRUECHE" 260 PRINT"TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT" 270 PRINT"{DOWN}DEZIMALBRUCH{SPACE,6SPACE}: ";:IF PK=1 THENPRINT"0"; 275 PRINTX$ 280 PRINT"LAENGE DER PERIODE : ";L$ 290 PRINT 300 REM BERECHNUNG 310 N(1)=10^(XL-L-PK) 320 IF PK=1 THENV$=MID$ (X$,2,XL-L-1):GOTO 337 330 V$=MID$ (X$,1,PK-1):VL=LEN (V$) 335 V$=V$+MID$ (X$,PK+1,XL-VL-1-L) 337 Z(1)=VAL (V$) 340 N(2)=10^(XL-PK) 350 Z(2)=VAL (MID$ (X$,XL-L+1)):IF Z(2)=0 THENER$="DEZIMALBRUCH TRIVIAL":GOTO 2000 360 N(3)=1-10^(-L):Z(3)=1 400 GOSUB 3000 410 GOSUB 4000:PRINT 420 IF Z(1)=0 THEN 450 430 G1=Z(1):G2=N(1):GOSUB 5000:REM GGT 440 Z(1)=Z(1)/GG:N(1)=N(1)/GG 450 Z(2)=Z(2)*Z(3) 460 N(2)=N(2)*N(3) 510 G1=Z(2):G2=N(2):GOSUB 5000:REM GGT 520 Z(2)=Z(2)/GG:N(2)=N(2)/GG 530 GOSUB 3000 540 IF Z(1)<>0 THENGOSUB 4300 550 IF Z(1)=0 THENGOSUB 4200:END 555 PRINT 560 G1=N(1):G2=N(2):GOSUB 5000 570 GG=N(1)*N(2)/GG:REM KGV 580 Z(1)=Z(1)*GG/N(1) 590 Z(2)=Z(2)*GG/N(2) 600 N(2)=GG:Z(2)=Z(1)+Z(2) 610 G1=Z(2):G2=N(2):GOSUB 5000 620 Z(2)=Z(2)/GG:N(2)=N(2)/GG 630 GOSUB 3000:GOSUB 4200 700 END 2000 REM FEHLERANZEIGE 2010 PRINT"{3DOWN,RVSON,SPACE}";ER$;" " 2015 IF EL=0 THEN2030 2017 PRINT"{DOWN}";X$:IF EL=1 THENPRINT"↑":GOTO 2030 2020 FOR J=1 TOI-1:PRINT" ";:NEXT :PRINT"↑" 2030 FOR W=1 TO1000:GET A$:IF A$="" THEN NEXT 2040 RUN 3000 REM AUSGABE DER ERRECHNETEN WERTE 3005 Z(1)=INT (Z(1)):Z(2)=INT (Z(2)):N(1)=INT (N(1)):N(2)=INT (N(2)) 3010 Z1$=STR$ (Z(1)):N1$=STR$ (N(1)) 3020 Z2$=STR$ (Z(2)):N2$=STR$ (N(2)) 3030 Z3$="1":N3$=STR$ (N(3)) 3040 L1=LEN (Z1$):IF L1<LEN (N1$) THEN L1=LEN (N1$) 3050 L2=LEN (Z2$):IF L2<LEN (N2$) THEN L2=LEN (N2$) 3060 L3=LEN (N3$) 3070 IF L1>LEN (Z1$) THENZ1$=" "+Z1$:GOTO 3070 3080 IF L1>LEN (N1$) THENN1$=" "+N1$:GOTO 3080 3090 IF L2>LEN (Z2$) THENZ2$=" "+Z2$:GOTO 3090 3100 IF L2>LEN (N2$) THENN2$=" "+N2$:GOTO 3100 3110 IF L3>LEN (Z3$) THENZ3$=" "+Z3$:GOTO 3110 3120 N3$="0"+MID$ (N3$,2) 3130 RETURN 4000 PRINT"{2SPACE}";Z1$;"{3SPACE}";Z2$;"{3SPACE}";Z3$ 4010 PRINT"= "; 4020 FOR I=1 TOL1:PRINT"*";:NEXT :PRINT" + ";:FOR I=1 TOL2:PRINT"*";:NEXT :PRINT" * "; 4030 FOR I=1 TOL3:PRINT"*";:NEXT :PRINT 4040 PRINT"{2SPACE}";N1$;"{3SPACE}";N2$;"{3SPACE}";N3$ 4050 RETURN 4100 PRINT"{2SPACE}";Z2$;"{3SPACE}";Z3$ 4110 PRINT"= "; 4120 FOR I=1 TOL2:PRINT"*";:NEXT :PRINT" * "; 4130 FOR I=1 TOL3:PRINT"*";:NEXT :PRINT 4140 PRINT"{2SPACE}";N2$;"{3SPACE}";N3$ 4150 RETURN 4200 PRINT"{2SPACE}";Z2$ 4210 PRINT"= "; 4230 FOR I=1 TOL2:PRINT"*";:NEXT :PRINT 4240 PRINT"{2SPACE}";N2$ 4250 RETURN 4300 PRINT"{2SPACE}";Z1$;"{3SPACE}";Z2$ 4310 PRINT"= "; 4320 FOR I=1 TOL1:PRINT"*";:NEXT :PRINT" + "; 4330 FOR I=1 TOL2:PRINT"*";:NEXT :PRINT 4340 PRINT"{2SPACE}";N1$;"{3SPACE}";N2$ 4350 RETURN 5000 REM GGT 5010 G1=INT (G1):G2=INT (G2) 5020 IF G1<G2 THENHI=G1:G1=G2:G2=HI 5030 IF G1/G2=INT (G1/G2) THENGG=G2:RETURN 5040 Q=G1/G2:IF Q>20 THEN G1=G1-INT (Q-10)*G2 5050 IF G1=G2 THENGG=G1:RETURN 5060 IF G1>G2 THENG1=INT (G1-G2):GOTO 5050 5070 G2=INT (G2-G1):GOTO 5050