C 64
Tips & Tricks

Apfelberge

Apfelmännchen sind nicht nur als Ebene darstellbar. Zeichnen Sie sie mit dreidimensionalen Effekten und in räumlicher Tiefe. Die Grafiken sehen aus wie Hochhaus- oder Gebirgs-Landschaften.

Dreidimensionale Darstellung eines Apfelmännchens als Landschaft aus senkrechten Balken auf einer Ebene

Vergleichen Sie das nebenstehende Bild mit einem Apfelmännchen aus Ausgabe 11/85, wird Ihnen die dem Programm zugrunde liegende Idee sofort auffallen. Die Anzahl der Iterationen bestimmt nun nicht mehr einen Farbwert, vielmehr stellt sie die Höhe eines Punktes über der Ebene dar. Die Höhe wird als Balken gezeichnet. Dabei besteht jeder Balken aus einer dunklen Vorderseite, einer etwas helleren rechten Seite und einer hellen Oberseite. Da diese Balken von links nach rechts und von hinten nach vorne aneinandergefügt werden, benötigt das Programm keinen Algorithmus zur Berechnung verdeckter Linien.

Das Programm »FRACTALBERGE« (siehe Listing 1) ist für Simons Basic geschrieben. Benötigt werden jedoch nur die Befehle zum Einschalten der Grafik und zum Zeichnen der Linien. Die das Bild bestimmenden Parameter sind in den Zeilen 5 bis 7 enthalten (Listing 2) und gliedern sich wie folgt.

Zeile 5: Festlegen der Farben, Gesamtgröße des Bildes
Zeile 6: Komplexe Parameter, Maximale Anzahl der Iterationen, maximale Höhe der Balken
Zeile 7: Ausschnitt des Bildes festlegen

Es wird immer ein rechteckförmiger Ausschnitt der Fractalebene dargestellt (Bild 1). Die Parallel-Perspektive entsteht durch das Verschieben jeder Zeile gegenüber der vorhergehenden um einen halben Bildpunkt nach links. Die Laufzeit beträgt im Durchschnitt über eine Stunde und ist je nach Bild nach oben beliebig offen.

(G.Paret/og)
Dreidimensionale Darstellung eines Apfelmännchens als flaches Plateau mit Höhenstufen
Bild 1. Apfelmännchen, fast wie ein Hochplateau
5 hires1,0:colour6,6:multi7,10,0:xm=105:ym=105
6 xc=1:yc=0:t=20:s=60
7 xl=-.15:xr=.26:yo=.47:yu=.9
8 dx=(xr-xl)/xm:dy=(yu-yo)/ym
9 forn=0toym:y1=yo+n*dy:form=0toxm:x=xl+m*dx:y=y1:k=0
10 x2=x*x:y2=y*y:y=2*x*y-yc:x=x2-y2-xc:k=k+1:if(k<t)and(x2+y2<s)then10
11 u=m+53-n/2:u1=u+1:v=n+80:v1=v-3*(k-1)
12 line u,v,u,v1,3:line u1,v,u1,v1,2:line u,v1,u1,v1,1
13 next:next
14 wait 198,255
Listing 1. »FRACTALBERGE« ist in Simons Basic geschrieben. Die Parameter entsprechen dem oberen Bild
5 hires 1,0:colour 0,0:multi 7,10,9:xm=105:ym=105
6 xc=.77:yc=.6:t=22:s=40
7 xl=-1.4:xr=1.4:yo=-.9:yu=1.2
8 dx=(xr-xl)/xm:dy=(yu-yo)/ym
9 forn=0toym:y1=yo+n*dy:form=0toxm:x=xl+m*dx:y=y1:k=0
10 x2=x*x:y2=y*y:y=2*x*y-yc:x=x2-y2-xc:k=k+1:if(k<t)and(x2+y2<s)then10
11 u=m+53-n/2:u1=u+1:v=n+80:v1=v-3*(k-1)
12 line u,v,u,v1,3:line u1,v,u1,v1,2:line u,v1,u1,v1,1
13 next:next
14 wait 198,255
Listing 2. Ein Beispiel für andere Parameter, entsprechend Bild 1
PDF Diesen Artikel als PDF herunterladen
Mastodon Diesen Artikel auf Mastodon teilen
← Vorheriger ArtikelNächster Artikel →