Herrscher über Leben und Tod
Es war schon immer der Reiz der Menschheit, Macht über andere auszuüben; erproben Sie Ihre Fähigkeit, über eine Stadt 65 Jahre zu regieren, lassen auch Sie sich von dieser Machtsucht erfassen und steigen Sie voll ein, in Hamurabi.
Das Programm »Hamurabi« für den C 116/ C 16 wurde dem berühmten Managementspiel »Kaiser« nachempfunden. Es geht darum, 65 Jahre lang über die Stadt Babylon zu herrschen.
Beispielsweise ist es wichtig, genügend Korn zu kaufen oder anzubauen, damit das Volk nicht verhungert...
Hamurabi läuft ohne Erweiterung. Der Spielstand kann auf Diskette gespeichert und natürlich wieder geladen werden. Wird die Frage »Altes Spiel laden?« mit JA beantwortet und es erscheint ein Disk-Error, muß überprüft werden, ob ein File mit dem alten Spielstand existiert. Erscheint keine Fehlermeldung, so wird das alte Spiel geladen. Gespeichert wird das Spiel, wenn am Ende einer Runde »S« für SAVEn eingegeben wird. Hierdurch wird ein File auf Diskette geschrieben, das alle wichtigen Daten enthält und das wieder geladen werden kann. Nach dem Programmstart wird das Titelbild aufgebaut und die Musik ertönt. Danach wird das Spiel mit »+« gestartet. Alle weiteren Anweisungen ergeben sich aus dem Programmablauf. Wir wünschen viel Spaß beim Spielen!
(do)| ES | – | Hektar Land, die eingesät werden sollen |
| BG | – | Bargeld |
| EW | – | Einwohner von Babylon |
| GM | – | Anzahl der großen Mühlen |
| JA | – | Jahr |
| KA | – | Kornbesitz |
| KK | – | Anzahl der Kornmühlen |
| LB | – | Landbesitz |
| MP | – | Anzahl der Marktplätze |
| 0 - 855 | Vorspann |
| 860 - 1100 | Hauptmenü |
| 2000 - 3100 | Auslosung des Wetters |
| 5000 - 8040 | Kauf und Verkauf von Land und Korn |
| 9000 - 9080 | Kornverteilung |
| 9100 - 9200 | Bericht über die Einnahmen |
| 9500 - 9800 | Einsäen des Landes |
| 9800 - 10000 | Mühlen, etc. kaufen |
| 10000 - 13000 | Kommentar nach Ende des Spiels |
| 15000 - 17000 | Laden und Speichern des Spielstandes |
| 17000 - 18000 | Bericht über die Stadt (wird im Programmablauf angesprungen). |
0 rem -----------------------------
1 rem -----------------------------
2 rem ---- ----
3 rem ---- dominik eisele ----
4 rem ---- ----
5 rem ---- alfred-kubin-str.13 ----
6 rem ---- ----
7 rem ---- 5090 leverkusen 1 ----
8 rem ---- ----
9 rem ---- west germany ----
10 rem ---- ----
11 rem ---- tel.0214/94695 ----
12 rem ---- ----
13 rem -----------------------------
14 rem -----------------------------
15 rem ^ rem-zeilen nicht abtippen ^
16 rem -----------------------------
17 print"{clr}{blk}{down}";:color0,11,6:color4,1,1:printchr$(8),chr$(142)
18 print"{rght}{rght} musik von "
20 print"{rght}{rght}{CBM-A}{CBM-S}{CBM-A}{CBM-S}{CBM-A}{CBM-S} {CBM-A}{CBM-S}{CBM-A}{CBM-S}{CBM-A}{CBM-S} gerald "
21 print"{rght}{rght}{SHIFT--}{CBM-Z}{CBM-X}{CBM-Z}{CBM-X}{SHIFT--} {SHIFT--}{CBM-Z}{CBM-X}{CBM-Z}{CBM-X}{SHIFT--} L{SHIFT-@} hanisch "
22 print"{rght}{rght}JI UK JI UK {SHIFT--}{SHIFT--} "
23 print"{rght}{rght} {SHIFT--} {CBM-F}{SHIFT--} {SHIFT--}{CBM-D} {SHIFT--} {SHIFT--}{SHIFT--} "
24 print"{rght}{rght} {SHIFT--} {CBM-V}{SHIFT--}{CBM-A}{CBM-S}{CBM-A}{CBM-S}{CBM-A}{CBM-S}{CBM-A}{CBM-S}{SHIFT--}{CBM-C} {SHIFT--} NM{SHIFT--}{SHIFT--} NM N "
25 print"{rght}{rght} {SHIFT--} {CBM-Z}{CBM-X}{CBM-Z}{CBM-X}{CBM-Z}{CBM-X}{CBM-Z}{CBM-X}{CBM-Z}{CBM-X} {SHIFT--}M N M{SHIFT--} NM N M N "
26 print"NM {SHIFT--} {CBM-F} {CBM-D} {SHIFT--}{SHIFT--} N MN M {SHIFT--}{CBM-L} {SHIFT--} N "
27 print"{rght}{rght}M{SHIFT--} {CBM-V} {CBM-D} UI {CBM-F} {CBM-C} {SHIFT--}{SHIFT--}N M{SHIFT--} {SHIFT--}N "
28 print"{rght}{rght} {SHIFT--} {CBM-C} KJ {CBM-V} {CBM-Q}K {CBM-A}{CBM-S}{CBM-A}{CBM-S}{CBM-A}{CBM-S}{CBM-A}{CBM-S}{SHIFT--}{CBM-L} {SHIFT--}{CBM-A}{CBM-S} "
29 print"{rght}{rght} {SHIFT--} {SHIFT--} {SHIFT--}{CBM-Z}{CBM-X}{CBM-Z}{CBM-X}{CBM-Z}{CBM-X}{CBM-Z}{CBM-X} {CBM-Z}{CBM-X}{SHIFT--} "
30 print"{rght}{rght} {SHIFT--} UI {SHIFT--} {SHIFT--} {CBM-D} {CBM-D} {CBM-D} {CBM-D} {SHIFT--} "
31 print"{rght}{rght} {SHIFT--} UI{SHIFT--}{SHIFT--}UI {SHIFT--} {SHIFT--} UI {SHIFT--} "
32 print"{rght}{rght} {CBM-Z}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-E}{CBM-E}{CBM-E}{CBM-E}{CBM-E}{CBM-E}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-X} {CBM-Z}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-E}{CBM-E}{SHIFT-*}{SHIFT-*}{CBM-X} "
97 print"{down}*dominik eisele* praesentiert :"
99 print"{rvon}{brn}+ +"
100 print"{rvon} {CBM-+} {CBM-+} {CBM-+}{CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+} {CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+}{CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+}{CBM-+} "
101 print"{rvon} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+}{CBM-+} {CBM-+} {CBM-+}{CBM-+} "
102 print"{rvon} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+}{CBM-+} "
103 print"{rvon} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+}{CBM-+} {CBM-+} {CBM-+}{CBM-+} "
104 print"{rvon} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+} {CBM-+}{CBM-+}{CBM-+}{CBM-+} {CBM-+}{CBM-+} ";
105 print"{rvon}+ +{rvof}";
106 restore 200
107 vol8
108 do
109 read x,y
110 sound1,x,y:vol0:fort=1to5:nextt:vol8
111 loop until x=0:goto 850
200 data 810,25,810,25,810,50,822,25,822,25,822,50,870,25,870,25,870,25
201 data 870,12,810,112,798,25,798,25,798,50,784,25,784,25,784,50,770,25,770,25
202 data 770,25,770,12,770,37,810,25,834,18,854,6,864,18,881,6,897,25,897,12
203 data 897,63,881,25,881,12,881,63,870,25,870,25,870,25,870,12,810,112
204 data 864,25,864,25,881,25,881,25,897,25,897,12,870,38,870,25,897,11,897,11
205 data 897,11,897,11,881,25,881,25,864,25,810,12,864,62,1,1,0,0
850 getr$:ifr$="+" then vol8:sound1,810,20:goto 860
855 goto 850
860 ka=15000:aa=0:bg=23000:ew=int(257*rnd(1))+500:lb=10000:ja=1:mp=0:kk=0:gm=0
870 kr=int(10000*rnd(1))+60000:bj=0:mp=1:bb=0
871 print"{clr}{down}{down}{down}{down}{rght}{rght}{rght}altes spiel laden ?"
872 print"{down}{rght}{rght}{rght}{rght}{rght}(j/n)"
873 getd$:ifd$="j"thenvol8:goto 15000
876 ifd$="n" then vol8:sound1,810,20:goto890
877 goto 873
890 gosub 1000
900 goto 890
1000 color 4,1,7:color0,1,1:print"{clr}"
1004 gosub 3000
1005 gosub 2000
1006 print"{clr}{red}"kr"{yel}scheffel korn werden angeboten{red}"
1007 print"{yel}{rght}ernteertraege :"int(ee)"scheffel"
1008 printvk"{yel}% eurer kornreserven sind verfault"
1009 gosub 3000
1010 bk=ew*9
1011 print"{dblu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}";
1012 print"{rght}{yel}kornreserven (scheffel) --- {lgrn}";int(ka)
1020 print"{rght}{down}{yel}benoetigtes korn --- {lgrn}";int(bk)
1030 print"{rght}{down}{yel}kornpreis (taler) --- {lgrn}";int(kp)
1040 print"{rght}{down}{yel}landpreis (taler) --- {lgrn}";int(lp)
1050 print"{rght}{down}{yel}landbesitz (hektar) --- {lgrn}";int(lb)
1060 print"{rght}{down}{yel}bargeld (taler) --- {lgrn}";int(bg)
1070 print"{dblu}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{lblu}";
1081 print"1 ----- korn kaufen ----- O{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}{CBM-Y}";
1082 print"2 ----- korn verkaufen ----- {CBM-H}weiter "
1083 print"3 ----- land kaufen ----- {CBM-H}mit"chr$(130)" {rvon}{pink}space{lblu}{rvof}"
1084 print"4 ----- land verkaufen ----- L{CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}{CBM-P}";
1088 get a$:ifa$=" " then vol8:sound1,900,10:goto 9000
1089 ifa$="1" then vol8:sound1,100,10:goto 5000
1090 ifa$="2" then vol8:sound1,150,10:goto 6000
1091 ifa$="3" then vol8:sound1,250,10:goto 7000
1092 ifa$="4" then vol8:sound1,340,10:goto 8000
1093 goto 1088
1100 return
2000 rem --- kornreserven ---
2010 k1=ka/100
2015 vk=int(100*rnd(1))
2020 ko=k1*vk
2030 ka=ka-ko
2035 if ka<=0 then ka=0
2040 return
3000 if bb=1 then printw$:return
3005 kp=int(370*rnd(1))+119
3010 if kp<192 then w$=" tolles wetter sehr reiche ernte":hl=2
3020 if kp>=192 and kp<284thenw$=" gutes wetter gewoehnliche ernte":hl=3
3030 if kp>=284 and kp<380 then w$=" regen schlechte ernte":hl=4
3040 if kp>=380 then w$=" duerre hungersnot droht":hl=5
3050 lp=int(70*rnd(1))+19
3100 bb=1:return
5000 input"{down}wieviel korn wollt ihr kaufen";km
5001 ifaa=1andkr<=0thenprint"{rvon}ihr bekommt nun kein korn mehr !!!!!!{rvof}":goto 5010
5003 if kr<=0 then kr=0
5005 if km<0 then 1006
5006 ifkm>krthengoto 5050
5007 ka=ka+km:kr=kr-km:bg=bg-km*kp/1000
5010 vol8:sound1,900,15:fort=1to500:nextt
5020 goto 1006
5050 print"{rvon}so viel korn wird nicht angeboten !{rvof}":aa=1:goto5010
6000 input"{down}wieviel korn wollt ihr verkaufen";kv
6010 if kv>ka then print"{rvon}ihr habt nicht so viel korn !!!{rvof}":goto 5010
6020 if kv<0 then 1006
6035 kr=kr+kv:ka=ka-kv:bg=bg+kv*kp/1000
6040 goto 5010
7000 input"{down}wieviel land wollt ihr kaufen";lw
7010 bg=bg-lw*lp/10
7020 lb=lb+lw
7025 if lw<0 then 1006
7030 vol8:sound1,900,15:fort=1to500:nextt
7040 return
8000 input"{down}wieviel land wollt ihr verkaufen";lv
8005 if lv>lb then print"{rvon}so viel land habt ihr nicht !!!{rvof}":goto 7030
8010 bg=bg+lp*lv/10
8020 if lv<0 then 1006
8030 lb=lb-lv
8040 goto 7030
9000 print"{clr}{wht}":color 0,1,1:color4,11,1
9005 print"{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}kornverteilung"
9010 print"{rght}{rght}{rght}{rght}{down}{down}o hamurabi von babylon ich frage"
9020 print"{rght}{rght}{rght}{rght}{down}euch, wieviel korn wollt ihr den"
9022 print"{rght}{rght}{rght}{rght}{down}hungernden zur verfuegung stellen?"
9025 print"{down}{rght}{rght}{rght}{rght}ihr besizt{red}"int(ka)"{wht}scheffel korn"
9026 print"{down}{rght}{rght}{rght}{rght}die benoetigte kornmenge ist{red}"int(bk)
9027 print"{down}{rght}{rght}{rght}{rght}{wht}die einwohnerzahl betraegt{red}"ew
9030 input"{wht}{down}{down}{rght}{rght}{rght}{rght}betrag {grn}";vs
9032 if vs>ka then vol8:sound1,150,15:goto9000
9033 if vs<0 then vol8:sound1,150,15:goto 9000
9035 ka=ka-vs
9040 vr=int(vs/ew):tw=ew
9050 vol8:sound1,350,15:gosub 9500
9055 print"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{down}{down}{down}weiter mit"chr$(130)" {rvon}{dblu}space{rvof}"
9070 gets$:ifs$=" " then vol8:sound1,900,15:goto 9100
9080 goto 9070
9100 print"{clr}{wht}":color0,11,4:color4,11,6
9101 print"{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}o hamurabi von babylon"
9102 print"{down}{rght}{rght}ich berichte euch ueber eure stadt.. "
9103 print"{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}jahr"ja
9105 print"{down}{rght}{wht}"int(tw)" {blk}einwohner sind verhungert."
9110 ifss=1 then print"{rght}{wht}"zw"{blk}einwohner sind zugewandert"
9120 ag=int(47*rnd(1))+20
9130 print"{rght}{yel}"int(ag)" {blk}einwohner wurden geboren."
9140 at=int(47*rnd(1))+20
9150 print"{rght}{yel}"int(at)" {blk}einwohner sind im alter gestorben":ew=ew+ag-at+zw-tw
9151 print"{down}{rght}{yel}eure marktplaetze brachten"int(mp*495):bg=bg+int(mp*495)
9152 print"{down}{rght}{yel}eure kornmuehlen brachten"int(kk*589):bg=bg+int(kk*589)
9153 print"{down}{rght}{yel}eure gr. kornmuehlen brachten"int(gm*678):bg=bg+(gm*678)
9154 print"{down}{rght}{blk}(angaben in talern){yel}"
9155 sv=sv+ew*2:if sv<0 then sv=0
9156 print"{down}{rght}{wht}das volk zahlte"sv"taler steuern."
9157 bg=bg+sv
9158 sv=0
9160 print"{down}{blk}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}weiter mit"chr$(130)" {rvon}space{rvof}"
9170 getc$:ifc$=" " then vol8:sound1,900,15:goto 17000
9180 goto 9170
9200 goto 10000
9500 for r=1 to 8
9510 if vr<=r then ew=int(ew-(tw/(r+r))):tw=tw-ew:return
9520 nextr
9530 if vr=>9 andvr<=25then tw=0:return
9540 for r=26 to 20000
9550 ifr=vrthen zw=int((tw*(r/2))/98):ew=int(ew+(tw*(r/2))/98):tw=0:ss=1:return
9560 nextr
9600 return
9700 print"{clr}{wht}":color 0,1,1:color 4,11,2
9705 print"{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}einsaehen"
9710 print"{down}{down}{rght}{rght}weiterhin o hamurabi frage ich euch :"
9720 print"{down}{rght}{rght}wieviel land wollt ihr einsaeen ?"
9730 print"{down}{rght}{rght}ihr besizt{red}"lb"{wht}hektar land."
9740 print"{down}{rght}{rght}ihr habt{red}"int(bg)"{wht}taler."
9745 print"{down}{rght}{rght}das einsaeen pro hektar land"
9746 print"{down}{rght}{rght}kostet{red}"hl"{wht}taler."
9750 input"{down}{rght}{rght}(hektar) ";es
9760 if es>lb then vol8:sound1,150,15:goto9700
9770 if es<0 then vol8:sound1,150,15:goto9700
9775 zf=int(24*rnd(1))+72
9780 bg=int(bg-hl*es):ka=ka+(es/hl)*zf:ee=int((es/hl)*zf):vol8:sound1,350,15
9785 print"{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}weiter mit"chr$(130)" {rvon}space{rvof}"
9795 getr$:ifr$=" " then vol8:sound1,900,15:goto 9800
9796 goto 9795
9800 print"{clr}{blk}":color 0,12,4:color4,1,4
9810 print"{rght}{rght}{rght}{rght}o edler hamurabi,"
9820 print"{rght}{rght}{rght}{down}{down}um die staatskasse aufzubessern,"
9830 print"{rght}{rght}{rght}{down}waere es von vorteil einnahmequellen"
9840 print"{rght}{rght}{rght}{down}zu errichten."
9850 print"{rght}{rght}{rght}{down}eure wahl :"
9860 iflb/(mp+kk+gm)<1000thenprint"{down}{down}{rght}{rvon}ihr benoetigt mehr bauland!{rvof}":goto 9990
9959 print"{down}{down}taler"bg
9960 input"wieviel marktplaetze - 2000 taler";tm
9961 mp=mp+tm
9962 bg=bg-tm*2000
9965 vol8:sound1,180,15
9969 print"taler"bg
9970 input"wieviel kornmuehlen - 3000 taler";tk
9971 kk=kk+tk
9972 bg=bg-tk*3000
9975 vol8:sound1,250,15
9979 print"taler"bg
9980 input"wieviel grosse muehlen - 5000 taler";tg
9981 gm=gm+tg
9982 bg=bg-tg*5000
9985 vol8:sound1,300,15
9986 print"taler"bg
9990 kr=int(10000*rnd(1))+60000
9991 if bg<0 then bj=bj+bg
9992 if bj<-90000 then 10000
9993 if ew<500 then 10000
9994 if ja=65 then 12000
9995 print"{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}s=saven!{rvof}"
9996 print"{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}weiter mit"chr$(130)" {rvon}space{rvof}"
9997 ifr$="s" then bb=0:aa=0:ss=0:ja=ja+1:gosub 16000
9998 getr$:ifr$=" " then bb=0:aa=0:ss=0:ja=ja+1:vol8:sound1,900,15:goto1000
9999 goto 9997
10000 fort=1to2000:nextt:print"{clr}{wht}":color0,1,1:color4,1,1
10005 print"{down}{down}{rght}hamurabi ich muss euch sagen,dass ihr"
10010 print"{down}{rght}ein schlechter herrscher wart."
10020 print"{down}{rght}euer volk zaehlte nach"ja"jahren"
10030 print"{down}"ew"menschen."
10040 print"{down}{rght}euer land war"lb"hektar gross und"
10050 print"{down}{rght}eure schatzkammer war mit"
10060 print"{down}{rght}"bg"talern gefuellt."
10070 print"{down}{rght}doch schaetzt eure faehigkeiten selbst"
10080 print"{down}{rght}ein und ueberlegt ob fuer euch eine"
10090 print"{down}{rght}wiederwahl in frage kommt....."
10095 gosub10500
10100 print"{down}{rght}({rvon}j{rvof}a/{rvon}n{rvof}ein)"
10110 getf$:iff$="j" then vol8:sound1,700,20:run
10120 iff$="n" then vol8:sound1,200,20:print"{clr}":goto 13000
10130 goto10110
10500 restore 10510
10505 vol8
10510 do
10515 read x,y
10516 sound1,x,y:vol0:fort=1to5:nextt:vol8
10517 loop until x=0:return
10518 data 453,60,453,45,453,15,453,60
10519 data 488,45,345,15,453,45,345,15,453,45,345,15,453,120,1,1,0,0
12000 fort=1to2000:nextt:print"{clr}{wht}":color0,1,1:color4,1,1
12010 print"{down}{down}{rght}hamurabi von babylon ich sage euch"
12020 print"{down}{rght}nachdem ihr 65 jahre lang der stadt"
12030 print"{down}{rght}vorgestanden habt wird es nun"
12040 print"{down}{rght}schwer sein einen ebenbuertigen"
12050 print"{down}{rght}nachfolger zu finden."
12060 print"{down}{rght}ihr wart seit jahrhunderten der beste"
12065 print"{down}{rght}herrscher ueber b a b y l o n !!!!!"
12070 print"{down}{down}{rght}{rght}landbesitz :"lb"hektar."
12080 print"{rght}{rght}bargeld :"bg"taler."
12090 print"{rght}{rght}einwohner :"ew
12091 gosub12500
12095 print"{down}{down}{rght}{rght}{rvon}{red}space{rvof}{wht} druecken..."
12100 getaa$:ifaa$=" "then print"{clr}":sound1,300,20:goto13000
12110 goto12100
12500 restore12520:vol8
12510 do
12515 read x,y
12516 sound1,x,y:vol0:fort=1to4:nextt:vol8
12517 loop until x=0:return
12520 data 596,20,596,20,704,20,739,20,770,40,704,10,685,10,643,20,784,20
12521 data 784,20,784,40,770,10,784,10,810,30,704,10,704,20,704,20,685,20
12522 data 704,20,739,100,596,10,596,10,596,20,704,20,739,20,770,40,704,10
12523 data 685,10,643,20,784,20,784,20,784,40,784,10,784,10,770,30,739,10,704,20
12524 data 596,20,685,20,739,20,704,100,810,20,834,20,834,20,834,20,834,20
12525 data 854,30,864,10,810,20,810,20,810,20,770,40,810,10,810,10,864,30
12526 data 810,10,810,20,810,20,784,20,770,20,739,100,810,10,810,10,834,20
12527 data 834,20,834,20,834,20,854,20,864,20,810,30,810,10,810,20,770,40
12528 data 810,10,810,10,864,30,810,10,810,20,810,20,784,20,770,20,810,100
12529 data 1,1,0,0
12590 end
13000 print"{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}{grn}!spielende!{rvof}":fort=1to60:nextt:goto13000
14000 end
15000 rem --- laden ---
15010 open 2,8,2,"0:ham.seq.,s,r":open15,8,15:input#15,en,em$,et,es
15020 input#2,aa,bb,bg,ee,ew,gm
15030 input#2,ja,ka,kk,lb,mp,ss
15040 print"{down}{down}{down}{rght}{rght}{rght}"
15041 if em$="ok"thenprint"ok":close2,8,2:close15:fort=1to1000:nextt:em$="":goto 890
15042 ifem$<>"ok"thenprint"disk error":close2:close15:fort=1to1000:next:goto871
16000 rem --- saven ---
16005 open 2,8,2,"@:ham.seq.,s,w"
16010 print#2,aa:print#2,bb:print#2,bg:print#2,ee:print#2,ew:print#2,gm
16020 print#2,ja:print#2,ka:print#2,kk:print#2,lb:print#2,mp:print#2,ss
16030 close2,8,2:print"{home}{rght}{rght}{rght}{rght}{rght}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"ds$:return
17000 print"{clr}{wht}":color 0,1,1:color4,1,1
17005 vol8:sound1,400,60:fort=1to5:nextt:sound1,500,70
17010 print"{down}{down}{down}weiterhin ereignete sich in diesem jahr:"
17022 pp=int(8*rnd(1))+1
17030 if pp=1then print"{down}{down}eure feinde nahmen euch bei einem":lb=lb-1000
17031 ifpp=1thenprint"{down}{down}raubzug 1000 hektar des landes.":goto17090
17040 ifpp=2thenprint"{down}{down}eine hungersnot bedrohte eure buerger":ew=ew-50
17041 ifpp=2thenprint"{down}{down}und nahm euch weitere 50 einwohner.":goto17090
17050 ifpp=3thenprint"{down}{down}die pest zog ueber die stadt und nahm":ew=ew-40
17051 ifpp=3thenprint"{down}{down}euch 40 steuerzahler.":goto 17090
17060 ifpp=4thenprint"{down}{down}ein sandsturm verwuestete die stadt.":bg=bg-5000
17061 ifpp=4thenprint"{down}{down}fuer eine saeuberung zahlt 5000 taler.":goto 17090
17070 ifpp=5thenprint"{down}{down}ihr habt durch eine gewonnene schlacht":lb=lb+1500
17071 ifpp=5thenprint"{down}{down}1500 hektar land dazu bekommen.":goto 17090
17080 ifpp>5thenprint"{down}{down}ihr habt glueck,es geschah nichts"
17081 ifpp>5thenprint"{down}{down}besonderes.":goto 17090
17090 print"{down}{down}{down}{down}{red}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}weiter mit"chr$(130)" {rvon}space{rvof}"
17091 getc$:ifc$=" " then vol8:sound1,900,15:goto 9700
17092 goto 17091
18000 end
Diesen Artikel als PDF herunterladen
Diesen Artikel auf Mastodon teilen