Monopoly mit Computer

petcat | Checksummer

10 rem  ******************************
11 rem  *                            *
12 rem  * commercial town   fuer c64 *
13 rem  *                            *
14 rem  * von : peter fink           *
15 rem  *       8500 nuernberg 30    *
16 rem  *       stephanstrasse 20    *
17 rem  *       tel.: 0911/467930    *
18 rem  *                            *
19 rem  ******************************
99 print"{clr}";
100 dimsn$(41)
150 poke53281,0:poke53280,0
200 sn$(0)=""
205 sn$(1)="     c o m m e r c i a l   t o w n"
210 sn$(2)="     DDDDDDDDDDDDDDDDDDDDDDDDDDDDD"
215 sn$(3)=""
220 sn$(4)="        peter fink, februar 1985"
225 sn$(5)=""
230 sn$(6)="dieses spiel laeuft nach den originalen"
235 sn$(7)="monopoly-regeln. es koennen 1 - 4 spie-"
240 sn$(8)="ler teilnehmen. die auf 4 spieler feh-"
245 sn$(9)="lenedn werden vom computer simuliert."
250 sn$(10)="bei der eingabe von strassennamen brau-"
255 sn$(11)="chen nur die ersten drei buchstaben"
260 sn$(12)="eingegeben zu werden."
265 sn$(13)="               ausnahmen:"
270 sn$(14)="schillerstrasse und schlossallee: 4"
275 sn$(15)="hauptbahnhof und hauptstrasse:    6"
280 sn$(16)=""
285 sn$(17)="1 hotel entspricht 5 haeusern, das"
290 sn$(18)="heisst auch beim kauf und verkauf von"
295 sn$(19)="haeusern muessen hotels als 5 haeuser"
300 sn$(20)="eingegeben werden."
305 sn$(21)=""
310 sn$(22)=""
315 sn$(23)="            weiter -> [space]"
320 sn$(24)=""
325 sn$(25)="bei der abfrage nach den aktivitaeten"
330 sn$(26)="des spielers vor dem wuerfeln kann fol-"
335 sn$(27)="gende auswahl getroffen werden:"
340 sn$(28)="> h < wenn er haeuser kaufen will"
345 sn$(29)="> z < wenn er eine hypothek zurueck-"
350 sn$(30)="                           zahlen will."
355 sn$(31)="> k < wenn er einem mitspieler ein ver-"
360 sn$(32)="      kaufs- oder tauschangebot machen"
362 sn$(34)="> w < wenn er wuerfeln will."
365 sn$(33)="                                  will."
370 sn$(35)=""
375 sn$(36)="steht im feld 'standort': {red}{rvon}gefaengnis #{rvof}{grn}"
380 sn$(37)="so heisst das, dass der spieler nicht"
385 sn$(38)="nur zu besuch sondern echt im gefaeng-"
390 sn$(39)="nis ist."
395 sn$(40)=""
400 sn$(41)="            start -> [space]"
420 fora=0to22:print"{orng}"sn$(a):next
422 gosub25000:printsn$(23)
425 geta$:ifa$<>" "then425
430 print"{clr}";:fora=24to40:print"{grn}"sn$(a):next
440 gosub25090:printsn$(41)
510 sn$(0)="{lred}UCCC{CBM-R}CCCCCCCCCC{CBM-R}CCCI{brn}UCCCCCCCCCCCCCCCCCCI"
520 sn$(1)="{lred}B***B  {yel}besitz{lred}  B***B{brn}B{wht}    standort:     {brn}B"
530 sn$(2)="{lred}{CBM-Q}CCCK  {blu}EEEEEE{lred}  JCCC{CBM-W}{brn}B                  B"
540 sn$(3)="{lred}B                  B{brn}B                  B"
550 sn$(4)="{lred}B                  B{brn}B                  B"
560 sn$(5)="{lred}B                  B{brn}{CBM-Q}CCCCCCCCCCCCCCCCCC{CBM-W}"
570 sn$(6)="{lred}B                  B{brn}B{cyn}{rvon}                  {rvof}{brn}B"
580 sn$(7)="{lred}B                  B{brn}B{cyn}{rvon}                  {rvof}{brn}B"
590 sn$(8)="{lred}B                  B{brn}B{cyn}{rvon}                  {rvof}{brn}B"
600 sn$(9)="{lred}B                  B{brn}B{cyn}{rvon}                  {rvof}{brn}B"
610 sn$(10)="{lred}B                  B{brn}B{cyn}{rvon}                  {rvof}{brn}B"
620 sn$(11)="{lred}B                  B{brn}B{cyn}{rvon}                  {rvof}{brn}B"
630 sn$(12)="{lred}B                  B{brn}B{cyn}{rvon}                  {rvof}{brn}B"
640 sn$(13)="{lred}B                  B{brn}JCCCCCCCCCCCCCCCCCCK"
650 sn$(14)="{lred}B                  B {red}spieler            "
660 sn$(15)="{lred}B                  B{grn}{rvon}{CBM-K}       {rvof}{CBM-K} {orng}UCCCCCCCI "
670 sn$(16)="{lred}B                  B{grn}{rvon}{CBM-K}       {rvof}{CBM-K} {orng}B{brn} zeit: {orng}B "
680 sn$(17)="{lred}B                  B{grn}{CBM-C}{rvon}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{rvof}{CBM-V} {orng}B       B "
690 sn$(18)="{lred}B                  B {yel}kapital  {orng}JCCCCCCCK "
700 sn$(19)="{lred}B                  B{pur}{rvon}{CBM-K}       {rvof}{CBM-K}           "
710 sn$(20)="{lred}B                  B{pur}{rvon}{CBM-K}       {rvof}{CBM-K} {blu}UCCCCCCCI "
720 sn$(21)="{lred}B                  B{pur}{CBM-C}{rvon}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{CBM-I}{rvof}{CBM-V} {blu}B{gry2}frei p.{blu}B "
730 sn$(22)="{lred}B                  B {lgrn}{rvon}Q Q{rvof} {rvon}  Q{rvof}  {blu}B       B "
740 sn$(23)="{lred}B                  B {lgrn}{rvon}   {rvof} {rvon} Q {rvof}  {blu}JCCCCCCCK "
750 sn$(24)="{lred}JCCCCCCCCCCCCCCCCCCK {lgrn}{rvon}Q Q{rvof} {rvon}Q  {rvof}           "
775 geta$:ifa$<>" "then775
776 print"{clr}";
780 fora=0to24:printsn$(a);:next
795 poke56295,14:poke2023,102
1000 gosub25220
1100 gosub10900:gosub10800:print"{down}dauer des spieles":gosub10800
1105 print"{down}{down}    (in min.)":gosub10800
1110 print"{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}";:b$=""
1111 geta$:ifa$<>chr$(20)then1114
1112 iflen(b$)>0thenprint"{left}{rvon} {left}";:b$=left$(b$,len(b$)-1)
1113 goto1111
1114 ifa$<>""anda$<>chr$(13)thenifasc(a$)<48orasc(a$)>57then1111
1115 printa$;:ifa$=chr$(13)andlen(b$)>0then1118
1116 b$=b$+a$:goto1111
1118 ru=val(b$)
1120 gosub10900:gosub10800
1125 print"{down}anzahl der spieler":gosub10800
1130 print"{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rvon}";:b$=""
1131 geta$:ifa$<>chr$(20)anda$<>chr$(13)anda$<>""thenprinta$"{left}";:b$=a$
1132 ifa$=chr$(13)andlen(b$)=1then1134
1133 goto1131
1134 ifasc(b$)<48orasc(b$)>52then1120
1135 an=val(b$)
1140 gosub10900:ifan=0then1180
1145 fora=1toan
1150 print"{home}"sr$su$"{cyn}{rvon}  name spieler "a
1155 printsr$"{up}{rvon}(bis zu 7 buchst.)
1156 print"{home}"su$sr$"{down}{down}{rvon}anm.: verschiedene{down}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}";
1157 print"{rvon}anfangsbuchstaben{down}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}";
1158 print"{rvon}waeren von vorteil"
1160 printsr$"{rght}{rght}{rght}{rght}{rght}{rvon}";:b$=""
1161 geta$:ifa$<>chr$(20)then1164
1162 iflen(b$)>0thenprint"{left}{rvon} {left}";:b$=left$(b$,len(b$)-1)
1163 goto1161
1164 iflen(b$)>=7then1168
1165 ifa$=chr$(13)then1167
1166 printa$;:b$=b$+a$:goto1161
1167 iflen(b$)=0then1161
1168 sp$(a)=b$:gosub10900
1170 nexta
1175 ifan=4then1200
1180 b=1:fora=an+1to4
1185 sp$(a)=na$(b):b=b+1
1190 nexta
1195 sp$(5)="bank"
1200 fora=1to40:sb(a)=0:next
1205 fora=1to4:po(a)=1:next
1210 bb$(0)=" ":bb$(1)="1":bb$(2)="2":bb$(3)="3":bb$(4)="4":bb$(5)="A"
1215 fora=1to4:s$(a)=left$(sp$(a),1):next
1220 fp=0:ez=1:gz=1
2995 ti$="000000":gosub20000
3000 forz=1to4:ll=0:p=0:wp$="":ifpo(z)=0then3995
3010 gosub7000
3015 gosub6000
3020 gosub10000
3025 gosub5000
3030 gosub8000
3035 ifpg(z)=1then21000
3040 ifz>anthengosub13000:goto3100
3042 gosub10900
3045 print"{home}"sr$su$"{cyn}{rvon} * aktivitaeten *"
3050 print"{home}"sr$su$"{rvon}{down}{down}haus kaufen   -> h"
3051 print"{home}"sr$su$"{rvon}{down}{down}{down}hyp. z'zahlen -> z"
3052 print"{home}"sr$su$"{rvon}{down}{down}{down}{down}angeb. mitsp. -> k"
3053 print"{home}"sr$su$"{rvon}{down}{down}{down}{down}{down}wuerfeln      -> w"
3054 tm$=ti$
3055 geta$:ifa$=""then3055
3057 ti$=tm$
3060 ifa$="h"thengosub10900:gosub12000:goto3042
3065 ifa$="z"thengosub10900:gosub11000:goto3042
3070 ifa$="k"thengosub10900:gosub16000:goto3042
3075 ifa$<>"w"then3045
3100 gosub22000
3105 gosub9000
3110 gosub5000
3200 iflo=1andpo(z)<>1theni=4000:goto3210
3205 iflo=1andpo(z)=1theni=8000:goto3210
3206 goto3220
3210 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" bekommt"
3215 gosub10800:print"{down}{down}"i"dm."
3216 ge(z)=ge(z)+i
3218 lo=0:fora=1to1500:next
3220 ifpo(z)=5orpo(z)=39thengosub20500
3225 ifpo(z)=8orpo(z)=23orpo(z)=37then23000
3230 ifpo(z)=3orpo(z)=18orpo(z)=34then23100
3235 ifz2=1thenz2=0:goto3995
3240 ifpo(z)=11thengosub10900:goto3285
3245 ifpo(z)=21thengosub10900:gosub10800:print"{rght}{down}"sp$(z)" bekommt"
3250 ifpo(z)=21thengosub10800:print"{down}{down}"fp"dm."
3255 ifpo(z)=21thenge(z)=ge(z)+fp:fp=0
3260 ifpo(z)=31thenpg(z)=1:wu=20:goto3105
3265 iffa(po(z))=10thengosub24000
3270 iffa(po(z))=9thengosub24200
3275 iffa(po(z))>0andfa(po(z))<9thengosub24400
3280 ifz2=1thenz2=0:goto3995
3285 gosub7000:gosub20000
3287 fora=1to1000:next
3290 ifwp$="pasch"andpg(z)=0then3400
3295 goto3990
3400 ifz<=anthen3100
3410 gosub10900:gosub10800:print"{down}{rght}pasch: nochmal!":fora=1to1500:next:goto3100
3990 fora=1to1000:next
3992 gosub10900
3995 nextz:iftt>ruthen27100
3996 goto3000
5000 print"{home}{rvof}"left$(re$,22);"{down}{down}{down}{lgrn}                 {down}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}";
5005 print"                 "
5010 print"{home}"left$(re$,22);"{down}{down}{down}{lgrn}{rvon}";sn$(po(z))" "bb$(sb(po(z)))"{rvof}";
5015 ifpg(z)=1thenprint"{left}#"
5020 iffa(po(z))>0thenprint"{home}"left$(re$,22)"{down}{down}{down}{down}{lred}besitzer: "sp$(be(po(z)))
5025 fora=1to100:next
5030 print"{home}{rvof}"left$(re$,22);"{down}{down}{down}{lgrn}                 {left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}";
5035 print"{home}"left$(re$,22);"{down}{down}{down}{lgrn}";sn$(po(z))" "bb$(sb(po(z)));
5040 ifpg(z)=1thenprint"{left}{rvon}#{rvof}"
5050 return
6000 print"{home}{grn}"left$(re$,21);left$(un$,16);"{rvon}       {rvof}"
6010 print"{home}{grn}"left$(re$,21);left$(un$,16);"{rvon}"sp$(z)"{rvof}"
6015 return
7000 ge(z)=int(ge(z)/10)*10:g$=right$(str$(ge(z)),len(str$(ge(z)))-1)
7005 print"{home}{pur}"left$(re$,21);left$(un$,20);"{rvon}       {rvof}"
7010 print"{home}{pur}"left$(re$,21);left$(un$,20);"{rvon}"g$"{rvof}"
7015 return
8000 zl=4:j=1
8002 forb=0toko(j)-1:i=st(j,b)
8005 ifbe(i)<>zthen8020
8007 ifzl=22thengosub8200
8010 print"{home}"left$(un$,zl)"{rght}"fa$(fa(i))"{rvon}              {rvof} - "bb$(sb(i));
8011 ifhy(i)=1thenprint"{left}h";
8012 print"{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{rvon}"sn$(i):zl=zl+1
8020 nextb
8025 j=j+1:ifj=11thenreturn
8030 goto8002
8200 ifz>anthen8300
8202 print"{home}"left$(un$,zl+1)"{rght}{gry3}weiter mit <space>"
8204 tm$=ti$
8205 geta$:ifa$=""then8205
8206 ti$=tm$
8210 gosub10000:zl=4:return
8300 fora=1to2000:next:goto8210
9000 fora=1toabs(wu):q=0
9005 fori=1to4:ifi=zthen9015
9010 ifpo(z)=po(i)thenq=1:j=i
9015 nexti
9020 ifq=0then9030
9025 ifasc(s$(j))<65thenpokekn(po(z))+54272,1:pokekn(po(z)),asc(s$(j)):goto9050
9027 pokekn(po(z))+54272,1:pokekn(po(z)),asc(s$(j))-64:goto9050
9030 pokekn(po(z))+54272,fb(po(z)):pokekn(po(z)),ze(po(z))
9050 po(z)=po(z)+sgn(wu)
9055 ifpo(z)>40thenpo(z)=po(z)-40:ifll=0andpg(z)=0thenlo=1
9060 ifasc(s$(z))<65thenpokekn(po(z))+54272,1:pokekn(po(z)),asc(s$(z)):goto9070
9065 pokekn(po(z))+54272,1:pokekn(po(z)),asc(s$(z))-64
9070 nexta:return
10000 print"{home}{rvof}{down}{down}{down}{rght}";
10005 fora=1to20
10010 print"                  {down}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}";
10015 next
10020 return
10800 print"{home}"su$sr$"{cyn}{rvon}";:return
10900 print"{home}"su$sr$lo$lp$lq$:return
11000 gosub10900:gosub10800:print"{down}{rght}auf welcher":gosub10800
11002 print"{down}{down}{rght}strasse willst du":gosub10800:print"{down}{down}{down}{rght}eine hypothek"
11004 gosub10800:print"{down}{down}{down}{down}{rght}zurueckzahlen ?"
11010 gosub19000:gosub10800:print"{down}{down}{down}{down}{down}{rght}auf "at$(i):iffe=1then11025
11020 ifhy(i)=1andge(z)>=.6*pr(i)then11030
11025 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}falsche eingabe!":goto11050
11030 hy(i)=0:ge(z)=ge(z)-.6*pr(i)
11035 kp(z,fa(i))=kp(z,fa(i))+1
11040 gosub10000:gosub8000:gosub7000
11050 fora=1to1500:next:return
12000 gosub10900:gosub10800
12005 print"{down}{rght}auf welche":gosub10800:print"{down}{down}{rght}strassen willst":gosub10800
12010 print"{down}{down}{down}{rght}du haeuser bauen?":gosub10800:print"{down}{down}{down}{down}{rght}(die 1. angeben)"
12015 gosub19000:iffe=1then12500
12020 ifbe(i)<>zthen12500
12025 ifi>38then12500
12027 iffa(i)<1orfa(i)>8then12500
12030 r=i
12035 w(0)=0:w(1)=0:w(2)=0
12040 forj=0toko(fa(r))-1:b(j)=st(fa(r),j):b$(j)=sn$(st(fa(r),j))
12045 ifbe(b(j))<>zthenq=1
12050 nextj
12055 ifq=1thenq=0:goto12500
12065 gosub10900:gosub10800:print"{down}{rght}{rght}{rght}wieviele auf .."
12070 fori=0toko(fa(r))-1
12075 gosub10800:printleft$(un$,i+2)"{rght}"b$(i);
12080 getw$(i):ifw$(i)=""then12080
12085 ifasc(w$(i))<48orasc(w$(i))>53then12080
12090 gosub10800:printleft$(un$,i+2)"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}"w$(i):w(i)=val(w$(i))
12095 nexti
12097 ifabs(sb(b(0))+w(0)-sb(b(1))-w(1))>1then12500
12100 ifko(fa(r))=3andabs(sb(b(1))+w(1)-sb(b(2))-w(2))>1then12500
12105 ifko(fa(r))=3andabs(sb(b(0))+w(0)-sb(b(2))-w(2))>1then12500
12110 fori=0toko(fa(r))-1
12115 ifsb(b(i))+w(i)>5thenq=1
12120 nexti
12125 ifq=1thenq=0:goto12500
12130 py=int((fa(r)+1)/2)*1000*(w(0)+w(1)+w(2))
12135 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}preis:"py:gosub19500
12140 ifpj=1thenreturn
12145 fori=0toko(fa(r))-1
12150 sb(b(i))=sb(b(i))+w(i)
12155 gt=gt+w(i)
12160 nexti
12165 ge(z)=ge(z)-py:gosub7000:gosub10000:gosub8000:fora=1to2000:next:return
12500 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}falsche eingabe!":fora=1to2000:next:return
13000 gosub13900:gosub14000:ifs2=1then13900
13005 gosub15000:ifs2=1thengosub13900
13010 gosub13100:return
13100 j=0:k=0:m2=9:kj=0
13105 l(0)=0:l(1)=0
13110 fori=1to8
13115 ifkp(z,i)=ko(i)thenk(j)=i:j=j+1:k=1
13120 nexti:ifk=0then13400
13125 fork=1toj
13130 ifge(z)<gt*200+rnd(1)*5000orge(z)<3*(int((k(j-1)+1)/2)*1000)then13400
13135 h=int((rnd(1)/4+.5)*ge(z))
13140 m=int(rnd(1)*j):ifm=m2thenm=m+1:ifm=jthenm=0
13145 n=int(h/((int((k(m)+1)/2)*1000)))
13150 ifn=0then13345
13155 m2=m
13160 fori=0toko(k(m))-1
13165 b$(i)=sn$(st(k(m),i)):b(i)=st(k(m),i):nexti
13190 y=sb(b(0))+sb(b(1))-(sb(b(2))*(ko(k(m))=3))
13195 ify+n>5*ko(k(m))thenn=5*ko(k(m))-y
13200 ifn=0then13345
13210 ifko(k(m))=2then13250
13215 ifsb(b(0))=sb(b(1))andsb(b(0))=sb(b(2))then13230
13220 ifsb(b(1))<sb(b(2))andsb(b(1))<sb(b(0))thenl(1)=1:n=n-1:goto13230
13225 ifsb(b(0))=sb(b(1))andsb(b(1))<sb(b(2))thenl(0)=1:l(1)=1:n=n-2
13230 ifint(n/3)=n/3thenc(0)=n/3:c(1)=c(0):c(2)=c(0)
13235 ifint((n+2)/3)=(n+2)/3thenc(0)=int(n/3):c(1)=c(0):c(2)=c(0)+1
13240 ifint((n+1)/3)=(n+1)/3thenc(0)=int(n/3)+1:c(1)=c(0)-1:c(2)=c(0)
13245 c(0)=c(0)+l(0):c(1)=c(1)+l(1):n=n+l(0)+l(1):goto13272
13250 ifsb(b(0))=sb(b(1))then13260
13255 l(0)=1:n=n-1
13260 ifint(n/2)=n/2thenc(0)=n/2:c(1)=c(0)
13265 ifint((n+1)/2)=(n+1)/2thenc(0)=int(n/2):c(1)=c(0)+1
13270 c(0)=c(0)+l(0):n=n+l(0)
13272 forg=0toko(k(m))-1
13273 ifc(g)+sb(b(g))>5thenn=n-(c(g)+sb(b(g))-5):c(g)=5-sb(b(g))
13274 nextg:ifn=0then13345
13275 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" kauft":gosub10800
13280 print"{down}{down}{rght}haeuser:   auf.."
13285 l(0)=0:l(1)=0
13290 forg=0toko(k(m))-1
13295 gosub10800:printleft$(un$,g+4)"{rght}"b$(g)
13300 gosub10800:printleft$(un$,g+4)"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}"c(g)
13305 nextg
13310 fori=0toko(k(m))-1
13315 sb(b(i))=sb(b(i))+c(i)
13320 gt=gt+c(i)
13325 nexti
13330 ge(z)=ge(z)-n*int((k(m)+1)/2)*1000
13335 xj=j:gosub7000:gosub10000:gosub8000:j=xj
13340 fora=1to2000:nexta
13345 nextk
13400 return
13900 gosub10900
13910 gosub10800:print"{down}{rght}* aktivitaeten *":return
14000 i=0:s2=0
14010 i=i+1:if(be(i)<>zorhy(i)=0)andi<40then14010
14020 ifi<40then14060
14030 ifbe(40)=zandhy(40)=1then14060
14040 ifs2=1thengosub7000:gosub10000:gosub8000
14050 return
14060 ifge(z)<.8*pr(i)then14040
14070 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" zahlt":gosub10800
14075 print"{down}{down}{rght}hypothek auf "at$(i):gosub10800:print"{down}{down}{down}{rght}"sn$(i)
14078 gosub10800:print"{down}{down}{down}{down}{rght}zurueck.
14080 ge(z)=ge(z)-.6*pr(i):hy(i)=0:s2=1
14085 kp(z,fa(i))=kp(z,fa(i))+1
14090 fora=1to1500:next
14095 ifi=40then14040
14100 goto14010
15000 s2=0:n=0
15005 fori=1to8:a$="":z4=0:z5=0:z6=0:z7=0:ifn>=2then15090
15010 ifkp(z,i)=ko(i)orkp(z,i)=0then15090
15015 forj=1to4:ifj=zorz4<>0then15025
15020 ifkp(j,i)>0thenz4=j
15025 nextj
15030 ifz4=0then15090
15035 fork=1to8:ifk=iorz5<>0then15045
15040 if(kp(z4,k)=1orkp(z4,k)=2andko(k)=3)andkp(z,k)=1thenz5=k
15045 nextk
15050 ifz5=0then15069
15055 m=-1
15057 m=m+1:ifbe(st(i,m))<>z4then15057
15060 z7=st(i,m):m=-1
15062 m=m+1:ifbe(st(z5,m))<>zthen15062
15065 z6=st(z5,m):gosub17500:n=n+1:s2=1:goto15090
15069 m=-1
15070 m=m+1:ifbe(st(i,m))<>z4then15070
15075 z7=st(i,m):pt=int((pr(z7)*(1.9+rnd(1)*1.4))/100)*100
15080 ifge(z)<ptthen15090
15085 gosub17000:s2=1:n=n+1
15090 ifa$="j"thengosub10000:gosub8000:gosub7000
15092 nexti
15095 ifs2=1thenfora=1to3000:next
15097 return
16000 n=0
16002 n=n+1:ifn=3then16500
16005 gosub10900:gosub10800:print"{down}{rght}welche strasse":gosub10800
16006 print"{down}{down}{rght}willst du ?"
16010 gosub19000:iffe=1then16500
16012 fora=1to800:next
16015 z7=i
16020 ifsb(i)>0then16500
16030 forj=0toko(fa(j))-1:b(j)=st(fa(i),j)
16035 nextj
16040 ifsb(b(1))>0then16500
16045 ifm=3andsb(b(2))>0then16500
16050 gosub10900:gosub10800:print"{down}{rght}von wem willst":gosub10800
16051 print"{down}{down}{rght}du "ar$(z7):gosub10800:print"{down}{down}{down}{rght}"sn$(z7)" ?"
16055 z4=0
16060 tm$=ti$
16065 geta$:ifa$=""then16065
16066 ti$=tm$
16070 fork=1to4:ifk=zthen16075
16072 ifa$=left$(sp$(k),1)thenz4=k
16075 nextk
16080 ifz4=0orz4<>be(i)then16500
16085 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}"sp$(z4)
16088 fora=1to1000:next
16090 gosub10900:gosub10800:print"{down}{rght}willst du":gosub10800
16095 print"{down}{down}{rght}kaufen (v) oder":gosub10800:print"{down}{down}{down}{rght}tauschen (t) ?"
16099 tm$=ti$
16100 geta$:ifa$<>"v"anda$<>"t"then16100
16101 ti$=tm$
16105 ifa$="t"then16140
16110 gosub10800:print"{down}{down}{down}{down}{rght}zu welchem preis?"
16113 b$=""
16115 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}dm ";
16116 geta$:ifa$<>chr$(20)then16119
16117 iflen(b$)>0thenprint"{left}{rvon} {left}";:b$=left$(b$,len(b$)-1)
16118 goto16116
16119 ifa$<>""anda$<>chr$(13)thenifasc(a$)<48orasc(a$)>57then16116
16120 printa$;:ifa$=chr$(13)andlen(b$)>0then16122
16121 b$=b$+a$:goto16116
16122 pt=val(b$)
16125 gosub17000
16130 ifa$="j"thengosub10000:gosub8000:gosub7000
16135 fora=1to3000:next:return
16140 gosub10800:print"{down}{down}{down}{down}{rght}gegen welche ?":gosub19000:iffe=1then16500
16145 z6=i:j=i
16150 ifbe(j)<>zthen16500
16155 fork=0toko(fa(j))-1:b(k)=st(fa(j),k)
16160 nextk
16165 ifsb(j)>0orsb(b(1))>0then16500
16170 ifm=2andsb(b(2))>0then16500
16180 gosub17500:goto16130
16500 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}falsche eingabe!":fora=1to1500:next:gosub10900
16510 return
17000 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" will":gosub10800
17002 print"{down}{down}{rght}von "sp$(z4)" "ar$(z7)
17005 a$=""
17010 gosub10800:print"{down}{down}{down}{rght}"sn$(z7):gosub10800:print"{down}{down}{down}{down}{rght}fuer dm"pt
17015 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}(j/n)?"
17020 ifz4>anthen17100
17024 tm$=ti$
17025 geta$:ifa$=""then17025
17026 ti$=tm$
17030 ifa$="j"then17050
17035 ifa$="n"then17045
17040 goto17024
17045 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}nein!":return
17050 ifge(z)<ptthengosub10800:print"{down}{down}{down}{down}{down}{down}{rght}zu wenig geld! "
17051 ifge(z)<ptthenreturn
17055 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}ja!"
17060 be(z7)=z
17061 ifhy(z7)=0thenkp(z,fa(z7))=kp(z,fa(z7))+1
17063 ifhy(z7)=0thenkp(z4,fa(z7))=kp(z4,fa(z7))-1
17065 ge(z)=ge(z)-pt:ge(z4)=ge(z4)+pt:return
17100 ifkp(z,fa(z7))=ko(fa(z7))-1thena$="n"
17105 ifkp(z4,fa(z7))>1thena$="n"
17110 m=0
17115 forj=1to8:ifkp(z4,j)=ko(j)thenm=m+1
17120 nextj:ifm<2andpt<3*pr(z7)thena$="n"
17125 ifpt<2*pr(z7)thena$="n"
17130 ifpt>3*pr(z7)andrnd(1)<.5thena$="n"
17132 ifge(z4)>3000thena$="n"
17135 ifa$<>"n"thena$="j"
17140 goto17030
17500 r=pr(z7)-pr(z6):a$=""
17505 ifr>0andge(z)<rthenreturn
17510 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" will":gosub10800
17512 print"{down}{down}{rght}von "sp$(z4)" "ar$(z7):gosub10800
17513 ifr>=0then17520
17515 print"{down}{down}{down}{rght}"sn$(z7)" +":gosub10800:print"{down}{down}{down}{down}"abs(r)"dm gegen "ar$(z6)
17517 gosub10800:print"{down}{down}{down}{down}{down}{rght}"sn$(z6)
17518 goto17525
17520 gosub10800:print"{down}{down}{down}{rght}"sn$(z7):gosub10800:print"{down}{down}{down}{down}{rght}gegen dm"abs(r)
17522 gosub10800:print"{down}{down}{down}{down}{down}{rght}+ "sn$(z6)
17525 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}(j/n)?"
17530 ifz4>anthen17600
17534 tm$=ti$
17535 geta$:ifa$=""then17535
17536 ti$=tm$
17540 ifa$="j"then17555
17545 ifa$="n"then17552
17550 goto17534
17552 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}nein!":return
17555 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}ja!"
17556 ifr>0andge(z)<rthengosub10800:print"{down}{down}{down}{down}{down}{down}{rght}zu wenig geld":goto17575
17557 ifr<0andge(z4)<(-r)thengosub10800:print"{down}{down}{down}{down}{down}{down}{rght}zu wenig geld":goto17575
17560 be(z7)=z:be(z6)=z4
17561 ifhy(z7)=0thenkp(z,fa(z7))=kp(z,fa(z7))+1
17563 ifhy(z7)=0thenkp(z4,fa(z7))=kp(z4,fa(z7))-1
17565 ifhy(z6)=0thenkp(z4,fa(z6))=kp(z4,fa(z6))+1
17567 ifhy(z6)=0thenkp(z,fa(z6))=kp(z,fa(z6))-1
17570 ge(z)=ge(z)-r:ge(z4)=ge(z4)+r
17575 return
17600 ifkp(z,fa(z7))-ko(fa(z7))<=kp(z4,fa(z6))-ko(fa(z6))thena$="j"
17602 ifa$<>"j"thena$="n"
17605 ifr<0andge(z4)<abs(r)thena$="n"
17610 goto17540
18000 ifge(z)<z9then18015
18005 ifz>anthengosub10000:gosub8000
18010 v=0:fora=1to1000:next:return
18015 q=0
18020 fori=1to40
18025 ifbe(i)=zthenq=1
18030 nexti
18035 ifq=0then27000
18040 gosub18100:gosub7000:goto18000
18100 ifz>anthen18500
18105 gosub10900:gosub10800:print"{down}haeuser verk. -> v"
18110 gosub10800:print"{down}{down}hypothek aufn.-> h"
18115 gosub10800:print"{down}{down}{down}strasse verk. -> s"
18120 gosub10800:print"{down}{down}{down}{down}{down}{rght}{rght}schuld:"z9
18124 tm$=ti$
18125 geta$:ifa$=""then18125
18126 ti$=tm$
18127 ifa$="v"then18300
18128 ifa$="h"then18200
18129 ifa$<>"s"then18124
18130 gosub10900:gosub10800:print"{down}{rght}welche strasse":gosub10800:print"{down}{down}{rght}willst du"
18135 gosub10800:print"{down}{down}{down}{rght}verkaufen?"
18140 gosub19000:iffe=1then18105
18142 ifbe(i)<>zthen18400
18144 forj=0to2
18146 b(j)=st(fa(i),j)
18148 nextj
18150 q=0
18152 forj=0toko(fa(i))
18154 ifsb(b(j))>0thenq=1
18156 nextj
18160 ifq=1then18400
18165 be(i)=5
18170 ge(z)=ge(z)+pr(i)*(1+(.5*(hy(i)=1)))
18172 ifhy(i)=0thenkp(z,fa(i))=kp(z,fa(i))-1
18175 hy(i)=0:gosub10000:gosub8000:return
18200 gosub10900:gosub10800:print"{down}{rght}auf welche":gosub10800:print"{down}{down}{rght}strasse willst"
18205 gosub10800:print"{down}{down}{down}{rght}du eine hypothek":gosub10800:print"{down}{down}{down}{down}{rght}aufnehmen?"
18210 gosub19000:iffe=1then18105
18215 ifbe(i)<>zthen18400
18220 forj=0toko(fa(i))-1
18225 b(j)=st(fa(i),j)
18230 nextj
18235 q=0
18240 forj=0toko(fa(i))-1
18245 ifsb(b(j))>0thenq=1
18250 nextj
18255 ifq=1then18400
18260 ifhy(i)=1then18400
18265 ge(z)=ge(z)+.5*pr(i)
18267 kp(z,fa(i))=kp(z,fa(i))-1
18270 hy(i)=1:gosub10000:gosub8000:return
18300 gosub10900:gosub10800:print"{down}{rght}auf welchem":gosub10800:print"{down}{down}{rght}strassenzug
18305 gosub10800:print"{down}{down}{down}{rght}willst du haeuser":gosub10800:print"{down}{down}{down}{down}{rght}verkaufen?"
18310 gosub10800:print"{down}{down}{down}{down}{down}{rght}(die 1. angeben)"
18315 gosub19000:iffe=1then18105
18325 forj=0toko(fa(i))-1
18330 b(j)=st(fa(i),j)
18332 nextj
18335 gosub10900
18337 forj=0toko(fa(i))-1
18340 gosub10800:printleft$(un$,j+1)sn$(b(j))":"
18345 geta$:ifa$=""then18345
18347 ifasc(a$)<48orasc(a$)>53then18345
18350 w(j)=val(a$):gosub10800:printleft$(un$,j+1)"{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}"w(j)
18355 c(j)=sb(b(j))-w(j)
18360 nextj
18370 ifabs(c(0)-c(1))>1then18400
18372 ifko(fa(i))=3andabs(c(0)-c(2))>1then18400
18374 ifko(fa(i))=3andabs(c(1)-c(2))>1then18400
18376 w=w(0)+w(1)+w(2)
18378 forj=0toko(fa(i))-1
18380 sb(b(j))=sb(b(j))-w(j)
18385 nextj
18390 ge(z)=ge(z)+w*500*int((fa(i)+1)/2)
18395 gt=gt-w:z4=i:gosub10000:gosub8000:goto18965
18400 gosub10900:gosub10800:print"{down}{down}{rght}das geht nicht!"
18405 fora=1to1500:next:goto18105
18500 z4=0:o=1
18505 forb=1to10:forc=0toko(b)-1:i=st(b,c):ifz4<>0then18514
18510 ifv>0thengosub18615:goto18514
18512 onogosub18525,18540,18555,18570,18585,18600,18615,18630,18645
18514 nextc,b
18516 ifz4<>0thenonz5goto18900,18920,18940
18518 o=o+1:ifo<10then18505
18520 return
18525 if(fa(i)=9orfa(i)=10)andbe(i)=zandhy(i)=0thenz4=i:z5=1
18526 return
18540 ifkp(z,fa(i))=1andbe(i)=zandhy(i)=0thenz4=i:z5=1
18541 return
18555 ifkp(z,fa(i))=2andko(fa(i))=3andbe(i)=zandhy(i)=0thenz4=i:z5=1
18556 return
18570 if(fa(i)=9orfa(i)=10)andbe(i)=zthenz4=i:z5=2
18571 return
18585 ifkp(z,fa(i))=0andbe(i)=zandhy(i)=1thenz4=i:z5=2
18586 return
18600 ifkp(z,fa(i))=0andko(fa(i))=3andbe(i)=zandhy(i)=1thenz4=i:z5=2
18601 return
18615 ifkp(z,fa(i))<ko(fa(i))thenreturn
18616 v=0:forj=0toko(fa(i))-1
18617 b(j)=st(fa(i),j)
18618 v=v+sb(b(j))
18619 nextj
18620 ifv=0thenreturn
18621 m=0
18622 forj=0toko(fa(i))-1
18623 ifsb(b(j))>mthenm=sb(b(j)):z4=b(j)
18624 nextj:z5=3:return
18630 ifbe(i)=zandhy(i)=0thenz4=i:z5=1
18631 return
18645 ifbe(i)=zthenz4=i:z5=2
18646 return
18900 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" nimmt":gosub10800
18902 print"{down}{down}{rght}hypothek auf "ar$(z4):gosub10800:print"{down}{down}{down}{rght}"sn$(z4)"
18905 gosub10800:print"{down}{down}{down}{down}{rght}auf.":gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}schuld:"z9
18910 ge(z)=ge(z)+.5*pr(z4)
18913 kp(z,fa(z4))=kp(z,fa(z4))-1
18915 hy(z4)=1:return
18920 gosub10900:gosub10800:print"{down}{rght}"sp$(z):gosub10800
18922 print"{down}{down}{rght}verkauft "ar$(z4):gosub10800
18925 print"{down}{down}{down}{rght}"sn$(z4)
18930 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}schuld:"z9
18932 ge(z)=ge(z)+.5*pr(z4)
18933 ifhy(z4)=0thenkp(z,fa(z4))=kp(z,fa(z4))-1
18935 be(z4)=5:hy(z4)=0:return
18940 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" verkauft":gosub10800
18942 print"{down}{down}{rght}ein haus auf "at$(z4):gosub10800:print"{down}{down}{down}{rght}"sn$(z4)
18945 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}schuld:"z9
18950 sb(z4)=sb(z4)-1:v=v-1
18955 ge(z)=ge(z)+int((fa(z4)+1)/2)*500
18960 gt=gt-1
18965 return
19000 fe=0
19002 getb$:ifb$=""then19000
19005 getc$:ifc$=""then19005
19010 getd$:ifd$=""then19010
19015 a$=b$+c$+d$
19020 ifa$="sch"then19100
19025 ifa$="hau"then19130
19030 i=0
19035 i=i+1:ifi=41then19045
19040 ifleft$(sn$(i),3)<>a$then19035
19045 ifi=41then19300
19050 goto19180
19100 getb$:ifb$=""then19100
19105 ifb$="l"theni=40:goto19180
19110 ifb$<>"i"then19300
19115 i=27:goto19180
19130 getb$:ifb$=""then19130
19135 getb$:ifb$=""then19135
19140 getb$:ifb$=""then19140
19145 ifb$="s"theni=33:goto19180
19150 ifb$<>"b"then19300
19155 i=36:goto19180
19180 a$=sn$(i)
19190 gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}"a$
19195 return
19300 fe=1:return
19500 ifge(z)>pythenpj=0:return
19510 pj=1:gosub10800:print"{down}{down}{down}{down}{down}{rght}"sp$(z)" hat nicht":gosub10800
19515 print"{down}{down}{down}{down}{down}{down}{rght}genug geld."
19520 return
20000 tt=val(left$(ti$,2))*60+val(mid$(ti$,3,2))
20002 print"{home}{gry1}"tr$tu$;"     {left}{left}{left}{left}{left}"str$(ru-tt)
20005 print"{home}{gry1}"fr$fu$;"      {left}{left}{left}{left}{left}{left}"str$(fp)
20010 return
20500 ifpo(z)=39thengoto20520
20505 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" muss"
20510 gosub10800:print"{down}{down}{rght}4000 dm zahlen."
20515 bz=4000:goto20550
20520 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" muss"
20525 gosub10800:print"{down}{down}{rght}2000 dm zahlen."
20530 bz=2000:goto20550
20550 ifbz>ge(z)thenz9=bz:gosub18000
20555 ge(z)=ge(z)-bz:fp=fp+bz:return
21000 gosub22000:gw(z)=gw(z)+1
21010 ifwp$="pasch"thenpg(z)=0:gw(z)=0:gosub21100:goto3105
21015 ifgw(z)=3thengw(z)=0:pg(z)=0:z9=1000:gosub21150:goto21040
21020 ifff(z)=1thenpg(z)=0:gw(z)=0:ff(z)=0:goto21065
21021 gosub10900:gosub10800:print"{down}{rght}willst du dich":gosub10800
21022 print"{down}{down}{rght}fuer dm 1000":gosub10800:print"{down}{down}{down}{rght}freikaufen ?":gosub10800
21023 print"{down}{down}{down}{down}{down}{rght}{rght}{rght}(j/n)";:ifz>anthen21030
21024 tm$=ti$
21025 geta$:ifa$<>"j"anda$<>"n"then21025
21026 ti$=tm$
21027 ifa$="j"andge(z)>=1000thengw(z)=3:print" ja!":fora=1to1000:next:goto21015
21028 print" nein!":fora=1to1000:next:goto3235
21030 ifgt>10orge(z)<1000thena$="n"
21031 ifge(z)>1000and(wu=10orwu=7)thena$="j"
21032 ifa$="n"thenprint" nein!":fora=1to1000:next:goto3235
21033 print" ja!"
21035 fora=1to1000:next:gw(z)=3:goto21015
21040 ifge(z)<z9thengosub18000
21045 ifz2=1then3235
21050 ge(z)=ge(z)-1000:goto3105
21065 gosub10900:gosub10800:print"{down}{rght}{rght}{rght}e/g-karte:"
21066 gosub10800:print"{down}{down}{rght}du kommst aus":gosub10800:print"{down}{down}{down}{rght}dem gefaengnis"
21067 gosub10800:print"{down}{down}{down}{down}{rght}frei."
21070 goto3105
21100 gosub10900:gosub10800:print"{down}{rght}{rght}{rght}{rght}* pasch *"
21105 gosub10800:print"{down}{down}{rght}du kommst aus":gosub10800:print"{down}{down}{down}{rght}dem gefaengnis"
21110 gosub10800:print"{down}{down}{down}{down}{rght}frei."
21115 return
21150 gosub10900:gosub10800:print"{down}{rght}du kommst fuer"
21155 gosub10800:print"{down}{down}{rght}1000 dm aus dem":gosub10800:print"{down}{down}{down}{rght}gefaengnis frei"
21160 return
21999 goto3100
22000 gosub10900
22005 gosub10800:print"{down}{rght}{rght}{rght}* wuerfeln *"
22010 ifz>anor(pg(z)=0andwp$="")then22025
22015 gosub10800:print"{rvof}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}return"
22019 tm$=ti$
22020 geta$:ifa$<>chr$(13)then22020
22021 ti$=tm$:gosub10800:print"{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}      "
22025 w(1)=6:w(2)=6
22030 b(1)=int(rnd(1)*12)+13
22040 b(2)=int(rnd(1)*12)+13
22045 ifb(1)>=b(2)thenx=b(1):goto22050
22046 x=b(2)
22050 fory=1tox:fori=1to2
22052 ify>b(i)then22056
22055 w(i)=w(i)-1:ifw(i)=0thenw(i)=6
22056 nexti
22057 print"{home}"left$(re$,21)left$(un$,22);
22058 onw(1)gosub22200,22210,22220,22230,22240,22250
22059 print"{home}"left$(re$,25)left$(un$,22);
22060 onw(2)gosub22200,22210,22220,22230,22240,22250
22065 nexty
22070 ifw(1)=w(2)thenwp$="pasch"
22072 ifw(1)<>w(2)thenwp$=""
22075 ifwp$="pasch"thenp=p+1:ifp=3thenpg(z)=1:wu=11-po(z):ifwu<0thenwu=wu+40
22080 ifp=3then22100
22085 wu=w(1)+w(2)
22090 return
22100 gosub10900:gosub10800
22105 print"{down}dreimal pasch:"
22110 gosub10800:print"{down}{down}{down}"sp$(z)" muss ins"
22115 gosub10800:print"{down}{down}{down}{down}gefaengnis."
22120 fora=1to2000:next:return
22200 print"{lgrn}{rvon}   {down}{left}{left}{left} Q {down}{left}{left}{left}   ";:return
22210 print"{lgrn}{rvon}  Q{down}{left}{left}{left}   {down}{left}{left}{left}Q  ";:return
22220 print"{lgrn}{rvon}Q  {down}{left}{left}{left} Q {down}{left}{left}{left}  Q";:return
22230 print"{lgrn}{rvon}Q Q{down}{left}{left}{left}   {down}{left}{left}{left}Q Q";:return
22240 print"{lgrn}{rvon}Q Q{down}{left}{left}{left} Q {down}{left}{left}{left}Q Q";:return
22250 print"{lgrn}{rvon}Q Q{down}{left}{left}{left}Q Q{down}{left}{left}{left}Q Q";:return
23000 a=0
23002 iflen(er$(a,ez))>18then23010
23005 a=a+1:goto23002
23010 lt$=right$(er$(a,ez),6):l1$=left$(lt$,1):e$(a)=left$(er$(a,ez),18)
23012 ifa>0thenforb=0toa-1:e$(b)=er$(b,ez):nextb
23015 gosub10900
23020 fori=0toa
23025 gosub10800:printleft$(un$,i+1)e$(i)
23030 nexti
23035 ez=ez+1:ifez=16thenez=0
23040 goto23140
23100 a=0
23102 iflen(ge$(a,gz))>18then23110
23105 a=a+1:goto23102
23110 lt$=right$(ge$(a,gz),6):l1$=left$(lt$,1):g$(a)=left$(ge$(a,gz),18)
23112 ifa>0thenforb=0toa-1:g$(b)=ge$(b,gz):nextb
23115 gosub10900
23120 fori=0toa
23125 gosub10800:printleft$(un$,i+1)g$(i)
23130 nexti
23135 gz=gz+1:ifgz=16thengz=0
23140 ifmid$(lt$,1,3)<>"0"thenl3=val(right$(lt$,4)):goto23160
23145 ifmid$(lt$,1,4)<>"0"thenl3=val(right$(lt$,3)):goto23160
23150 ifmid$(lt$,1,5)<>"0"thenl3=val(right$(lt$,2)):goto23160
23155 l3=val(right$(lt$,1)):goto23160
23160 ifl1$="x"thenwu=l3-po(z):ifwu<0thenwu=wu+40
23162 ifl1$="x"then3105
23165 ifl1$="y"thenwu=l3-po(z):ll=1
23166 ifl1$="y"then3105
23170 ifl1$<>"z"then23175
23171 ifl3>ge(z)thenz9=l3:gosub18000
23172 ifz2=1then3235
23173 ge(z)=ge(z)-l3:fp=fp+l3:goto3235
23175 ifl1$="e"thenge(z)=ge(z)+l3:goto3235
23180 ifl1$="g"thenwu=-3:ll=1:goto3105
23185 ifl1$="f"thenff(z)=1:goto3235
23190 ifl1$="k"thenpg(z)=1:wu=11-po(z):ifwu<0thenwu=wu+40
23195 ifl1$="k"thengosub9000:goto3235
23200 ifl1$<>"a"then23220
23201 gosub10800:print"{down}{down}{down}{down}{down}{down}{rvof}e{rvon}'karte - {rvof}z{rvon}ahlen ?"
23202 ifz<=anthen23205
23203 ifrnd(1)<.5orge(z)<200then23210
23204 goto23215
23205 tm$=ti$
23206 geta$:ifa$=""then23205
23207 ti$=tm$:ifa$="e"then23210
23208 ifa$<>"z"then23205
23209 goto23215
23210 q$="{down}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}          "
23211 gosub10800:printq$:fora=1to1500:next
23212 goto23000
23215 q$="{down}{down}{down}{down}{down}{down}         "
23216 gosub10800:printq$:ifge(z)<200then23201
23217 ge(z)=ge(z)-200:fp=fp+200:goto3235
23220 ifl1$<>"b"then23230
23221 fori=1to4:ifi=zthen23223
23222 ifge(i)>200thenge(i)=ge(i)-200
23223 nexti
23224 ge(z)=ge(z)+600
23225 goto3235
23230 ifl1$<>"s"then23250
23231 u=0
23232 fori=1to40
23233 ifsb(i)=5andbe(i)=zthenu=u+2300:goto23235
23234 ifsb(i)>0andbe(i)=zthenu=u+800*sb(i)
23235 next:gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}gesamt:"u"dm"
23236 ifge(z)<uthenz9=u:gosub18000
23237 ifz2=1then3235
23238 ge(z)=ge(z)-u
23239 fp=fp+u
23240 goto3235
23250 ifl1$<>"r"then3235
23251 u=0
23252 fori=1to40
23253 ifsb(i)=5andbe(i)=zthenu=u+2000:goto23255
23254 ifsb(i)>0andbe(i)=zthenu=u+500*sb(i)
23255 nexti:gosub10800:print"{down}{down}{down}{down}{down}{down}{rght}gesamt:"u"dm"
23256 ifge(z)<uthenz9=u:gosub18000
23257 ifz2=1then3235
23258 ge(z)=ge(z)-u
23259 fp=fp+u
23260 goto3235
24000 ifbe(po(z))=5then24045
24005 ifbe(po(z))=zthengosub10900:gosub10800:print"{down}{rght}"sp$(z)" ist"
24006 ifbe(po(z))=zthengosub10800:print"{down}{down}{rght}selbst besitzer":return
24010 ifbe(14)=be(29)andhy(14)=0andhy(29)=0thenmx=200*wu:goto24020
24012 mx=80*wu
24015 ifhy(po(z))=1then24500
24020 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" zahlt an":gosub10800
24025 print"{down}{down}{rght}"sp$(be(po(z)));mx"dm":gosub10800:print"{down}{down}{down}{rght}miete."
24030 ge(be(po(z)))=ge(be(po(z)))+mx
24035 ifge(z)<mxthenz9=mx:gosub18000:ifz2=1thenreturn
24040 ge(z)=ge(z)-mx:return
24045 gosub10900:gosub10800:print"{down}{rght}"sn$(po(z)):gosub10800
24047 print"{down}{down}{rght}ist fuer"pr(po(z))"dm"
24050 gosub10800:print"{down}{down}{down}{rght}zu verkaufen.":gosub10800:print"{down}{down}{down}{down}{down}{rght}{rght}{rght}(j/n)?"
24055 ifz>anthen24135
24059 tm$=ti$
24060 geta$:ifa$<>"j"anda$<>"n"then24060
24061 ti$=tm$
24065 ifa$="n"thengosub10800:print"{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}nein !":return
24070 gosub10800:print"{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}ja !"
24075 py=pr(po(z))
24080 gosub19500:ifpj=1thenreturn
24085 ge(z)=ge(z)-py
24090 be(po(z))=z
24095 kp(z,fa(po(z)))=kp(z,fa(po(z)))+1
24100 print"{home}"left$(un$,zl)"{rght}"fa$(fa(po(z)))"{rvon}              {rvof} - "bb$(sb(po(z)));
24102 print"{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{rvon}"sn$(po(z))
24105 zl=zl+1:ifzl=22thengosub10000:zl=4
24110 return
24135 ifkp(z,fa(po(z)))=0andrnd(1)<.1andge(z)<2*pr(po(z))thena$="n":goto24065
24140 ifge(z)>=pr(po(z))thena$="j":goto24070
24145 a$="n":goto24065
24200 ifbe(po(z))=5then24045
24205 ifbe(po(z))=zthengosub10900:gosub10800:print"{down}{rght}"sp$(z)" ist"
24206 ifbe(po(z))=zthengosub10800:print"{down}{down}{rght}selbst besitzer":return
24208 mx=(2^(kp(be(po(z)),fa(po(z)))-1))*500
24210 goto24015
24400 ifbe(po(z))=5then24045
24405 ifbe(po(z))=zthengosub10900:gosub10800:print"{down}{rght}"sp$(z)" ist"
24406 ifbe(po(z))=zthengosub10800:print"{down}{down}{rght}selbst besitzer":return
24410 mx=mi(po(z),sb(po(z)))
24415 ifkp(be(po(z)),fa(po(z)))=ko(fa(po(z)))andsb(po(z))=0thenmx=mx*2
24420 goto24015
24500 gosub10900:gosub10800:print"{down}{rght}hypothek auf "at$(po(z)):gosub10800
24505 print"{down}{down}{rght}"sn$(po(z))":":gosub10800:print"{down}{down}{down}{down}{rght}keine miete!"
24510 return
25000 dimpr(40),mi(40,5),be(40),ar$(40),gw(4)
25005 dimsb(40),fa(40),kp(4,10),hy(40),ge(4),g1(4),gg(4),sp$(5),po(4),pg(4)
25010 dimer$(4,15),ge$(4,15),v(15),kn(40),fb(40),ze(40),at$(40),st(10,3)
25015 fora=1to4:ge(a)=30000:next
25020 fora=1to40:readpr(a):next
25025 fora=1to40:forb=0to5:readmi(a,b):nextb,a
25030 fora=1to40:be(a)=5:next
25035 fora=1to40:readar$(a):next
25036 fora=1to40:readat$(a):next
25040 fora=1to40:readfa(a):next
25045 fora=1to10:readko(a):next
25050 fora=0to15:v(a)=a:next
25055 fora=15to0step-1
25060 c=int(rnd(1)*(a+1)):e=0
25065 readge$(e,v(c))
25070 iflen(ge$(e,v(c)))<=18thene=e+1:goto25065
25075 ifc=athen25085
25080 ford=ctoa-1:v(d)=v(d+1):nextd
25085 nexta:return
25090 fora=0to15:v(a)=a:next
25095 fora=15to0step-1
25100 c=int(rnd(1)*(a+1)):e=0
25105 reader$(e,v(c))
25110 iflen(er$(e,v(c)))<=18thene=e+1:goto25105
25115 ifc=athen25125
25120 ford=ctoa-1:v(d)=v(d+1):nextd
25125 nexta
25130 fora=1to4:readna$(a):next
25135 fora=1to11:b=32-a
25136 kn(a)=2024-a:kn(b)=kn(a)-400
25137 nexta
25140 fora=12to20:b=52-a
25141 kn(a)=2013-40*(a-11):kn(b)=kn(a)+10
25142 nexta
25150 re$="{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}{rght}"
25155 un$="{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
25160 tr$=left$(re$,31):tu$=left$(un$,17)
25165 fr$=left$(re$,31):fu$=left$(un$,22)
25170 sr$=left$(re$,21):su$=left$(un$,6)
25175 l$="{cyn}{rvon}                  {down}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}"
25180 fora=1to3:lo$=lo$+l$:next
25185 fora=1to2:lp$=lp$+l$:next
25190 fora=1to2:lq$=lq$+l$:next
25200 fa$(1)="{blu}":fa$(2)="{cyn}":fa$(3)="{pur}":fa$(4)="{orng}":fa$(5)="{red}":fa$(6)="{yel}"
25205 fa$(7)="{grn}":fa$(8)="{lblu}":fa$(9)="{wht}":fa$(10)="{gry2}"
25210 fora=1to40:readfb(a),ze(a):nexta
25215 return
25220 fora=1to40:pokekn(a)+54272,fb(a):pokekn(a),ze(a):next
25300 b=0:c=0:d=0
25305 fora=1to40:readsn$(a)
25310 iffa(a)<9andfa(a)>0thenst(fa(a),b)=a:b=b+1:ifb=ko(fa(a))thenb=0
25315 iffa(a)=9thenst(9,c)=a:c=c+1
25320 iffa(a)=10thenst(10,d)=a:d=d+1
25325 nexta
25999 return
26000 data0,1200,0,1600,0,4000,2000,0,2000,2400,0,2800,2800,3000,3200,4000
26005 data3600,0,3600,4000,0,4400,0,4400,4800,4000,5200,5200,3000,5600,0,6000
26010 data6000,0,6400,4000,0,7000,0,8000
26020 data0,0,0,0,0,0
26025 data40,200,600,1800,3200,5000
26030 data0,0,0,0,0,0
26035 data80,400,1200,3600,6400,9000
26040 data0,0,0,0,0,0
26045 data500,1000,2000,4000,0,0
26050 data120,600,1800,5400,8000,11000
26055 data0,0,0,0,0,0
26060 data120,600,1800,5400,8000,11000
26065 data160,800,2000,6000,9000,12000
26070 data0,0,0,0,0,0
26075 data200,1000,3000,9000,12000,15000
26080 data200,1000,3000,9000,12000,15000
26085 data1,1,1,1,1,1
26090 data240,1200,3600,10000,13000,16000
26095 data500,1000,2000,4000,0,0
26100 data280,1400,4000,11000,15000,19000
26105 data0,0,0,0,0,0
26110 data280,1400,4000,11000,15000,19000
26115 data320,1600,4400,12000,16000,20000
26120 data0,0,0,0,0,0
26125 data360,1800,5000,14000,17500,23000
26130 data0,0,0,0,0,0
26135 data360,1800,5000,14000,17500,23000
26140 data400,2000,6000,15000,18500,24000
26145 data500,1000,2000,4000,0,0
26150 data440,2200,6600,17000,21000,25000
26155 data440,2200,6600,17000,21000,25000
26160 data1,1,1,1,1,1
26165 data480,2400,7200,18000,22500,27000
26170 data0,0,0,0,0,0
26175 data520,2600,7800,19000,24000,28000
26180 data520,2600,7800,19000,24000,28000
26185 data0,0,0,0,0,0
26190 data560,2800,8400,20000,25500,30000
26195 data500,1000,2000,4000,0,0
26200 data0,0,0,0,0,0
26205 data700,3000,11000,25000,30000,35000
26210 data0,0,0,0,0,0
26211 data1000,4000,12000,28000,34000,40000
26212 data,die,das,die,die,den,die,das,die,die,das,die,die,das,die,den,die,das
26213 datadie,die,,die,das,die,den,den,die,die,das,die,,den,die,das,die,den
26214 datadas,die,die,die
26215 data,der,dem,der,der,dem,der,dem,der,der,dem,der,der,dem,der,dem,der,dem
26216 datader,der,,der,dem,der,dem,dem,der,der,dem,der,,dem,der,dem,der,dem,dem
26217 datader,der,der
26275 data0,1,0,1,0,9,2,0,2,2,0,3,3,10,3,9,4,0,4,4,0,5,0,5,5,9,6,6,10,6,0
26280 data7,7,0,7,9,0,8,0,8
26285 data2,3,3,3,3,3,3,2,4,2
26330 data"zahle an das kran-
26331 data"kenhaus. dm 2000  z 2000
26335 data" aus lagerverkaeu-
26336 data" fen erhaeltst du
26337 data" dm 100.          e 0100
26340 data" einkommenssteuer-
26341 data" rueckzahlung. du
26342 data" erhaeltst dm 400.e 0400
26345 data"   arztkosten.
26346 data"   zahle dm 100.  z 0100
26350 data"du kommst aus dem
26351 data"gefaengnis frei.  f 0000
26355 data" zahle deine ver-
26356 data" sicherungssumme.
26357 data" dm 1000.         z 1000
26360 data"bankirrtum zu
26361 data"deinen gunsten. du
26362 data"erhaeltst dm 4000 e 4000
26365 data"du hast im kreuz-
26366 data"wortraetsel gewon-
26367 data"nen. du erhaeltst
26368 data"dm 2000.          e 2000
26370 data" gehe zurueck zur
26371 data" badsstrasse.     y 0002
26375 data"   gehe in das
26376 data"   gefaengnis     k 0011
26380 data"deine jahresrente
26381 data"wird faellig.
26382 data"ziehe dm 2000 ein.e 2000
26385 data"du hast in einer
26386 data"schoenheitskonkur-
26387 data"renz den 2. preis
26388 data"gewonnen. du
26389 data"erhaeltst dm 200  e 0200
26390 data" aus vorzugsaktien
26391 data" erhaeltst du 7%
26392 data" dividende. dm 500e 0500
26395 data" du erbst dm 2000.e 2000
26400 data" zahle eine stra-
26401 data" fe von dm 200
26402 data" oder nimm eine
26403 data" ereigniskarte.   a 0000
26405 data" ruecke vor bis
26406 data" auf los          x 0001
26410 data"   mache einen
26411 data"   ausflug zum
26412 data"   westbahnhof    x 0016
26415 data" zahle schulgeld.
26416 data" dm 3000.         z 3000
26420 data"betrunken im
26421 data"dienst. zahle eine
26422 data"strafe von dm 200.z 0200
26425 data" ruecke vor bis
26426 data" zur schlossallee.x 0040
26430 data" die bank zahlt
26431 data" dir eine dividen-
26432 data" de von dm 1000.  e 1000
26435 data"  gehe 3 felder
26436 data"  zurueck.        g 0003
26440 data" ruecke vor bis
26441 data" zur seestrasse.  x 0012
26445 data" strafe fuer zu
26446 data" schnelles fahren.
26447 data" dm 300.          z 0300
26450 data" miete und anlei-
26451 data" hezinsen werden
26452 data" faellig. du er-
26453 data" haeltst dm 3000. e 3000
26455 data"  ruecke vor bis
26456 data"  auf los.        x 0001
26460 data" ruecke vor bis
26461 data" zum opernplatz.  x 0025
26465 data" strassenausbes-
26466 data"   serungsarbeiten
26467 data"pro haus-  dm 800
26468 data"pro hotel- dm 2300s 0000
26470 data" lasse deine haeu-
26471 data" ser renovieren.
26472 data"pro haus-  dm 500
26473 data"pro hotel- dm 2000r 0000
26475 data"   gehe in das
26476 data"   gefaengnis     k 0011
26480 data" es ist dein ge-
26481 data" burtstag. ziehe
26482 data" von jedem spie-
26483 data" ler dm 200 ein.  b 0200
26485 data" du kommst aus dem
26486 data" gefaengnis frei. f 0000
26490 data1 comm,2 comm,3 comm,4 comm
26500 data1,159,6,130,12,160,6,148,11,160,1,147,3,131,12,160,3,133,3,144,10,163
26510 data4,147,4,136,15,133,4,142,1,151,8,141,12,160,8,151,8,130,13,164
26515 data2,141,12,160,2,148,2,143,1,142,7,147,7,140,15,151,7,135,10,161
26520 data5,146,5,136,12,160,5,130,1,136,12,160,14,144,11,160,14,147
26620 datalos,badstrasse,gemeins.-feld,turmstrasse,einkom.-steuer,suedbahnhof
26625 datachausseestr.,ereignisfeld,elisenstrasse,poststrasse,gefaengnis
26630 dataseestrasse,hafenstrasse,elektr.-werk,neue strasse,westbahnhof
26632 datamuenchner str.,gemeins.-feld,wiener strasse,berliner str.,frei parken
26635 datamuseumsstrasse,ereignisfeld,theaterstrasse,opernplatz,nordbahnhof
26640 dataschillerstr.,lessingstrasse,wasserwerk,goethestrasse,gehe ins gef.
26645 datarathausplatz,hauptstrasse,gemeins.-feld,bahnhofstrasse,hauptbahnhof
26650 dataereignisfeld,parkstrasse,zusatzsteuer,schlossallee
27000 gosub10900:gosub10800:print"{down}{rght}"sp$(z)" ist":gosub10800
27001 print"{down}{down}{rght}ausgeschieden !"
27002 ge(z)=0
27005 fori=1to40:ifbe(i)=zthenbe(i)=5
27006 nexti
27010 fori=1to4:ifi=zthen27015
27012 ifpo(i)=po(z)thenq=1:j=i
27015 nexti
27020 ifq=0then27030
27022 ifasc(s$(j))<65thenpokekn(po(z))+54272,1:pokekn(po(z)),asc(s$(j))
27025 ifasc(s$(j))>=65thenpokekn(po(z))+54272,1:pokekn(po(z)),asc(s$(j))-64
27027 goto27035
27030 pokekn(po(z))+54272,fb(po(z)):pokekn(po(z)),ze(po(z))
27035 po(z)=0
27040 j=0
27045 fori=1to4:ifpo(i)=0thenj=j+1
27050 nexti
27055 ifj=3then27100
27075 z2=1:return
27100 fora=1to4:fori=1to40
27110 ifbe(i)=atheng1(a)=g1(a)+pr(i)*(1+.5*(hy(i)=1))
27115 ifbe(i)=aandsb(i)>0theng1(a)=g1(a)+(int((fa(i)+1)/2)*500)*sb(i)
27120 nexti
27125 gg(a)=ge(a)+g1(a)
27130 nexta
27135 print"{clr}"
27137 print:print
27140 print"{red}         e n d r e s u l t a t"
27145 print"{blu}         DDDDDDDDDDDDDDDDDDDDD"
27150 print:print
27155 print"{yel} spieler:  {pur}kapital:  {cyn}besitz:   {orng}gesamt:"
27160 print"{wht}----------------------------------------";
27163 print
27165 fora=1to4
27170 printtab(1)"{yel}"sp$(a);tab(11)"{pur}"ge(a);tab(21)"{cyn}"g1(a);tab(31)"{orng}"gg(a)
27172 print
27175 nexta
27180 print:print:print
27185 print"{grn}    noch ein spiel ? -> [space]"
27190 geta$:ifa$<>" "then27190
27200 run

 10 REM  ****************************** 
 11 REM  *                            * 
 12 REM  * COMMERCIAL TOWN   FUER C64 * 
 13 REM  *                            * 
 14 REM  * VON : PETER FINK           * 
 15 REM  *       8500 NUERNBERG 30    * 
 16 REM  *       STEPHANSTRASSE 20    * 
 17 REM  *       TEL.: 0911/467930    * 
 18 REM  *                            * 
 19 REM  ****************************** 
 99 PRINT"{CLR}"; 
 100 DIM SN$(41) 
 150 POKE 53281,0:POKE 53280,0 
 200 SN$(0)="" 
 205 SN$(1)="{5SPACE}C O M M E R C I A L{3SPACE}T O W N" 
 210 SN$(2)="{5SPACE}DDDDDDDDDDDDDDDDDDDDDDDDDDDDD" 
 215 SN$(3)="" 
 220 SN$(4)="{8SPACE}PETER FINK, FEBRUAR 1985" 
 225 SN$(5)="" 
 230 SN$(6)="DIESES SPIEL LAEUFT NACH DEN ORIGINALEN" 
 235 SN$(7)="MONOPOLY-REGELN. ES KOENNEN 1 - 4 SPIE-" 
 240 SN$(8)="LER TEILNEHMEN. DIE AUF 4 SPIELER FEH-" 
 245 SN$(9)="LENEDN WERDEN VOM COMPUTER SIMULIERT." 
 250 SN$(10)="BEI DER EINGABE VON STRASSENNAMEN BRAU-" 
 255 SN$(11)="CHEN NUR DIE ERSTEN DREI BUCHSTABEN" 
 260 SN$(12)="EINGEGEBEN ZU WERDEN." 
 265 SN$(13)="{15SPACE}AUSNAHMEN:" 
 270 SN$(14)="SCHILLERSTRASSE UND SCHLOSSALLEE: 4" 
 275 SN$(15)="HAUPTBAHNHOF UND HAUPTSTRASSE:{4SPACE}6" 
 280 SN$(16)="" 
 285 SN$(17)="1 HOTEL ENTSPRICHT 5 HAEUSERN, DAS" 
 290 SN$(18)="HEISST AUCH BEIM KAUF UND VERKAUF VON" 
 295 SN$(19)="HAEUSERN MUESSEN HOTELS ALS 5 HAEUSER" 
 300 SN$(20)="EINGEGEBEN WERDEN." 
 305 SN$(21)="" 
 310 SN$(22)="" 
 315 SN$(23)="{12SPACE}WEITER -> [SPACE]" 
 320 SN$(24)="" 
 325 SN$(25)="BEI DER ABFRAGE NACH DEN AKTIVITAETEN" 
 330 SN$(26)="DES SPIELERS VOR DEM WUERFELN KANN FOL-" 
 335 SN$(27)="GENDE AUSWAHL GETROFFEN WERDEN:" 
 340 SN$(28)="> H < WENN ER HAEUSER KAUFEN WILL" 
 345 SN$(29)="> Z < WENN ER EINE HYPOTHEK ZURUECK-" 
 350 SN$(30)="{27SPACE}ZAHLEN WILL." 
 355 SN$(31)="> K < WENN ER EINEM MITSPIELER EIN VER-" 
 360 SN$(32)="{6SPACE}KAUFS- ODER TAUSCHANGEBOT MACHEN" 
 362 SN$(34)="> W < WENN ER WUERFELN WILL." 
 365 SN$(33)="{34SPACE}WILL." 
 370 SN$(35)="" 
 375 SN$(36)="STEHT IM FELD 'STANDORT':{SPACE,RED,RVSON}GEFAENGNIS #{RVOFF,GREEN}" 
 380 SN$(37)="SO HEISST DAS, DASS DER SPIELER NICHT" 
 385 SN$(38)="NUR ZU BESUCH SONDERN ECHT IM GEFAENG-" 
 390 SN$(39)="NIS IST." 
 395 SN$(40)="" 
 400 SN$(41)="{12SPACE}START -> [SPACE]" 
 420 FOR A=0 TO22:PRINT"{ORANGE}"SN$(A):NEXT 
 422 GOSUB 25000:PRINTSN$(23) 
 425 GET A$:IF A$<>" " THEN425 
 430 PRINT"{CLR}";:FOR A=24 TO40:PRINT"{GREEN}"SN$(A):NEXT 
 440 GOSUB 25090:PRINTSN$(41) 
 510 SN$(0)="{LIG.RED}UCCCRCCCCCCCCCCRCCCI{BROWN}UCCCCCCCCCCCCCCCCCCI" 
 520 SN$(1)="{LIG.RED}B***B{SPACE,SPACE,YELLOW}BESITZ{LIG.RED,2SPACE}B***B{BROWN}B{WHITE,4SPACE}STANDORT:{5SPACE,BROWN}B" 
 530 SN$(2)="{LIG.RED}QCCCK{SPACE,SPACE,BLUE}EEEEEE{LIG.RED,2SPACE}JCCCW{BROWN}B{SPACE,17SPACE}B" 
 540 SN$(3)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{SPACE,17SPACE}B" 
 550 SN$(4)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{SPACE,17SPACE}B" 
 560 SN$(5)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}QCCCCCCCCCCCCCCCCCCW" 
 570 SN$(6)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{CYAN,RVSON,18SPACE,RVOFF,BROWN}B" 
 580 SN$(7)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{CYAN,RVSON,18SPACE,RVOFF,BROWN}B" 
 590 SN$(8)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{CYAN,RVSON,18SPACE,RVOFF,BROWN}B" 
 600 SN$(9)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{CYAN,RVSON,18SPACE,RVOFF,BROWN}B" 
 610 SN$(10)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{CYAN,RVSON,18SPACE,RVOFF,BROWN}B" 
 620 SN$(11)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{CYAN,RVSON,18SPACE,RVOFF,BROWN}B" 
 630 SN$(12)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}B{CYAN,RVSON,18SPACE,RVOFF,BROWN}B" 
 640 SN$(13)="{LIG.RED}B{SPACE,17SPACE}B{BROWN}JCCCCCCCCCCCCCCCCCCK" 
 650 SN$(14)="{LIG.RED}B{SPACE,17SPACE}B{SPACE,RED}SPIELER{12SPACE}" 
 660 SN$(15)="{LIG.RED}B{SPACE,17SPACE}B{GREEN,RVSON}K{7SPACE,RVOFF}K{SPACE,ORANGE}UCCCCCCCI " 
 670 SN$(16)="{LIG.RED}B{SPACE,17SPACE}B{GREEN,RVSON}K{7SPACE,RVOFF}K{SPACE,ORANGE}B{BROWN,SPACE}ZEIT:{SPACE,ORANGE}B " 
 680 SN$(17)="{LIG.RED}B{SPACE,17SPACE}B{GREEN}C{RVSON}IIIIIII{RVOFF}V{SPACE,ORANGE}B{7SPACE}B " 
 690 SN$(18)="{LIG.RED}B{SPACE,17SPACE}B{SPACE,YELLOW}KAPITAL{2SPACE,ORANGE}JCCCCCCCK " 
 700 SN$(19)="{LIG.RED}B{SPACE,17SPACE}B{PURPLE,RVSON}K{7SPACE,RVOFF}K{11SPACE}" 
 710 SN$(20)="{LIG.RED}B{SPACE,17SPACE}B{PURPLE,RVSON}K{7SPACE,RVOFF}K{SPACE,BLUE}UCCCCCCCI " 
 720 SN$(21)="{LIG.RED}B{SPACE,17SPACE}B{PURPLE}C{RVSON}IIIIIII{RVOFF}V{SPACE,BLUE}B{GREY2}FREI P.{BLUE}B " 
 730 SN$(22)="{LIG.RED}B{SPACE,17SPACE}B{SPACE,LIG.GREEN,RVSON}Q Q{RVOFF,SPACE,RVSON,2SPACE}Q{RVOFF,2SPACE,BLUE}B{7SPACE}B " 
 740 SN$(23)="{LIG.RED}B{SPACE,17SPACE}B{SPACE,LIG.GREEN,RVSON,3SPACE,RVOFF,SPACE,RVSON,SPACE}Q{SPACE,RVOFF,2SPACE,BLUE}JCCCCCCCK " 
 750 SN$(24)="{LIG.RED}JCCCCCCCCCCCCCCCCCCK{SPACE,LIG.GREEN,RVSON}Q Q{RVOFF,SPACE,RVSON}Q{2SPACE,RVOFF,11SPACE}" 
 775 GET A$:IF A$<>" " THEN775 
 776 PRINT"{CLR}"; 
 780 FOR A=0 TO24:PRINTSN$(A);:NEXT 
 795 POKE 56295,14:POKE 2023,102 
 1000 GOSUB 25220 
 1100 GOSUB 10900:GOSUB 10800:PRINT"{DOWN}DAUER DES SPIELES":GOSUB 10800 
 1105 PRINT"{2DOWN,4SPACE}(IN MIN.)":GOSUB 10800 
 1110 PRINT"{4DOWN,6RIGHT}";:B$="" 
 1111 GET A$:IF A$<>CHR$ (20) THEN1114 
 1112 IF LEN (B$)>0 THENPRINT"{LEFT,RVSON,SPACE,LEFT}";:B$=LEFT$ (B$,LEN (B$)-1) 
 1113 GOTO 1111 
 1114 IF A$<>""AND A$<>CHR$ (13) THENIF ASC (A$)<48OR ASC (A$)>57 THEN1111 
 1115 PRINTA$;:IF A$=CHR$ (13)AND LEN (B$)>0 THEN1118 
 1116 B$=B$+A$:GOTO 1111 
 1118 RU=VAL (B$) 
 1120 GOSUB 10900:GOSUB 10800 
 1125 PRINT"{DOWN}ANZAHL DER SPIELER":GOSUB 10800 
 1130 PRINT"{3DOWN,8RIGHT,RVSON}";:B$="" 
 1131 GET A$:IF A$<>CHR$ (20)AND A$<>CHR$ (13)AND A$<>"" THENPRINTA$"{LEFT}";:B$=A$ 
 1132 IF A$=CHR$ (13)AND LEN (B$)=1 THEN1134 
 1133 GOTO 1131 
 1134 IF ASC (B$)<48OR ASC (B$)>52 THEN1120 
 1135 AN=VAL (B$) 
 1140 GOSUB 10900:IF AN=0 THEN1180 
 1145 FOR A=1 TOAN 
 1150 PRINT"{HOME}"SR$SU$"{CYAN,RVSON,2SPACE}NAME SPIELER "A 
 1155 PRINTSR$"{UP,RVSON}(BIS ZU 7 BUCHST.) 
 1156 PRINT"{HOME}"SU$SR$"{DOWN,DOWN,RVSON}ANM.: VERSCHIEDENE{DOWN,18LEFT}"; 
 1157 PRINT"{RVSON}ANFANGSBUCHSTABEN{DOWN,17LEFT}"; 
 1158 PRINT"{RVSON}WAEREN VON VORTEIL" 
 1160 PRINTSR$"{5RIGHT,RVSON}";:B$="" 
 1161 GET A$:IF A$<>CHR$ (20) THEN1164 
 1162 IF LEN (B$)>0 THENPRINT"{LEFT,RVSON,SPACE,LEFT}";:B$=LEFT$ (B$,LEN (B$)-1) 
 1163 GOTO 1161 
 1164 IF LEN (B$)>=7 THEN1168 
 1165 IF A$=CHR$ (13) THEN1167 
 1166 PRINTA$;:B$=B$+A$:GOTO 1161 
 1167 IF LEN (B$)=0 THEN1161 
 1168 SP$(A)=B$:GOSUB 10900 
 1170 NEXT A 
 1175 IF AN=4 THEN1200 
 1180 B=1:FOR A=AN+1 TO4 
 1185 SP$(A)=NA$(B):B=B+1 
 1190 NEXT A 
 1195 SP$(5)="BANK" 
 1200 FOR A=1 TO40:SB(A)=0:NEXT 
 1205 FOR A=1 TO4:PO(A)=1:NEXT 
 1210 BB$(0)=" ":BB$(1)="1":BB$(2)="2":BB$(3)="3":BB$(4)="4":BB$(5)="A" 
 1215 FOR A=1 TO4:S$(A)=LEFT$ (SP$(A),1):NEXT 
 1220 FP=0:EZ=1:GZ=1 
 2995 TI$="000000":GOSUB 20000 
 3000 FOR Z=1 TO4:LL=0:P=0:WP$="":IF PO(Z)=0 THEN3995 
 3010 GOSUB 7000 
 3015 GOSUB 6000 
 3020 GOSUB 10000 
 3025 GOSUB 5000 
 3030 GOSUB 8000 
 3035 IF PG(Z)=1 THEN21000 
 3040 IF Z>AN THENGOSUB 13000:GOTO 3100 
 3042 GOSUB 10900 
 3045 PRINT"{HOME}"SR$SU$"{CYAN,RVSON,SPACE}* AKTIVITAETEN *" 
 3050 PRINT"{HOME}"SR$SU$"{RVSON,2DOWN}HAUS KAUFEN{3SPACE}-> H" 
 3051 PRINT"{HOME}"SR$SU$"{RVSON,3DOWN}HYP. Z'ZAHLEN -> Z" 
 3052 PRINT"{HOME}"SR$SU$"{RVSON,4DOWN}ANGEB. MITSP. -> K" 
 3053 PRINT"{HOME}"SR$SU$"{RVSON,5DOWN}WUERFELN{6SPACE}-> W" 
 3054 TM$=TI$ 
 3055 GET A$:IF A$="" THEN3055 
 3057 TI$=TM$ 
 3060 IF A$="H" THENGOSUB 10900:GOSUB 12000:GOTO 3042 
 3065 IF A$="Z" THENGOSUB 10900:GOSUB 11000:GOTO 3042 
 3070 IF A$="K" THENGOSUB 10900:GOSUB 16000:GOTO 3042 
 3075 IF A$<>"W" THEN3045 
 3100 GOSUB 22000 
 3105 GOSUB 9000 
 3110 GOSUB 5000 
 3200 IF LO=1AND PO(Z)<>1 THENI=4000:GOTO 3210 
 3205 IF LO=1AND PO(Z)=1 THENI=8000:GOTO 3210 
 3206 GOTO 3220 
 3210 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" BEKOMMT" 
 3215 GOSUB 10800:PRINT"{2DOWN}"I"DM." 
 3216 GE(Z)=GE(Z)+I 
 3218 LO=0:FOR A=1 TO1500:NEXT 
 3220 IF PO(Z)=5OR PO(Z)=39 THENGOSUB 20500 
 3225 IF PO(Z)=8OR PO(Z)=23OR PO(Z)=37 THEN23000 
 3230 IF PO(Z)=3OR PO(Z)=18OR PO(Z)=34 THEN23100 
 3235 IF Z2=1 THENZ2=0:GOTO 3995 
 3240 IF PO(Z)=11 THENGOSUB 10900:GOTO 3285 
 3245 IF PO(Z)=21 THENGOSUB 10900:GOSUB 10800:PRINT"{RIGHT,DOWN}"SP$(Z)" BEKOMMT" 
 3250 IF PO(Z)=21 THENGOSUB 10800:PRINT"{2DOWN}"FP"DM." 
 3255 IF PO(Z)=21 THENGE(Z)=GE(Z)+FP:FP=0 
 3260 IF PO(Z)=31 THENPG(Z)=1:WU=20:GOTO 3105 
 3265 IF FA(PO(Z))=10 THENGOSUB 24000 
 3270 IF FA(PO(Z))=9 THENGOSUB 24200 
 3275 IF FA(PO(Z))>0AND FA(PO(Z))<9 THENGOSUB 24400 
 3280 IF Z2=1 THENZ2=0:GOTO 3995 
 3285 GOSUB 7000:GOSUB 20000 
 3287 FOR A=1 TO1000:NEXT 
 3290 IF WP$="PASCH"AND PG(Z)=0 THEN3400 
 3295 GOTO 3990 
 3400 IF Z<=AN THEN3100 
 3410 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}PASCH: NOCHMAL!":FOR A=1 TO1500:NEXT :GOTO 3100 
 3990 FOR A=1 TO1000:NEXT 
 3992 GOSUB 10900 
 3995 NEXT Z:IF TT>RU THEN27100 
 3996 GOTO 3000 
 5000 PRINT"{HOME,RVOFF}"LEFT$ (RE$,22);"{3DOWN,LIG.GREEN,17SPACE,DOWN,17LEFT}"; 
 5005 PRINT"{17SPACE}" 
 5010 PRINT"{HOME}"LEFT$ (RE$,22);"{DOWN,2DOWN,LIG.GREEN,RVSON}";SN$(PO(Z))" "BB$(SB(PO(Z)))"{RVOFF}"; 
 5015 IF PG(Z)=1 THENPRINT"{LEFT}#" 
 5020 IF FA(PO(Z))>0 THENPRINT"{HOME}"LEFT$ (RE$,22)"{DOWN,3DOWN,LIG.RED}BESITZER: "SP$(BE(PO(Z))) 
 5025 FOR A=1 TO100:NEXT 
 5030 PRINT"{HOME,RVOFF}"LEFT$ (RE$,22);"{3DOWN,LIG.GREEN,17SPACE,17LEFT}"; 
 5035 PRINT"{HOME}"LEFT$ (RE$,22);"{DOWN,2DOWN,LIG.GREEN}";SN$(PO(Z))" "BB$(SB(PO(Z))); 
 5040 IF PG(Z)=1 THENPRINT"{LEFT,RVSON}#{RVOFF}" 
 5050 RETURN 
 6000 PRINT"{HOME,GREEN}"LEFT$ (RE$,21);LEFT$ (UN$,16);"{RVSON,7SPACE,RVOFF}" 
 6010 PRINT"{HOME,GREEN}"LEFT$ (RE$,21);LEFT$ (UN$,16);"{RVSON}"SP$(Z)"{RVOFF}" 
 6015 RETURN 
 7000 GE(Z)=INT (GE(Z)/10)*10:G$=RIGHT$ (STR$ (GE(Z)),LEN (STR$ (GE(Z)))-1) 
 7005 PRINT"{HOME,PURPLE}"LEFT$ (RE$,21);LEFT$ (UN$,20);"{RVSON,7SPACE,RVOFF}" 
 7010 PRINT"{HOME,PURPLE}"LEFT$ (RE$,21);LEFT$ (UN$,20);"{RVSON}"G$"{RVOFF}" 
 7015 RETURN 
 8000 ZL=4:J=1 
 8002 FOR B=0 TOKO(J)-1:I=ST(J,B) 
 8005 IF BE(I)<>Z THEN8020 
 8007 IF ZL=22 THENGOSUB 8200 
 8010 PRINT"{HOME}"LEFT$ (UN$,ZL)"{RIGHT}"FA$(FA(I))"{RVSON,14SPACE,RVOFF,SPACE}- "BB$(SB(I)); 
 8011 IF HY(I)=1 THENPRINT"{LEFT}H"; 
 8012 PRINT"{18LEFT,RVSON}"SN$(I):ZL=ZL+1 
 8020 NEXT B 
 8025 J=J+1:IF J=11 THENRETURN 
 8030 GOTO 8002 
 8200 IF Z>AN THEN8300 
 8202 PRINT"{HOME}"LEFT$ (UN$,ZL+1)"{RIGHT,GREY3}WEITER MIT <SPACE>" 
 8204 TM$=TI$ 
 8205 GET A$:IF A$="" THEN8205 
 8206 TI$=TM$ 
 8210 GOSUB 10000:ZL=4:RETURN 
 8300 FOR A=1 TO2000:NEXT :GOTO 8210 
 9000 FOR A=1 TOABS (WU):Q=0 
 9005 FOR I=1 TO4:IF I=Z THEN9015 
 9010 IF PO(Z)=PO(I) THENQ=1:J=I 
 9015 NEXT I 
 9020 IF Q=0 THEN9030 
 9025 IF ASC (S$(J))<65 THENPOKE KN(PO(Z))+54272,1:POKE KN(PO(Z)),ASC (S$(J)):GOTO 9050 
 9027 POKE KN(PO(Z))+54272,1:POKE KN(PO(Z)),ASC (S$(J))-64:GOTO 9050 
 9030 POKE KN(PO(Z))+54272,FB(PO(Z)):POKE KN(PO(Z)),ZE(PO(Z)) 
 9050 PO(Z)=PO(Z)+SGN (WU) 
 9055 IF PO(Z)>40 THENPO(Z)=PO(Z)-40:IF LL=0AND PG(Z)=0 THENLO=1 
 9060 IF ASC (S$(Z))<65 THENPOKE KN(PO(Z))+54272,1:POKE KN(PO(Z)),ASC (S$(Z)):GOTO 9070 
 9065 POKE KN(PO(Z))+54272,1:POKE KN(PO(Z)),ASC (S$(Z))-64 
 9070 NEXT A:RETURN 
 10000 PRINT"{HOME,RVOFF,3DOWN,RIGHT}"; 
 10005 FOR A=1 TO20 
 10010 PRINT"{18SPACE,DOWN,18LEFT}"; 
 10015 NEXT 
 10020 RETURN 
 10800 PRINT"{HOME}"SU$SR$"{CYAN,RVSON}";:RETURN 
 10900 PRINT"{HOME}"SU$SR$LO$LP$LQ$:RETURN 
 11000 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}AUF WELCHER":GOSUB 10800 
 11002 PRINT"{2DOWN,RIGHT}STRASSE WILLST DU":GOSUB 10800:PRINT"{3DOWN,RIGHT}EINE HYPOTHEK" 
 11004 GOSUB 10800:PRINT"{4DOWN,RIGHT}ZURUECKZAHLEN ?" 
 11010 GOSUB 19000:GOSUB 10800:PRINT"{5DOWN,RIGHT}AUF "AT$(I):IF FE=1 THEN11025 
 11020 IF HY(I)=1AND GE(Z)>=.6*PR(I) THEN11030 
 11025 GOSUB 10800:PRINT"{6DOWN,RIGHT}FALSCHE EINGABE!":GOTO 11050 
 11030 HY(I)=0:GE(Z)=GE(Z)-.6*PR(I) 
 11035 KP(Z,FA(I))=KP(Z,FA(I))+1 
 11040 GOSUB 10000:GOSUB 8000:GOSUB 7000 
 11050 FOR A=1 TO1500:NEXT :RETURN 
 12000 GOSUB 10900:GOSUB 10800 
 12005 PRINT"{DOWN,RIGHT}AUF WELCHE":GOSUB 10800:PRINT"{2DOWN,RIGHT}STRASSEN WILLST":GOSUB 10800 
 12010 PRINT"{3DOWN,RIGHT}DU HAEUSER BAUEN?":GOSUB 10800:PRINT"{4DOWN,RIGHT}(DIE 1. ANGEBEN)" 
 12015 GOSUB 19000:IF FE=1 THEN12500 
 12020 IF BE(I)<>Z THEN12500 
 12025 IF I>38 THEN12500 
 12027 IF FA(I)<1OR FA(I)>8 THEN12500 
 12030 R=I 
 12035 W(0)=0:W(1)=0:W(2)=0 
 12040 FOR J=0 TOKO(FA(R))-1:B(J)=ST(FA(R),J):B$(J)=SN$(ST(FA(R),J)) 
 12045 IF BE(B(J))<>Z THENQ=1 
 12050 NEXT J 
 12055 IF Q=1 THENQ=0:GOTO 12500 
 12065 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,3RIGHT}WIEVIELE AUF .." 
 12070 FOR I=0 TOKO(FA(R))-1 
 12075 GOSUB 10800:PRINTLEFT$ (UN$,I+2)"{RIGHT}"B$(I); 
 12080 GET W$(I):IF W$(I)="" THEN12080 
 12085 IF ASC (W$(I))<48OR ASC (W$(I))>53 THEN12080 
 12090 GOSUB 10800:PRINTLEFT$ (UN$,I+2)"{17RIGHT}"W$(I):W(I)=VAL (W$(I)) 
 12095 NEXT I 
 12097 IF ABS (SB(B(0))+W(0)-SB(B(1))-W(1))>1 THEN12500 
 12100 IF KO(FA(R))=3AND ABS (SB(B(1))+W(1)-SB(B(2))-W(2))>1 THEN12500 
 12105 IF KO(FA(R))=3AND ABS (SB(B(0))+W(0)-SB(B(2))-W(2))>1 THEN12500 
 12110 FOR I=0 TOKO(FA(R))-1 
 12115 IF SB(B(I))+W(I)>5 THENQ=1 
 12120 NEXT I 
 12125 IF Q=1 THENQ=0:GOTO 12500 
 12130 PY=INT ((FA(R)+1)/2)*1000*(W(0)+W(1)+W(2)) 
 12135 GOSUB 10800:PRINT"{6DOWN,RIGHT}PREIS:"PY:GOSUB 19500 
 12140 IF PJ=1 THENRETURN 
 12145 FOR I=0 TOKO(FA(R))-1 
 12150 SB(B(I))=SB(B(I))+W(I) 
 12155 GT=GT+W(I) 
 12160 NEXT I 
 12165 GE(Z)=GE(Z)-PY:GOSUB 7000:GOSUB 10000:GOSUB 8000:FOR A=1 TO2000:NEXT :RETURN 
 12500 GOSUB 10800:PRINT"{6DOWN,RIGHT}FALSCHE EINGABE!":FOR A=1 TO2000:NEXT :RETURN 
 13000 GOSUB 13900:GOSUB 14000:IF S2=1 THEN13900 
 13005 GOSUB 15000:IF S2=1 THENGOSUB 13900 
 13010 GOSUB 13100:RETURN 
 13100 J=0:K=0:M2=9:KJ=0 
 13105 L(0)=0:L(1)=0 
 13110 FOR I=1 TO8 
 13115 IF KP(Z,I)=KO(I) THENK(J)=I:J=J+1:K=1 
 13120 NEXT I:IF K=0 THEN13400 
 13125 FOR K=1 TOJ 
 13130 IF GE(Z)<GT*200+RND (1)*5000OR GE(Z)<3*(INT ((K(J-1)+1)/2)*1000) THEN13400 
 13135 H=INT ((RND (1)/4+.5)*GE(Z)) 
 13140 M=INT (RND (1)*J):IF M=M2 THENM=M+1:IF M=J THENM=0 
 13145 N=INT (H/((INT ((K(M)+1)/2)*1000))) 
 13150 IF N=0 THEN13345 
 13155 M2=M 
 13160 FOR I=0 TOKO(K(M))-1 
 13165 B$(I)=SN$(ST(K(M),I)):B(I)=ST(K(M),I):NEXT I 
 13190 Y=SB(B(0))+SB(B(1))-(SB(B(2))*(KO(K(M))=3)) 
 13195 IF Y+N>5*KO(K(M)) THENN=5*KO(K(M))-Y 
 13200 IF N=0 THEN13345 
 13210 IF KO(K(M))=2 THEN13250 
 13215 IF SB(B(0))=SB(B(1))AND SB(B(0))=SB(B(2)) THEN13230 
 13220 IF SB(B(1))<SB(B(2))AND SB(B(1))<SB(B(0)) THENL(1)=1:N=N-1:GOTO 13230 
 13225 IF SB(B(0))=SB(B(1))AND SB(B(1))<SB(B(2)) THENL(0)=1:L(1)=1:N=N-2 
 13230 IF INT (N/3)=N/3 THENC(0)=N/3:C(1)=C(0):C(2)=C(0) 
 13235 IF INT ((N+2)/3)=(N+2)/3 THENC(0)=INT (N/3):C(1)=C(0):C(2)=C(0)+1 
 13240 IF INT ((N+1)/3)=(N+1)/3 THENC(0)=INT (N/3)+1:C(1)=C(0)-1:C(2)=C(0) 
 13245 C(0)=C(0)+L(0):C(1)=C(1)+L(1):N=N+L(0)+L(1):GOTO 13272 
 13250 IF SB(B(0))=SB(B(1)) THEN13260 
 13255 L(0)=1:N=N-1 
 13260 IF INT (N/2)=N/2 THENC(0)=N/2:C(1)=C(0) 
 13265 IF INT ((N+1)/2)=(N+1)/2 THENC(0)=INT (N/2):C(1)=C(0)+1 
 13270 C(0)=C(0)+L(0):N=N+L(0) 
 13272 FOR G=0 TOKO(K(M))-1 
 13273 IF C(G)+SB(B(G))>5 THENN=N-(C(G)+SB(B(G))-5):C(G)=5-SB(B(G)) 
 13274 NEXT G:IF N=0 THEN13345 
 13275 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" KAUFT":GOSUB 10800 
 13280 PRINT"{2DOWN,RIGHT}HAEUSER:{3SPACE}AUF.." 
 13285 L(0)=0:L(1)=0 
 13290 FOR G=0 TOKO(K(M))-1 
 13295 GOSUB 10800:PRINTLEFT$ (UN$,G+4)"{RIGHT}"B$(G) 
 13300 GOSUB 10800:PRINTLEFT$ (UN$,G+4)"{16RIGHT}"C(G) 
 13305 NEXT G 
 13310 FOR I=0 TOKO(K(M))-1 
 13315 SB(B(I))=SB(B(I))+C(I) 
 13320 GT=GT+C(I) 
 13325 NEXT I 
 13330 GE(Z)=GE(Z)-N*INT ((K(M)+1)/2)*1000 
 13335 XJ=J:GOSUB 7000:GOSUB 10000:GOSUB 8000:J=XJ 
 13340 FOR A=1 TO2000:NEXT A 
 13345 NEXT K 
 13400 RETURN 
 13900 GOSUB 10900 
 13910 GOSUB 10800:PRINT"{DOWN,RIGHT}* AKTIVITAETEN *":RETURN 
 14000 I=0:S2=0 
 14010 I=I+1:IF (BE(I)<>ZOR HY(I)=0)AND I<40 THEN14010 
 14020 IF I<40 THEN14060 
 14030 IF BE(40)=ZAND HY(40)=1 THEN14060 
 14040 IF S2=1 THENGOSUB 7000:GOSUB 10000:GOSUB 8000 
 14050 RETURN 
 14060 IF GE(Z)<.8*PR(I) THEN14040 
 14070 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" ZAHLT":GOSUB 10800 
 14075 PRINT"{2DOWN,RIGHT}HYPOTHEK AUF "AT$(I):GOSUB 10800:PRINT"{3DOWN,RIGHT}"SN$(I) 
 14078 GOSUB 10800:PRINT"{4DOWN,RIGHT}ZURUECK. 
 14080 GE(Z)=GE(Z)-.6*PR(I):HY(I)=0:S2=1 
 14085 KP(Z,FA(I))=KP(Z,FA(I))+1 
 14090 FOR A=1 TO1500:NEXT 
 14095 IF I=40 THEN14040 
 14100 GOTO 14010 
 15000 S2=0:N=0 
 15005 FOR I=1 TO8:A$="":Z4=0:Z5=0:Z6=0:Z7=0:IF N>=2 THEN15090 
 15010 IF KP(Z,I)=KO(I)OR KP(Z,I)=0 THEN15090 
 15015 FOR J=1 TO4:IF J=ZOR Z4<>0 THEN15025 
 15020 IF KP(J,I)>0 THENZ4=J 
 15025 NEXT J 
 15030 IF Z4=0 THEN15090 
 15035 FOR K=1 TO8:IF K=IOR Z5<>0 THEN15045 
 15040 IF (KP(Z4,K)=1OR KP(Z4,K)=2AND KO(K)=3)AND KP(Z,K)=1 THENZ5=K 
 15045 NEXT K 
 15050 IF Z5=0 THEN15069 
 15055 M=-1 
 15057 M=M+1:IF BE(ST(I,M))<>Z4 THEN15057 
 15060 Z7=ST(I,M):M=-1 
 15062 M=M+1:IF BE(ST(Z5,M))<>Z THEN15062 
 15065 Z6=ST(Z5,M):GOSUB 17500:N=N+1:S2=1:GOTO 15090 
 15069 M=-1 
 15070 M=M+1:IF BE(ST(I,M))<>Z4 THEN15070 
 15075 Z7=ST(I,M):PT=INT ((PR(Z7)*(1.9+RND (1)*1.4))/100)*100 
 15080 IF GE(Z)<PT THEN15090 
 15085 GOSUB 17000:S2=1:N=N+1 
 15090 IF A$="J" THENGOSUB 10000:GOSUB 8000:GOSUB 7000 
 15092 NEXT I 
 15095 IF S2=1 THENFOR A=1 TO3000:NEXT 
 15097 RETURN 
 16000 N=0 
 16002 N=N+1:IF N=3 THEN16500 
 16005 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}WELCHE STRASSE":GOSUB 10800 
 16006 PRINT"{2DOWN,RIGHT}WILLST DU ?" 
 16010 GOSUB 19000:IF FE=1 THEN16500 
 16012 FOR A=1 TO800:NEXT 
 16015 Z7=I 
 16020 IF SB(I)>0 THEN16500 
 16030 FOR J=0 TOKO(FA(J))-1:B(J)=ST(FA(I),J) 
 16035 NEXT J 
 16040 IF SB(B(1))>0 THEN16500 
 16045 IF M=3AND SB(B(2))>0 THEN16500 
 16050 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}VON WEM WILLST":GOSUB 10800 
 16051 PRINT"{2DOWN,RIGHT}DU "AR$(Z7):GOSUB 10800:PRINT"{3DOWN,RIGHT}"SN$(Z7)" ?" 
 16055 Z4=0 
 16060 TM$=TI$ 
 16065 GET A$:IF A$="" THEN16065 
 16066 TI$=TM$ 
 16070 FOR K=1 TO4:IF K=Z THEN16075 
 16072 IF A$=LEFT$ (SP$(K),1) THENZ4=K 
 16075 NEXT K 
 16080 IF Z4=0OR Z4<>BE(I) THEN16500 
 16085 GOSUB 10800:PRINT"{6DOWN,5RIGHT}"SP$(Z4) 
 16088 FOR A=1 TO1000:NEXT 
 16090 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}WILLST DU":GOSUB 10800 
 16095 PRINT"{2DOWN,RIGHT}KAUFEN (V) ODER":GOSUB 10800:PRINT"{3DOWN,RIGHT}TAUSCHEN (T) ?" 
 16099 TM$=TI$ 
 16100 GET A$:IF A$<>"V"AND A$<>"T" THEN16100 
 16101 TI$=TM$ 
 16105 IF A$="T" THEN16140 
 16110 GOSUB 10800:PRINT"{4DOWN,RIGHT}ZU WELCHEM PREIS?" 
 16113 B$="" 
 16115 GOSUB 10800:PRINT"{6DOWN,4RIGHT}DM "; 
 16116 GET A$:IF A$<>CHR$ (20) THEN16119 
 16117 IF LEN (B$)>0 THENPRINT"{LEFT,RVSON,SPACE,LEFT}";:B$=LEFT$ (B$,LEN (B$)-1) 
 16118 GOTO 16116 
 16119 IF A$<>""AND A$<>CHR$ (13) THENIF ASC (A$)<48OR ASC (A$)>57 THEN16116 
 16120 PRINTA$;:IF A$=CHR$ (13)AND LEN (B$)>0 THEN16122 
 16121 B$=B$+A$:GOTO 16116 
 16122 PT=VAL (B$) 
 16125 GOSUB 17000 
 16130 IF A$="J" THENGOSUB 10000:GOSUB 8000:GOSUB 7000 
 16135 FOR A=1 TO3000:NEXT :RETURN 
 16140 GOSUB 10800:PRINT"{4DOWN,RIGHT}GEGEN WELCHE ?":GOSUB 19000:IF FE=1 THEN16500 
 16145 Z6=I:J=I 
 16150 IF BE(J)<>Z THEN16500 
 16155 FOR K=0 TOKO(FA(J))-1:B(K)=ST(FA(J),K) 
 16160 NEXT K 
 16165 IF SB(J)>0OR SB(B(1))>0 THEN16500 
 16170 IF M=2AND SB(B(2))>0 THEN16500 
 16180 GOSUB 17500:GOTO 16130 
 16500 GOSUB 10800:PRINT"{6DOWN,RIGHT}FALSCHE EINGABE!":FOR A=1 TO1500:NEXT :GOSUB 10900 
 16510 RETURN 
 17000 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" WILL":GOSUB 10800 
 17002 PRINT"{2DOWN,RIGHT}VON "SP$(Z4)" "AR$(Z7) 
 17005 A$="" 
 17010 GOSUB 10800:PRINT"{3DOWN,RIGHT}"SN$(Z7):GOSUB 10800:PRINT"{4DOWN,RIGHT}FUER DM"PT 
 17015 GOSUB 10800:PRINT"{6DOWN,3RIGHT}(J/N)?" 
 17020 IF Z4>AN THEN17100 
 17024 TM$=TI$ 
 17025 GET A$:IF A$="" THEN17025 
 17026 TI$=TM$ 
 17030 IF A$="J" THEN17050 
 17035 IF A$="N" THEN17045 
 17040 GOTO 17024 
 17045 GOSUB 10800:PRINT"{6DOWN,11RIGHT}NEIN!":RETURN 
 17050 IF GE(Z)<PT THENGOSUB 10800:PRINT"{6DOWN,RIGHT}ZU WENIG GELD! " 
 17051 IF GE(Z)<PT THENRETURN 
 17055 GOSUB 10800:PRINT"{6DOWN,11RIGHT}JA!" 
 17060 BE(Z7)=Z 
 17061 IF HY(Z7)=0 THENKP(Z,FA(Z7))=KP(Z,FA(Z7))+1 
 17063 IF HY(Z7)=0 THENKP(Z4,FA(Z7))=KP(Z4,FA(Z7))-1 
 17065 GE(Z)=GE(Z)-PT:GE(Z4)=GE(Z4)+PT:RETURN 
 17100 IF KP(Z,FA(Z7))=KO(FA(Z7))-1 THENA$="N" 
 17105 IF KP(Z4,FA(Z7))>1 THENA$="N" 
 17110 M=0 
 17115 FOR J=1 TO8:IF KP(Z4,J)=KO(J) THENM=M+1 
 17120 NEXT J:IF M<2AND PT<3*PR(Z7) THENA$="N" 
 17125 IF PT<2*PR(Z7) THENA$="N" 
 17130 IF PT>3*PR(Z7)AND RND (1)<.5 THENA$="N" 
 17132 IF GE(Z4)>3000 THENA$="N" 
 17135 IF A$<>"N" THENA$="J" 
 17140 GOTO 17030 
 17500 R=PR(Z7)-PR(Z6):A$="" 
 17505 IF R>0AND GE(Z)<R THENRETURN 
 17510 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" WILL":GOSUB 10800 
 17512 PRINT"{2DOWN,RIGHT}VON "SP$(Z4)" "AR$(Z7):GOSUB 10800 
 17513 IF R>=0 THEN17520 
 17515 PRINT"{3DOWN,RIGHT}"SN$(Z7)" +":GOSUB 10800:PRINT"{4DOWN}"ABS (R)"DM GEGEN "AR$(Z6) 
 17517 GOSUB 10800:PRINT"{5DOWN,RIGHT}"SN$(Z6) 
 17518 GOTO 17525 
 17520 GOSUB 10800:PRINT"{3DOWN,RIGHT}"SN$(Z7):GOSUB 10800:PRINT"{4DOWN,RIGHT}GEGEN DM"ABS (R) 
 17522 GOSUB 10800:PRINT"{5DOWN,RIGHT}+ "SN$(Z6) 
 17525 GOSUB 10800:PRINT"{6DOWN,3RIGHT}(J/N)?" 
 17530 IF Z4>AN THEN17600 
 17534 TM$=TI$ 
 17535 GET A$:IF A$="" THEN17535 
 17536 TI$=TM$ 
 17540 IF A$="J" THEN17555 
 17545 IF A$="N" THEN17552 
 17550 GOTO 17534 
 17552 GOSUB 10800:PRINT"{6DOWN,11RIGHT}NEIN!":RETURN 
 17555 GOSUB 10800:PRINT"{6DOWN,12RIGHT}JA!" 
 17556 IF R>0AND GE(Z)<R THENGOSUB 10800:PRINT"{6DOWN,RIGHT}ZU WENIG GELD":GOTO 17575 
 17557 IF R<0AND GE(Z4)<(-R) THENGOSUB 10800:PRINT"{6DOWN,RIGHT}ZU WENIG GELD":GOTO 17575 
 17560 BE(Z7)=Z:BE(Z6)=Z4 
 17561 IF HY(Z7)=0 THENKP(Z,FA(Z7))=KP(Z,FA(Z7))+1 
 17563 IF HY(Z7)=0 THENKP(Z4,FA(Z7))=KP(Z4,FA(Z7))-1 
 17565 IF HY(Z6)=0 THENKP(Z4,FA(Z6))=KP(Z4,FA(Z6))+1 
 17567 IF HY(Z6)=0 THENKP(Z,FA(Z6))=KP(Z,FA(Z6))-1 
 17570 GE(Z)=GE(Z)-R:GE(Z4)=GE(Z4)+R 
 17575 RETURN 
 17600 IF KP(Z,FA(Z7))-KO(FA(Z7))<=KP(Z4,FA(Z6))-KO(FA(Z6)) THENA$="J" 
 17602 IF A$<>"J" THENA$="N" 
 17605 IF R<0AND GE(Z4)<ABS (R) THENA$="N" 
 17610 GOTO 17540 
 18000 IF GE(Z)<Z9 THEN18015 
 18005 IF Z>AN THENGOSUB 10000:GOSUB 8000 
 18010 V=0:FOR A=1 TO1000:NEXT :RETURN 
 18015 Q=0 
 18020 FOR I=1 TO40 
 18025 IF BE(I)=Z THENQ=1 
 18030 NEXT I 
 18035 IF Q=0 THEN27000 
 18040 GOSUB 18100:GOSUB 7000:GOTO 18000 
 18100 IF Z>AN THEN18500 
 18105 GOSUB 10900:GOSUB 10800:PRINT"{DOWN}HAEUSER VERK. -> V" 
 18110 GOSUB 10800:PRINT"{2DOWN}HYPOTHEK AUFN.-> H" 
 18115 GOSUB 10800:PRINT"{3DOWN}STRASSE VERK. -> S" 
 18120 GOSUB 10800:PRINT"{5DOWN,2RIGHT}SCHULD:"Z9 
 18124 TM$=TI$ 
 18125 GET A$:IF A$="" THEN18125 
 18126 TI$=TM$ 
 18127 IF A$="V" THEN18300 
 18128 IF A$="H" THEN18200 
 18129 IF A$<>"S" THEN18124 
 18130 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}WELCHE STRASSE":GOSUB 10800:PRINT"{2DOWN,RIGHT}WILLST DU" 
 18135 GOSUB 10800:PRINT"{3DOWN,RIGHT}VERKAUFEN?" 
 18140 GOSUB 19000:IF FE=1 THEN18105 
 18142 IF BE(I)<>Z THEN18400 
 18144 FOR J=0 TO2 
 18146 B(J)=ST(FA(I),J) 
 18148 NEXT J 
 18150 Q=0 
 18152 FOR J=0 TOKO(FA(I)) 
 18154 IF SB(B(J))>0 THENQ=1 
 18156 NEXT J 
 18160 IF Q=1 THEN18400 
 18165 BE(I)=5 
 18170 GE(Z)=GE(Z)+PR(I)*(1+(.5*(HY(I)=1))) 
 18172 IF HY(I)=0 THENKP(Z,FA(I))=KP(Z,FA(I))-1 
 18175 HY(I)=0:GOSUB 10000:GOSUB 8000:RETURN 
 18200 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}AUF WELCHE":GOSUB 10800:PRINT"{2DOWN,RIGHT}STRASSE WILLST" 
 18205 GOSUB 10800:PRINT"{3DOWN,RIGHT}DU EINE HYPOTHEK":GOSUB 10800:PRINT"{4DOWN,RIGHT}AUFNEHMEN?" 
 18210 GOSUB 19000:IF FE=1 THEN18105 
 18215 IF BE(I)<>Z THEN18400 
 18220 FOR J=0 TOKO(FA(I))-1 
 18225 B(J)=ST(FA(I),J) 
 18230 NEXT J 
 18235 Q=0 
 18240 FOR J=0 TOKO(FA(I))-1 
 18245 IF SB(B(J))>0 THENQ=1 
 18250 NEXT J 
 18255 IF Q=1 THEN18400 
 18260 IF HY(I)=1 THEN18400 
 18265 GE(Z)=GE(Z)+.5*PR(I) 
 18267 KP(Z,FA(I))=KP(Z,FA(I))-1 
 18270 HY(I)=1:GOSUB 10000:GOSUB 8000:RETURN 
 18300 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}AUF WELCHEM":GOSUB 10800:PRINT"{2DOWN,RIGHT}STRASSENZUG 
 18305 GOSUB 10800:PRINT"{3DOWN,RIGHT}WILLST DU HAEUSER":GOSUB 10800:PRINT"{4DOWN,RIGHT}VERKAUFEN?" 
 18310 GOSUB 10800:PRINT"{5DOWN,RIGHT}(DIE 1. ANGEBEN)" 
 18315 GOSUB 19000:IF FE=1 THEN18105 
 18325 FOR J=0 TOKO(FA(I))-1 
 18330 B(J)=ST(FA(I),J) 
 18332 NEXT J 
 18335 GOSUB 10900 
 18337 FOR J=0 TOKO(FA(I))-1 
 18340 GOSUB 10800:PRINTLEFT$ (UN$,J+1)SN$(B(J))":" 
 18345 GET A$:IF A$="" THEN18345 
 18347 IF ASC (A$)<48OR ASC (A$)>53 THEN18345 
 18350 W(J)=VAL (A$):GOSUB 10800:PRINTLEFT$ (UN$,J+1)"{16RIGHT}"W(J) 
 18355 C(J)=SB(B(J))-W(J) 
 18360 NEXT J 
 18370 IF ABS (C(0)-C(1))>1 THEN18400 
 18372 IF KO(FA(I))=3AND ABS (C(0)-C(2))>1 THEN18400 
 18374 IF KO(FA(I))=3AND ABS (C(1)-C(2))>1 THEN18400 
 18376 W=W(0)+W(1)+W(2) 
 18378 FOR J=0 TOKO(FA(I))-1 
 18380 SB(B(J))=SB(B(J))-W(J) 
 18385 NEXT J 
 18390 GE(Z)=GE(Z)+W*500*INT ((FA(I)+1)/2) 
 18395 GT=GT-W:Z4=I:GOSUB 10000:GOSUB 8000:GOTO 18965 
 18400 GOSUB 10900:GOSUB 10800:PRINT"{2DOWN,RIGHT}DAS GEHT NICHT!" 
 18405 FOR A=1 TO1500:NEXT :GOTO 18105 
 18500 Z4=0:O=1 
 18505 FOR B=1 TO10:FOR C=0 TOKO(B)-1:I=ST(B,C):IF Z4<>0 THEN18514 
 18510 IF V>0 THENGOSUB 18615:GOTO 18514 
 18512 ON OGOSUB 18525,18540,18555,18570,18585,18600,18615,18630,18645 
 18514 NEXT C,B 
 18516 IF Z4<>0 THENON Z5GOTO 18900,18920,18940 
 18518 O=O+1:IF O<10 THEN18505 
 18520 RETURN 
 18525 IF (FA(I)=9OR FA(I)=10)AND BE(I)=ZAND HY(I)=0 THENZ4=I:Z5=1 
 18526 RETURN 
 18540 IF KP(Z,FA(I))=1AND BE(I)=ZAND HY(I)=0 THENZ4=I:Z5=1 
 18541 RETURN 
 18555 IF KP(Z,FA(I))=2AND KO(FA(I))=3AND BE(I)=ZAND HY(I)=0 THENZ4=I:Z5=1 
 18556 RETURN 
 18570 IF (FA(I)=9OR FA(I)=10)AND BE(I)=Z THENZ4=I:Z5=2 
 18571 RETURN 
 18585 IF KP(Z,FA(I))=0AND BE(I)=ZAND HY(I)=1 THENZ4=I:Z5=2 
 18586 RETURN 
 18600 IF KP(Z,FA(I))=0AND KO(FA(I))=3AND BE(I)=ZAND HY(I)=1 THENZ4=I:Z5=2 
 18601 RETURN 
 18615 IF KP(Z,FA(I))<KO(FA(I)) THENRETURN 
 18616 V=0:FOR J=0 TOKO(FA(I))-1 
 18617 B(J)=ST(FA(I),J) 
 18618 V=V+SB(B(J)) 
 18619 NEXT J 
 18620 IF V=0 THENRETURN 
 18621 M=0 
 18622 FOR J=0 TOKO(FA(I))-1 
 18623 IF SB(B(J))>M THENM=SB(B(J)):Z4=B(J) 
 18624 NEXT J:Z5=3:RETURN 
 18630 IF BE(I)=ZAND HY(I)=0 THENZ4=I:Z5=1 
 18631 RETURN 
 18645 IF BE(I)=Z THENZ4=I:Z5=2 
 18646 RETURN 
 18900 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" NIMMT":GOSUB 10800 
 18902 PRINT"{2DOWN,RIGHT}HYPOTHEK AUF "AR$(Z4):GOSUB 10800:PRINT"{3DOWN,RIGHT}"SN$(Z4)" 
 18905 GOSUB 10800:PRINT"{4DOWN,RIGHT}AUF.":GOSUB 10800:PRINT"{6DOWN,RIGHT}SCHULD:"Z9 
 18910 GE(Z)=GE(Z)+.5*PR(Z4) 
 18913 KP(Z,FA(Z4))=KP(Z,FA(Z4))-1 
 18915 HY(Z4)=1:RETURN 
 18920 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z):GOSUB 10800 
 18922 PRINT"{2DOWN,RIGHT}VERKAUFT "AR$(Z4):GOSUB 10800 
 18925 PRINT"{3DOWN,RIGHT}"SN$(Z4) 
 18930 GOSUB 10800:PRINT"{6DOWN,RIGHT}SCHULD:"Z9 
 18932 GE(Z)=GE(Z)+.5*PR(Z4) 
 18933 IF HY(Z4)=0 THENKP(Z,FA(Z4))=KP(Z,FA(Z4))-1 
 18935 BE(Z4)=5:HY(Z4)=0:RETURN 
 18940 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" VERKAUFT":GOSUB 10800 
 18942 PRINT"{2DOWN,RIGHT}EIN HAUS AUF "AT$(Z4):GOSUB 10800:PRINT"{3DOWN,RIGHT}"SN$(Z4) 
 18945 GOSUB 10800:PRINT"{6DOWN,RIGHT}SCHULD:"Z9 
 18950 SB(Z4)=SB(Z4)-1:V=V-1 
 18955 GE(Z)=GE(Z)+INT ((FA(Z4)+1)/2)*500 
 18960 GT=GT-1 
 18965 RETURN 
 19000 FE=0 
 19002 GET B$:IF B$="" THEN19000 
 19005 GET C$:IF C$="" THEN19005 
 19010 GET D$:IF D$="" THEN19010 
 19015 A$=B$+C$+D$ 
 19020 IF A$="SCH" THEN19100 
 19025 IF A$="HAU" THEN19130 
 19030 I=0 
 19035 I=I+1:IF I=41 THEN19045 
 19040 IF LEFT$ (SN$(I),3)<>A$ THEN19035 
 19045 IF I=41 THEN19300 
 19050 GOTO 19180 
 19100 GET B$:IF B$="" THEN19100 
 19105 IF B$="L" THENI=40:GOTO 19180 
 19110 IF B$<>"I" THEN19300 
 19115 I=27:GOTO 19180 
 19130 GET B$:IF B$="" THEN19130 
 19135 GET B$:IF B$="" THEN19135 
 19140 GET B$:IF B$="" THEN19140 
 19145 IF B$="S" THENI=33:GOTO 19180 
 19150 IF B$<>"B" THEN19300 
 19155 I=36:GOTO 19180 
 19180 A$=SN$(I) 
 19190 GOSUB 10800:PRINT"{6DOWN,RIGHT}"A$ 
 19195 RETURN 
 19300 FE=1:RETURN 
 19500 IF GE(Z)>PY THENPJ=0:RETURN 
 19510 PJ=1:GOSUB 10800:PRINT"{5DOWN,RIGHT}"SP$(Z)" HAT NICHT":GOSUB 10800 
 19515 PRINT"{6DOWN,RIGHT}GENUG GELD." 
 19520 RETURN 
 20000 TT=VAL (LEFT$ (TI$,2))*60+VAL (MID$ (TI$,3,2)) 
 20002 PRINT"{HOME,GREY1}"TR$TU$;"{5SPACE,5LEFT}"STR$ (RU-TT) 
 20005 PRINT"{HOME,GREY1}"FR$FU$;"{6SPACE,6LEFT}"STR$ (FP) 
 20010 RETURN 
 20500 IF PO(Z)=39 THENGOTO 20520 
 20505 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" MUSS" 
 20510 GOSUB 10800:PRINT"{2DOWN,RIGHT}4000 DM ZAHLEN." 
 20515 BZ=4000:GOTO 20550 
 20520 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" MUSS" 
 20525 GOSUB 10800:PRINT"{2DOWN,RIGHT}2000 DM ZAHLEN." 
 20530 BZ=2000:GOTO 20550 
 20550 IF BZ>GE(Z) THENZ9=BZ:GOSUB 18000 
 20555 GE(Z)=GE(Z)-BZ:FP=FP+BZ:RETURN 
 21000 GOSUB 22000:GW(Z)=GW(Z)+1 
 21010 IF WP$="PASCH" THENPG(Z)=0:GW(Z)=0:GOSUB 21100:GOTO 3105 
 21015 IF GW(Z)=3 THENGW(Z)=0:PG(Z)=0:Z9=1000:GOSUB 21150:GOTO 21040 
 21020 IF FF(Z)=1 THENPG(Z)=0:GW(Z)=0:FF(Z)=0:GOTO 21065 
 21021 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}WILLST DU DICH":GOSUB 10800 
 21022 PRINT"{2DOWN,RIGHT}FUER DM 1000":GOSUB 10800:PRINT"{3DOWN,RIGHT}FREIKAUFEN ?":GOSUB 10800 
 21023 PRINT"{5DOWN,3RIGHT}(J/N)";:IF Z>AN THEN21030 
 21024 TM$=TI$ 
 21025 GET A$:IF A$<>"J"AND A$<>"N" THEN21025 
 21026 TI$=TM$ 
 21027 IF A$="J"AND GE(Z)>=1000 THENGW(Z)=3:PRINT" JA!":FOR A=1 TO1000:NEXT :GOTO 21015 
 21028 PRINT" NEIN!":FOR A=1 TO1000:NEXT :GOTO 3235 
 21030 IF GT>10OR GE(Z)<1000 THENA$="N" 
 21031 IF GE(Z)>1000AND (WU=10OR WU=7) THENA$="J" 
 21032 IF A$="N" THENPRINT" NEIN!":FOR A=1 TO1000:NEXT :GOTO 3235 
 21033 PRINT" JA!" 
 21035 FOR A=1 TO1000:NEXT :GW(Z)=3:GOTO 21015 
 21040 IF GE(Z)<Z9 THENGOSUB 18000 
 21045 IF Z2=1 THEN3235 
 21050 GE(Z)=GE(Z)-1000:GOTO 3105 
 21065 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,3RIGHT}E/G-KARTE:" 
 21066 GOSUB 10800:PRINT"{2DOWN,RIGHT}DU KOMMST AUS":GOSUB 10800:PRINT"{3DOWN,RIGHT}DEM GEFAENGNIS" 
 21067 GOSUB 10800:PRINT"{4DOWN,RIGHT}FREI." 
 21070 GOTO 3105 
 21100 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,4RIGHT}* PASCH *" 
 21105 GOSUB 10800:PRINT"{2DOWN,RIGHT}DU KOMMST AUS":GOSUB 10800:PRINT"{3DOWN,RIGHT}DEM GEFAENGNIS" 
 21110 GOSUB 10800:PRINT"{4DOWN,RIGHT}FREI." 
 21115 RETURN 
 21150 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}DU KOMMST FUER" 
 21155 GOSUB 10800:PRINT"{2DOWN,RIGHT}1000 DM AUS DEM":GOSUB 10800:PRINT"{3DOWN,RIGHT}GEFAENGNIS FREI" 
 21160 RETURN 
 21999 GOTO 3100 
 22000 GOSUB 10900 
 22005 GOSUB 10800:PRINT"{DOWN,3RIGHT}* WUERFELN *" 
 22010 IF Z>ANOR (PG(Z)=0AND WP$="") THEN22025 
 22015 GOSUB 10800:PRINT"{RVOFF,3DOWN,6RIGHT}RETURN" 
 22019 TM$=TI$ 
 22020 GET A$:IF A$<>CHR$ (13) THEN22020 
 22021 TI$=TM$:GOSUB 10800:PRINT"{3DOWN,6RIGHT,6SPACE}" 
 22025 W(1)=6:W(2)=6 
 22030 B(1)=INT (RND (1)*12)+13 
 22040 B(2)=INT (RND (1)*12)+13 
 22045 IF B(1)>=B(2) THENX=B(1):GOTO 22050 
 22046 X=B(2) 
 22050 FOR Y=1 TOX:FOR I=1 TO2 
 22052 IF Y>B(I) THEN22056 
 22055 W(I)=W(I)-1:IF W(I)=0 THENW(I)=6 
 22056 NEXT I 
 22057 PRINT"{HOME}"LEFT$ (RE$,21)LEFT$ (UN$,22); 
 22058 ON W(1)GOSUB 22200,22210,22220,22230,22240,22250 
 22059 PRINT"{HOME}"LEFT$ (RE$,25)LEFT$ (UN$,22); 
 22060 ON W(2)GOSUB 22200,22210,22220,22230,22240,22250 
 22065 NEXT Y 
 22070 IF W(1)=W(2) THENWP$="PASCH" 
 22072 IF W(1)<>W(2) THENWP$="" 
 22075 IF WP$="PASCH" THENP=P+1:IF P=3 THENPG(Z)=1:WU=11-PO(Z):IF WU<0 THENWU=WU+40 
 22080 IF P=3 THEN22100 
 22085 WU=W(1)+W(2) 
 22090 RETURN 
 22100 GOSUB 10900:GOSUB 10800 
 22105 PRINT"{DOWN}DREIMAL PASCH:" 
 22110 GOSUB 10800:PRINT"{3DOWN}"SP$(Z)" MUSS INS" 
 22115 GOSUB 10800:PRINT"{4DOWN}GEFAENGNIS." 
 22120 FOR A=1 TO2000:NEXT :RETURN 
 22200 PRINT"{LIG.GREEN,RVSON,3SPACE,DOWN,3LEFT,SPACE}Q{SPACE,DOWN,3LEFT,3SPACE}";:RETURN 
 22210 PRINT"{LIG.GREEN,RVSON,2SPACE}Q{DOWN,3LEFT,3SPACE,DOWN,3LEFT}Q{2SPACE}";:RETURN 
 22220 PRINT"{LIG.GREEN,RVSON}Q{2SPACE,DOWN,3LEFT,SPACE}Q{SPACE,DOWN,3LEFT,2SPACE}Q";:RETURN 
 22230 PRINT"{LIG.GREEN,RVSON}Q Q{DOWN,3LEFT,3SPACE,DOWN,3LEFT}Q Q";:RETURN 
 22240 PRINT"{LIG.GREEN,RVSON}Q Q{DOWN,3LEFT,SPACE}Q{SPACE,DOWN,3LEFT}Q Q";:RETURN 
 22250 PRINT"{LIG.GREEN,RVSON}Q Q{DOWN,3LEFT}Q Q{DOWN,3LEFT}Q Q";:RETURN 
 23000 A=0 
 23002 IF LEN (ER$(A,EZ))>18 THEN23010 
 23005 A=A+1:GOTO 23002 
 23010 LT$=RIGHT$ (ER$(A,EZ),6):L1$=LEFT$ (LT$,1):E$(A)=LEFT$ (ER$(A,EZ),18) 
 23012 IF A>0 THENFOR B=0 TOA-1:E$(B)=ER$(B,EZ):NEXT B 
 23015 GOSUB 10900 
 23020 FOR I=0 TOA 
 23025 GOSUB 10800:PRINTLEFT$ (UN$,I+1)E$(I) 
 23030 NEXT I 
 23035 EZ=EZ+1:IF EZ=16 THENEZ=0 
 23040 GOTO 23140 
 23100 A=0 
 23102 IF LEN (GE$(A,GZ))>18 THEN23110 
 23105 A=A+1:GOTO 23102 
 23110 LT$=RIGHT$ (GE$(A,GZ),6):L1$=LEFT$ (LT$,1):G$(A)=LEFT$ (GE$(A,GZ),18) 
 23112 IF A>0 THENFOR B=0 TOA-1:G$(B)=GE$(B,GZ):NEXT B 
 23115 GOSUB 10900 
 23120 FOR I=0 TOA 
 23125 GOSUB 10800:PRINTLEFT$ (UN$,I+1)G$(I) 
 23130 NEXT I 
 23135 GZ=GZ+1:IF GZ=16 THENGZ=0 
 23140 IF MID$ (LT$,1,3)<>"0" THENL3=VAL (RIGHT$ (LT$,4)):GOTO 23160 
 23145 IF MID$ (LT$,1,4)<>"0" THENL3=VAL (RIGHT$ (LT$,3)):GOTO 23160 
 23150 IF MID$ (LT$,1,5)<>"0" THENL3=VAL (RIGHT$ (LT$,2)):GOTO 23160 
 23155 L3=VAL (RIGHT$ (LT$,1)):GOTO 23160 
 23160 IF L1$="X" THENWU=L3-PO(Z):IF WU<0 THENWU=WU+40 
 23162 IF L1$="X" THEN3105 
 23165 IF L1$="Y" THENWU=L3-PO(Z):LL=1 
 23166 IF L1$="Y" THEN3105 
 23170 IF L1$<>"Z" THEN23175 
 23171 IF L3>GE(Z) THENZ9=L3:GOSUB 18000 
 23172 IF Z2=1 THEN3235 
 23173 GE(Z)=GE(Z)-L3:FP=FP+L3:GOTO 3235 
 23175 IF L1$="E" THENGE(Z)=GE(Z)+L3:GOTO 3235 
 23180 IF L1$="G" THENWU=-3:LL=1:GOTO 3105 
 23185 IF L1$="F" THENFF(Z)=1:GOTO 3235 
 23190 IF L1$="K" THENPG(Z)=1:WU=11-PO(Z):IF WU<0 THENWU=WU+40 
 23195 IF L1$="K" THENGOSUB 9000:GOTO 3235 
 23200 IF L1$<>"A" THEN23220 
 23201 GOSUB 10800:PRINT"{6DOWN,RVOFF}E{RVSON}'KARTE -{SPACE,RVOFF}Z{RVSON}AHLEN ?" 
 23202 IF Z<=AN THEN23205 
 23203 IF RND (1)<.5OR GE(Z)<200 THEN23210 
 23204 GOTO 23215 
 23205 TM$=TI$ 
 23206 GET A$:IF A$="" THEN23205 
 23207 TI$=TM$:IF A$="E" THEN23210 
 23208 IF A$<>"Z" THEN23205 
 23209 GOTO 23215 
 23210 Q$="{6DOWN,8RIGHT,10SPACE}" 
 23211 GOSUB 10800:PRINTQ$:FOR A=1 TO1500:NEXT 
 23212 GOTO 23000 
 23215 Q$="{6DOWN,9SPACE}" 
 23216 GOSUB 10800:PRINTQ$:IF GE(Z)<200 THEN23201 
 23217 GE(Z)=GE(Z)-200:FP=FP+200:GOTO 3235 
 23220 IF L1$<>"B" THEN23230 
 23221 FOR I=1 TO4:IF I=Z THEN23223 
 23222 IF GE(I)>200 THENGE(I)=GE(I)-200 
 23223 NEXT I 
 23224 GE(Z)=GE(Z)+600 
 23225 GOTO 3235 
 23230 IF L1$<>"S" THEN23250 
 23231 U=0 
 23232 FOR I=1 TO40 
 23233 IF SB(I)=5AND BE(I)=Z THENU=U+2300:GOTO 23235 
 23234 IF SB(I)>0AND BE(I)=Z THENU=U+800*SB(I) 
 23235 NEXT :GOSUB 10800:PRINT"{6DOWN,RIGHT}GESAMT:"U"DM" 
 23236 IF GE(Z)<U THENZ9=U:GOSUB 18000 
 23237 IF Z2=1 THEN3235 
 23238 GE(Z)=GE(Z)-U 
 23239 FP=FP+U 
 23240 GOTO 3235 
 23250 IF L1$<>"R" THEN3235 
 23251 U=0 
 23252 FOR I=1 TO40 
 23253 IF SB(I)=5AND BE(I)=Z THENU=U+2000:GOTO 23255 
 23254 IF SB(I)>0AND BE(I)=Z THENU=U+500*SB(I) 
 23255 NEXT I:GOSUB 10800:PRINT"{6DOWN,RIGHT}GESAMT:"U"DM" 
 23256 IF GE(Z)<U THENZ9=U:GOSUB 18000 
 23257 IF Z2=1 THEN3235 
 23258 GE(Z)=GE(Z)-U 
 23259 FP=FP+U 
 23260 GOTO 3235 
 24000 IF BE(PO(Z))=5 THEN24045 
 24005 IF BE(PO(Z))=Z THENGOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" IST" 
 24006 IF BE(PO(Z))=Z THENGOSUB 10800:PRINT"{2DOWN,RIGHT}SELBST BESITZER":RETURN 
 24010 IF BE(14)=BE(29)AND HY(14)=0AND HY(29)=0 THENMX=200*WU:GOTO 24020 
 24012 MX=80*WU 
 24015 IF HY(PO(Z))=1 THEN24500 
 24020 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" ZAHLT AN":GOSUB 10800 
 24025 PRINT"{2DOWN,RIGHT}"SP$(BE(PO(Z)));MX"DM":GOSUB 10800:PRINT"{3DOWN,RIGHT}MIETE." 
 24030 GE(BE(PO(Z)))=GE(BE(PO(Z)))+MX 
 24035 IF GE(Z)<MX THENZ9=MX:GOSUB 18000:IF Z2=1 THENRETURN 
 24040 GE(Z)=GE(Z)-MX:RETURN 
 24045 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SN$(PO(Z)):GOSUB 10800 
 24047 PRINT"{2DOWN,RIGHT}IST FUER"PR(PO(Z))"DM" 
 24050 GOSUB 10800:PRINT"{3DOWN,RIGHT}ZU VERKAUFEN.":GOSUB 10800:PRINT"{5DOWN,3RIGHT}(J/N)?" 
 24055 IF Z>AN THEN24135 
 24059 TM$=TI$ 
 24060 GET A$:IF A$<>"J"AND A$<>"N" THEN24060 
 24061 TI$=TM$ 
 24065 IF A$="N" THENGOSUB 10800:PRINT"{5DOWN,10RIGHT}NEIN !":RETURN 
 24070 GOSUB 10800:PRINT"{5DOWN,10RIGHT}JA !" 
 24075 PY=PR(PO(Z)) 
 24080 GOSUB 19500:IF PJ=1 THENRETURN 
 24085 GE(Z)=GE(Z)-PY 
 24090 BE(PO(Z))=Z 
 24095 KP(Z,FA(PO(Z)))=KP(Z,FA(PO(Z)))+1 
 24100 PRINT"{HOME}"LEFT$ (UN$,ZL)"{RIGHT}"FA$(FA(PO(Z)))"{RVSON,14SPACE,RVOFF,SPACE}- "BB$(SB(PO(Z))); 
 24102 PRINT"{18LEFT,RVSON}"SN$(PO(Z)) 
 24105 ZL=ZL+1:IF ZL=22 THENGOSUB 10000:ZL=4 
 24110 RETURN 
 24135 IF KP(Z,FA(PO(Z)))=0AND RND (1)<.1AND GE(Z)<2*PR(PO(Z)) THENA$="N":GOTO 24065 
 24140 IF GE(Z)>=PR(PO(Z)) THENA$="J":GOTO 24070 
 24145 A$="N":GOTO 24065 
 24200 IF BE(PO(Z))=5 THEN24045 
 24205 IF BE(PO(Z))=Z THENGOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" IST" 
 24206 IF BE(PO(Z))=Z THENGOSUB 10800:PRINT"{2DOWN,RIGHT}SELBST BESITZER":RETURN 
 24208 MX=(2^(KP(BE(PO(Z)),FA(PO(Z)))-1))*500 
 24210 GOTO 24015 
 24400 IF BE(PO(Z))=5 THEN24045 
 24405 IF BE(PO(Z))=Z THENGOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" IST" 
 24406 IF BE(PO(Z))=Z THENGOSUB 10800:PRINT"{2DOWN,RIGHT}SELBST BESITZER":RETURN 
 24410 MX=MI(PO(Z),SB(PO(Z))) 
 24415 IF KP(BE(PO(Z)),FA(PO(Z)))=KO(FA(PO(Z)))AND SB(PO(Z))=0 THENMX=MX*2 
 24420 GOTO 24015 
 24500 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}HYPOTHEK AUF "AT$(PO(Z)):GOSUB 10800 
 24505 PRINT"{2DOWN,RIGHT}"SN$(PO(Z))":":GOSUB 10800:PRINT"{4DOWN,RIGHT}KEINE MIETE!" 
 24510 RETURN 
 25000 DIM PR(40),MI(40,5),BE(40),AR$(40),GW(4) 
 25005 DIM SB(40),FA(40),KP(4,10),HY(40),GE(4),G1(4),GG(4),SP$(5),PO(4),PG(4) 
 25010 DIM ER$(4,15),GE$(4,15),V(15),KN(40),FB(40),ZE(40),AT$(40),ST(10,3) 
 25015 FOR A=1 TO4:GE(A)=30000:NEXT 
 25020 FOR A=1 TO40:READ PR(A):NEXT 
 25025 FOR A=1 TO40:FOR B=0 TO5:READ MI(A,B):NEXT B,A 
 25030 FOR A=1 TO40:BE(A)=5:NEXT 
 25035 FOR A=1 TO40:READ AR$(A):NEXT 
 25036 FOR A=1 TO40:READ AT$(A):NEXT 
 25040 FOR A=1 TO40:READ FA(A):NEXT 
 25045 FOR A=1 TO10:READ KO(A):NEXT 
 25050 FOR A=0 TO15:V(A)=A:NEXT 
 25055 FOR A=15 TO0STEP -1 
 25060 C=INT (RND (1)*(A+1)):E=0 
 25065 READ GE$(E,V(C)) 
 25070 IF LEN (GE$(E,V(C)))<=18 THENE=E+1:GOTO 25065 
 25075 IF C=A THEN25085 
 25080 FOR D=C TOA-1:V(D)=V(D+1):NEXT D 
 25085 NEXT A:RETURN 
 25090 FOR A=0 TO15:V(A)=A:NEXT 
 25095 FOR A=15 TO0STEP -1 
 25100 C=INT (RND (1)*(A+1)):E=0 
 25105 READ ER$(E,V(C)) 
 25110 IF LEN (ER$(E,V(C)))<=18 THENE=E+1:GOTO 25105 
 25115 IF C=A THEN25125 
 25120 FOR D=C TOA-1:V(D)=V(D+1):NEXT D 
 25125 NEXT A 
 25130 FOR A=1 TO4:READ NA$(A):NEXT 
 25135 FOR A=1 TO11:B=32-A 
 25136 KN(A)=2024-A:KN(B)=KN(A)-400 
 25137 NEXT A 
 25140 FOR A=12 TO20:B=52-A 
 25141 KN(A)=2013-40*(A-11):KN(B)=KN(A)+10 
 25142 NEXT A 
 25150 RE$="{40RIGHT}" 
 25155 UN$="{28DOWN}" 
 25160 TR$=LEFT$ (RE$,31):TU$=LEFT$ (UN$,17) 
 25165 FR$=LEFT$ (RE$,31):FU$=LEFT$ (UN$,22) 
 25170 SR$=LEFT$ (RE$,21):SU$=LEFT$ (UN$,6) 
 25175 L$="{CYAN,RVSON,18SPACE,DOWN,18LEFT}" 
 25180 FOR A=1 TO3:LO$=LO$+L$:NEXT 
 25185 FOR A=1 TO2:LP$=LP$+L$:NEXT 
 25190 FOR A=1 TO2:LQ$=LQ$+L$:NEXT 
 25200 FA$(1)="{BLUE}":FA$(2)="{CYAN}":FA$(3)="{PURPLE}":FA$(4)="{ORANGE}":FA$(5)="{RED}":FA$(6)="{YELLOW}" 
 25205 FA$(7)="{GREEN}":FA$(8)="{LIG.BLUE}":FA$(9)="{WHITE}":FA$(10)="{GREY2}" 
 25210 FOR A=1 TO40:READ FB(A),ZE(A):NEXT A 
 25215 RETURN 
 25220 FOR A=1 TO40:POKE KN(A)+54272,FB(A):POKE KN(A),ZE(A):NEXT 
 25300 B=0:C=0:D=0 
 25305 FOR A=1 TO40:READ SN$(A) 
 25310 IF FA(A)<9AND FA(A)>0 THENST(FA(A),B)=A:B=B+1:IF B=KO(FA(A)) THENB=0 
 25315 IF FA(A)=9 THENST(9,C)=A:C=C+1 
 25320 IF FA(A)=10 THENST(10,D)=A:D=D+1 
 25325 NEXT A 
 25999 RETURN 
 26000 DATA 0,1200,0,1600,0,4000,2000,0,2000,2400,0,2800,2800,3000,3200,4000 
 26005 DATA 3600,0,3600,4000,0,4400,0,4400,4800,4000,5200,5200,3000,5600,0,6000 
 26010 DATA 6000,0,6400,4000,0,7000,0,8000 
 26020 DATA 0,0,0,0,0,0 
 26025 DATA 40,200,600,1800,3200,5000 
 26030 DATA 0,0,0,0,0,0 
 26035 DATA 80,400,1200,3600,6400,9000 
 26040 DATA 0,0,0,0,0,0 
 26045 DATA 500,1000,2000,4000,0,0 
 26050 DATA 120,600,1800,5400,8000,11000 
 26055 DATA 0,0,0,0,0,0 
 26060 DATA 120,600,1800,5400,8000,11000 
 26065 DATA 160,800,2000,6000,9000,12000 
 26070 DATA 0,0,0,0,0,0 
 26075 DATA 200,1000,3000,9000,12000,15000 
 26080 DATA 200,1000,3000,9000,12000,15000 
 26085 DATA 1,1,1,1,1,1 
 26090 DATA 240,1200,3600,10000,13000,16000 
 26095 DATA 500,1000,2000,4000,0,0 
 26100 DATA 280,1400,4000,11000,15000,19000 
 26105 DATA 0,0,0,0,0,0 
 26110 DATA 280,1400,4000,11000,15000,19000 
 26115 DATA 320,1600,4400,12000,16000,20000 
 26120 DATA 0,0,0,0,0,0 
 26125 DATA 360,1800,5000,14000,17500,23000 
 26130 DATA 0,0,0,0,0,0 
 26135 DATA 360,1800,5000,14000,17500,23000 
 26140 DATA 400,2000,6000,15000,18500,24000 
 26145 DATA 500,1000,2000,4000,0,0 
 26150 DATA 440,2200,6600,17000,21000,25000 
 26155 DATA 440,2200,6600,17000,21000,25000 
 26160 DATA 1,1,1,1,1,1 
 26165 DATA 480,2400,7200,18000,22500,27000 
 26170 DATA 0,0,0,0,0,0 
 26175 DATA 520,2600,7800,19000,24000,28000 
 26180 DATA 520,2600,7800,19000,24000,28000 
 26185 DATA 0,0,0,0,0,0 
 26190 DATA 560,2800,8400,20000,25500,30000 
 26195 DATA 500,1000,2000,4000,0,0 
 26200 DATA 0,0,0,0,0,0 
 26205 DATA 700,3000,11000,25000,30000,35000 
 26210 DATA 0,0,0,0,0,0 
 26211 DATA 1000,4000,12000,28000,34000,40000 
 26212 DATA ,DIE,DAS,DIE,DIE,DEN,DIE,DAS,DIE,DIE,DAS,DIE,DIE,DAS,DIE,DEN,DIE,DAS 
 26213 DATA DIE,DIE,,DIE,DAS,DIE,DEN,DEN,DIE,DIE,DAS,DIE,,DEN,DIE,DAS,DIE,DEN 
 26214 DATA DAS,DIE,DIE,DIE 
 26215 DATA ,DER,DEM,DER,DER,DEM,DER,DEM,DER,DER,DEM,DER,DER,DEM,DER,DEM,DER,DEM 
 26216 DATA DER,DER,,DER,DEM,DER,DEM,DEM,DER,DER,DEM,DER,,DEM,DER,DEM,DER,DEM,DEM 
 26217 DATA DER,DER,DER 
 26275 DATA 0,1,0,1,0,9,2,0,2,2,0,3,3,10,3,9,4,0,4,4,0,5,0,5,5,9,6,6,10,6,0 
 26280 DATA 7,7,0,7,9,0,8,0,8 
 26285 DATA 2,3,3,3,3,3,3,2,4,2 
 26330 DATA "ZAHLE AN DAS KRAN- 
 26331 DATA "KENHAUS. DM 2000{2SPACE}Z 2000 
 26335 DATA " AUS LAGERVERKAEU- 
 26336 DATA " FEN ERHAELTST DU 
 26337 DATA " DM 100.{10SPACE}E 0100 
 26340 DATA " EINKOMMENSSTEUER- 
 26341 DATA " RUECKZAHLUNG. DU 
 26342 DATA " ERHAELTST DM 400.E 0400 
 26345 DATA "{3SPACE}ARZTKOSTEN. 
 26346 DATA "{3SPACE}ZAHLE DM 100.{2SPACE}Z 0100 
 26350 DATA "DU KOMMST AUS DEM 
 26351 DATA "GEFAENGNIS FREI.{2SPACE}F 0000 
 26355 DATA " ZAHLE DEINE VER- 
 26356 DATA " SICHERUNGSSUMME. 
 26357 DATA " DM 1000.{9SPACE}Z 1000 
 26360 DATA "BANKIRRTUM ZU 
 26361 DATA "DEINEN GUNSTEN. DU 
 26362 DATA "ERHAELTST DM 4000 E 4000 
 26365 DATA "DU HAST IM KREUZ- 
 26366 DATA "WORTRAETSEL GEWON- 
 26367 DATA "NEN. DU ERHAELTST 
 26368 DATA "DM 2000.{10SPACE}E 2000 
 26370 DATA " GEHE ZURUECK ZUR 
 26371 DATA " BADSSTRASSE.{5SPACE}Y 0002 
 26375 DATA "{3SPACE}GEHE IN DAS 
 26376 DATA "{3SPACE}GEFAENGNIS{5SPACE}K 0011 
 26380 DATA "DEINE JAHRESRENTE 
 26381 DATA "WIRD FAELLIG. 
 26382 DATA "ZIEHE DM 2000 EIN.E 2000 
 26385 DATA "DU HAST IN EINER 
 26386 DATA "SCHOENHEITSKONKUR- 
 26387 DATA "RENZ DEN 2. PREIS 
 26388 DATA "GEWONNEN. DU 
 26389 DATA "ERHAELTST DM 200{2SPACE}E 0200 
 26390 DATA " AUS VORZUGSAKTIEN 
 26391 DATA " ERHAELTST DU 7% 
 26392 DATA " DIVIDENDE. DM 500E 0500 
 26395 DATA " DU ERBST DM 2000.E 2000 
 26400 DATA " ZAHLE EINE STRA- 
 26401 DATA " FE VON DM 200 
 26402 DATA " ODER NIMM EINE 
 26403 DATA " EREIGNISKARTE.{3SPACE}A 0000 
 26405 DATA " RUECKE VOR BIS 
 26406 DATA " AUF LOS{10SPACE}X 0001 
 26410 DATA "{3SPACE}MACHE EINEN 
 26411 DATA "{3SPACE}AUSFLUG ZUM 
 26412 DATA "{3SPACE}WESTBAHNHOF{4SPACE}X 0016 
 26415 DATA " ZAHLE SCHULGELD. 
 26416 DATA " DM 3000.{9SPACE}Z 3000 
 26420 DATA "BETRUNKEN IM 
 26421 DATA "DIENST. ZAHLE EINE 
 26422 DATA "STRAFE VON DM 200.Z 0200 
 26425 DATA " RUECKE VOR BIS 
 26426 DATA " ZUR SCHLOSSALLEE.X 0040 
 26430 DATA " DIE BANK ZAHLT 
 26431 DATA " DIR EINE DIVIDEN- 
 26432 DATA " DE VON DM 1000.{2SPACE}E 1000 
 26435 DATA "{2SPACE}GEHE 3 FELDER 
 26436 DATA "{2SPACE}ZURUECK.{8SPACE}G 0003 
 26440 DATA " RUECKE VOR BIS 
 26441 DATA " ZUR SEESTRASSE.{2SPACE}X 0012 
 26445 DATA " STRAFE FUER ZU 
 26446 DATA " SCHNELLES FAHREN. 
 26447 DATA " DM 300.{10SPACE}Z 0300 
 26450 DATA " MIETE UND ANLEI- 
 26451 DATA " HEZINSEN WERDEN 
 26452 DATA " FAELLIG. DU ER- 
 26453 DATA " HAELTST DM 3000. E 3000 
 26455 DATA "{2SPACE}RUECKE VOR BIS 
 26456 DATA "{2SPACE}AUF LOS.{8SPACE}X 0001 
 26460 DATA " RUECKE VOR BIS 
 26461 DATA " ZUM OPERNPLATZ.{2SPACE}X 0025 
 26465 DATA " STRASSENAUSBES- 
 26466 DATA "{3SPACE}SERUNGSARBEITEN 
 26467 DATA "PRO HAUS-{2SPACE}DM 800 
 26468 DATA "PRO HOTEL- DM 2300S 0000 
 26470 DATA " LASSE DEINE HAEU- 
 26471 DATA " SER RENOVIEREN. 
 26472 DATA "PRO HAUS-{2SPACE}DM 500 
 26473 DATA "PRO HOTEL- DM 2000R 0000 
 26475 DATA "{3SPACE}GEHE IN DAS 
 26476 DATA "{3SPACE}GEFAENGNIS{5SPACE}K 0011 
 26480 DATA " ES IST DEIN GE- 
 26481 DATA " BURTSTAG. ZIEHE 
 26482 DATA " VON JEDEM SPIE- 
 26483 DATA " LER DM 200 EIN.{2SPACE}B 0200 
 26485 DATA " DU KOMMST AUS DEM 
 26486 DATA " GEFAENGNIS FREI. F 0000 
 26490 DATA 1 COMM,2 COMM,3 COMM,4 COMM 
 26500 DATA 1,159,6,130,12,160,6,148,11,160,1,147,3,131,12,160,3,133,3,144,10,163 
 26510 DATA 4,147,4,136,15,133,4,142,1,151,8,141,12,160,8,151,8,130,13,164 
 26515 DATA 2,141,12,160,2,148,2,143,1,142,7,147,7,140,15,151,7,135,10,161 
 26520 DATA 5,146,5,136,12,160,5,130,1,136,12,160,14,144,11,160,14,147 
 26620 DATA LOS,BADSTRASSE,GEMEINS.-FELD,TURMSTRASSE,EINKOM.-STEUER,SUEDBAHNHOF 
 26625 DATA CHAUSSEESTR.,EREIGNISFELD,ELISENSTRASSE,POSTSTRASSE,GEFAENGNIS 
 26630 DATA SEESTRASSE,HAFENSTRASSE,ELEKTR.-WERK,NEUE STRASSE,WESTBAHNHOF 
 26632 DATA MUENCHNER STR.,GEMEINS.-FELD,WIENER STRASSE,BERLINER STR.,FREI PARKEN 
 26635 DATA MUSEUMSSTRASSE,EREIGNISFELD,THEATERSTRASSE,OPERNPLATZ,NORDBAHNHOF 
 26640 DATA SCHILLERSTR.,LESSINGSTRASSE,WASSERWERK,GOETHESTRASSE,GEHE INS GEF. 
 26645 DATA RATHAUSPLATZ,HAUPTSTRASSE,GEMEINS.-FELD,BAHNHOFSTRASSE,HAUPTBAHNHOF 
 26650 DATA EREIGNISFELD,PARKSTRASSE,ZUSATZSTEUER,SCHLOSSALLEE 
 27000 GOSUB 10900:GOSUB 10800:PRINT"{DOWN,RIGHT}"SP$(Z)" IST":GOSUB 10800 
 27001 PRINT"{2DOWN,RIGHT}AUSGESCHIEDEN !" 
 27002 GE(Z)=0 
 27005 FOR I=1 TO40:IF BE(I)=Z THENBE(I)=5 
 27006 NEXT I 
 27010 FOR I=1 TO4:IF I=Z THEN27015 
 27012 IF PO(I)=PO(Z) THENQ=1:J=I 
 27015 NEXT I 
 27020 IF Q=0 THEN27030 
 27022 IF ASC (S$(J))<65 THENPOKE KN(PO(Z))+54272,1:POKE KN(PO(Z)),ASC (S$(J)) 
 27025 IF ASC (S$(J))>=65 THENPOKE KN(PO(Z))+54272,1:POKE KN(PO(Z)),ASC (S$(J))-64 
 27027 GOTO 27035 
 27030 POKE KN(PO(Z))+54272,FB(PO(Z)):POKE KN(PO(Z)),ZE(PO(Z)) 
 27035 PO(Z)=0 
 27040 J=0 
 27045 FOR I=1 TO4:IF PO(I)=0 THENJ=J+1 
 27050 NEXT I 
 27055 IF J=3 THEN27100 
 27075 Z2=1:RETURN 
 27100 FOR A=1 TO4:FOR I=1 TO40 
 27110 IF BE(I)=A THENG1(A)=G1(A)+PR(I)*(1+.5*(HY(I)=1)) 
 27115 IF BE(I)=AAND SB(I)>0 THENG1(A)=G1(A)+(INT ((FA(I)+1)/2)*500)*SB(I) 
 27120 NEXT I 
 27125 GG(A)=GE(A)+G1(A) 
 27130 NEXT A 
 27135 PRINT"{CLR}" 
 27137 PRINT:PRINT 
 27140 PRINT"{RED,9SPACE}E N D R E S U L T A T" 
 27145 PRINT"{BLUE,9SPACE}DDDDDDDDDDDDDDDDDDDDD" 
 27150 PRINT:PRINT 
 27155 PRINT"{YELLOW,SPACE}SPIELER:{2SPACE,PURPLE}KAPITAL:{2SPACE,CYAN}BESITZ:{3SPACE,ORANGE}GESAMT:" 
 27160 PRINT"{WHITE}----------------------------------------"; 
 27163 PRINT 
 27165 FOR A=1 TO4 
 27170 PRINTTAB( 1)"{YELLOW}"SP$(A);TAB( 11)"{PURPLE}"GE(A);TAB( 21)"{CYAN}"G1(A);TAB( 31)"{ORANGE}"GG(A) 
 27172 PRINT 
 27175 NEXT A 
 27180 PRINT:PRINT:PRINT 
 27185 PRINT"{GREEN,4SPACE}NOCH EIN SPIEL ? -> [SPACE]" 
 27190 GET A$:IF A$<>" " THEN27190 
 27200 RUN