Cohan's Land

petcat | Checksummer

0 rem *********************************
2 rem *    c o h a n ' s   l a n d    *
4 rem *      copyright 1984 by        *
5 rem * supermike's fantasy products  *
7 rem *********************************
8 poke53280,0:poke53281,0:printchr$(14):sys65499:print"{clr}{yel}
9 zn=1:ro=10000+zn*100
11 data76,24,1,177,251,145,251,200,208,249,230,252,202,208,244,96,120,160
12 data0,169,160,132,251,133,252,162,32,32,11,1,169,224,132,251,133,252
13 data162,32,32,11,1,169,53,133,1,88,96:fori=264to310:reada:pokei,a:next
15 sys264:a=710:fori=atoa+20:readx:pokei,x:next
16 data208,3,76,29,168,32,192,2,32,19,166,56,165,95,233,1,164,96,76,36,168
18 poke40996,197:poke40997,2:poke1,54:a=43168:fori=atoa+2:readx:pokei,x:next
20 a=704:fori=atoa+5:readx:pokei,x:next:data32,192,2,32,138,173,76,247,183
25 gosub51000
30 print"{clr}{down}{down}{down}{down}{down}{down}";chr$(142)
36 print,"{yel}N{CBM-T} NP{CBM-N}{CBM-P}{SHIFT-@} NP{CBM-N}M {CBM-G}N N{CBM-T}
37 print,"L{CBM-P}{CBM-M}{CBM-P}{SHIFT-@}{CBM-N} {CBM-N} OP{CBM-N} M{CBM-G}  {CBM-Y}P
38 print,"                 {CBM-T}{CBM-T}
39 print,"    {CBM-H}  NP{CBM-N}M {CBM-H}OM
40 print,"    L{CBM-P} OP{CBM-N} M{CBM-H}LN
42 print,"{down}{down}{down}{lred}{left}ein abenteuerspiel von
43 print,"{down}{lred}  michael nickles":poke198,0:wait198,1
50 print"{clr}";chr$(14)
55 remge$(14)="Drahtgitter":ge(15)=-1:ma=0:ge(10)=-1:ge(16)=-1:ge(6)=-1
56 rem   ge(1)=-1:zb=10
57 remfori=1togz:ge(i)=-1:next
60 goto1040
1000 rem actionmodul -------------------
1001 ifrithen1015
1002 gosub50000
1010 ifri=0then2000
1015 ifri(ri)=0thenprint"Kein Weg in diese Richtung !":ri=0:goto2000
1016 ve=0:om=0:ob=0:pe=0:pm=0:rem ge=0
1020 ro=10000+100*ri(ri):zn=ri(ri):ri=0
1040 restorero:fori=1to10:readri(i):next
1041 ifpa(7)andzn=37thenri(2)=38
1050 print"{clr}{yel}";:gosub room
1100 rem ***** sie sehen
1700 se$="":ic=0:fori=1topz:ifpe(i)=znthenprintpe$(i)". ";:ic=1
1710 next:ificthenprint
1820 fori=1tooz:ifoo(i)=znthense$=se$+o$(i)+". ":ic=1
1822 next
1830 fori=1togz:ifge(i)=znthense$=se$+ge$(i)+". ":ic=1
1831 ifge(i)=-2andzn=1andtu(1)=0thense$=se$+ge$(i)+". ":ic=1
1832 ifge(i)=-3andzn=5andtu(3)=0thense$=se$+ge$(i)+". ":ic=1
1833 ifge(i)=-4andzn=43andtu(4)=0thense$=se$+ge$(i)+". ":ic=1
1834 nexti
1835 ifse$=""then1900
1840 iflen(se$)<41thenprintse$:goto1900
1850 i$=left$(se$,39)
1860 im=0:fori=1tolen(i$)
1865 :ifmid$(i$,i,1)=" "thenim=i
1868 nexti
1870 i$=left$(i$,im):printi$
1880 se$=right$(se$,len(se$)-im)
1890 goto1840
1900 print"Moegliche Richtungen : ";
1910 ic=0:fori=1to10:ifri(i)thenprintri$(i)",";:ic=1
1920 next:ific=0thenprint"keine ";
1930 print"{left} {down}"
2000 rem reagieren auf befehle ---------
2005 rem fehlermeldungen **************
2010 ifobandom=0thenprint"Das geht hier nicht .... noch nicht !"
2015 ifpeandpm=0thenprint"Ich sehe diese Person hier nicht !"
2019 ifve=16then2100
2020 ifve<>5andve<>8andg1andgm=0andg1<>12thenprint"Ich habe das nicht !"
2100 rem einwort-befehle **************
2105 ifve=3andob=0andgm=0thenve=0:goto1050:rem look
2110 ifve<>12then2130:rem inventur
2111 se$="Ich habe: ":ic=0:fori=1togz:ifge(i)=-1thense$=se$+ge$(i)+", ":ic=1
2112 nexti:ific=0thense$=se$+" nichts. "
2113 se$=left$(se$,len(se$)-1)
2116 iflen(se$)<41thenprintse$:goto2130
2117 i$=left$(se$,39)
2118 im=0:fori=1tolen(i$)
2119 :ifmid$(i$,i,1)=" "thenim=i
2120 nexti
2121 i$=left$(i$,im):printi$
2122 se$=right$(se$,len(se$)-im)
2123 goto2116
2130 ifve=19thenprint"Zeit vergeht......."
2200 rem nimm/verlier rout. ***********
2205 ifve<>5andve<>8org1=0orobthen2237
2220 ifve=5andge(g1)=-1thenprint"Ich habe das bereits !":goto2300
2222 ifve=8andge(g1)<>-1thenprint"Ich habe das nicht !"
2229 ifzn=27andve=5andge(5)=-4thenge(5)=-1:print"Ok.":goto2300
2230 ifve=5andge(g1)=znthenprint"Ok.":ge(g1)=-1:goto2250
2231 ifve=8andge(g1)=-1thenprint"Ok.":ge(g1)=zn
2232 ifve=5andge(g1)=-2andtu(1)=0thenprint"Ok.":ge(g1)=-1:goto2250
2233 ifve=5andge(g1)=-3andtu(3)=0thenprint"Ok.":ge(g1)=-1:goto2250
2234 ifve=5andge(g1)=-4andtu(4)=0thenprint"Ok.":ge(g1)=-1:goto2250
2237 ifg1andve=5andge(g1)<>znthenprint"Ich sehe das hier nicht !"
2238 ifve=5andg1=0andob<>0thenprint"Dazu bin ich nicht stark genug !"
2250 ifg1=15andfs=1thenfs=0
2252 ifg1=14andfa+fs=2then2625
2254 ifve=5andg1=16thenprint"Ich ziehe den Schutzanzug am besten so- fort an !"
2300 rem toete ************************
2310 ifve<>20then2400
2315 ifg1=0thenprint"Wie ? Doch nicht mit meinen blossen     Haenden !":goto2400
2320 ifgm=3thenprint"Ich greife mit dem Saebel an !"
2322 ifgm=10thenprint"Ich greife mit der Axt an !"
2324 ifgm=6andmu=0thenprint"Ich habe keine Munition mehr !":ge(7)=0:goto2400
2326 ifgm=6andmuthenprint"Ich schiesse mit der Pistole !":mu=mu-1
2330 ifpa(3)<6then2340
2332 ifzn<>71orgm<>6then2340
2334 print"Der Loewe bricht tot zusammen.":pe$(3)="Toter Loewe":pa(3)=-1
2335 pe(3)=10:sc=sc+7.5
2340 ifgm<>6andgm<>3andgm<>10orpa(4)<1then2350
2342 print"Das Krokodil stuerzt blutend ins Wasser.":pa(4)=-1:sc=sc+3.5
2350 ifzn<>61orom<>39orgm<>6then2360
2352 i=int(100*rnd(1))+1
2354 ifi>50orbr=2thenprint"Die Kugel verfehlt den Druckknopf knapp.":br=-1
2356 ifi<=50andbr<>2thenprint"Die Kugel trifft den Druckknopf exakt !":br=1
2360 :
2400 rem baue floss ******************
2410 ifve<>25org1<>12then2500
2420 ifge(11)<>-1thenprint"Ich habe kein Holz !":goto2500
2430 print"Ok.":ge(11)=0:ge(12)=-1
2500 ifve<>31andve<>42then2600: rem verbinde ******************
2505 ifg1+g2<>29then2600
2510 ifge(14)<>-1thenprint"Ich habe das Drahtgitter nicht !":goto2600
2520 ifge(15)<>-1then2600
2530 iffa=1thenprint"Das habe ich bereits.":goto2600
2535 print"Ok.":fa=1:rem iffs=1then2625
2600 ifve<>44andve<>42then2700:rem stecke **************
2610 ifom<>26then2700
2620 iffs=0thenprint"Ok.":ge(15)=zn:fs=1
2622 iffa<>1orge(14)<>-1then2630
2625 print"Das Drahtgitter glueht auf und verabrei-cht mir einen Elektroschock";
2626 print" von mehrerentausend Volt.":goto8000
2630 iffs=0andge(15)=-1thenprint"Ok.":ge(15)=zn:fs=1
2700 rem spezial action scenario
2710 ifzn=43orzn=51thenifma<>0then6145
2715 ifge(18)=-1andzb=11thenprint"Die Zeitbombe beginnt ploetzlich zu     ticken !"
2716 ifzb<11andge(18)=-1thenprint"Die Zeitbombe tickt immer schneller !"
2720 ifzbthenzb=zb-1:ifzb=0thenprint"Die Zeitbombe explodiert.":goto8000
2730 i=pa(9): rem strahlenverseuchung
2735 ifi=1thenprint"Mir wird ganz komisch von dem violetten Licht !"
2740 ifithenpa(9)=pa(9)+1:i=pa(9)
2745 ifi=5thenprint"Ich werde ploetzlich ganz schwach !"
2746 ifi=8thenprint"Ich werde immer schwaecher !"
2747 ifi=10thenprint"Meine Kraefte verlassen mich .....":goto8000
2800 ifve=28andgm=1thenprint"Ich bin kein Schiffsnavigator !"
2810 ifve<>37orgm<>8orge$(8)="Glasscherben"then2820
2815 print"Die Flasche zerspringt in Glasscherben. Eine Seekarte faellt auf ";
2816 print"den Boden.":ge$(8)="Glasscherben":ge(8)=zn:ge(1)=zn:sc=sc+2.5
2820 ifve<>49then2830
2822 ifge(2)<>-1andge(4)<>-1thenprint"Ich habe keinen Hunger.":goto2830
2824 print"Ok.":ge(2)=0:ge(4)=0:sc=sc+2.5
2830 :
4000 rem hilfe ***********************
4010 ifve<>30then5000
4999 rem  gosub61020
5000 rem u n t e r s u c h e -----------
5001 ifve<>3orom=0andgm=0then5999
5010 ic=0:ifom=7thenprint"Die Mauer ist unueberwindbar hoch.":ic=1
5015 ifom=14andoo(16)<>22thensc=sc+6.5
5020 ifom=14thenprint"Eine Schrift ist in die Wand geritzt.":oo(16)=22:ic=1
5030 ifom<>17then5035
5031 print"Die rechte Hand des Skeletts umklammert einen spitzen Kreidestein."
5032 ic=1:oo(15)=22
5035 ifom<>20then5037
5036 print"In einem Tropfstein ist eingeritzt :    POWERPETER{$a0}war hier !":ic=1
5037 ifom=24orom=1thenve=0:goto1050
5040 ifgm=7thenprint"Ich habe noch";mu;"Schuss !":ic=1
5050 ifgm<>15then5055
5051 print"Das Kabel ist ca 50m lang. Am einen Endehat es einen Stecker, am ";
5052 print"anderen Ende   ist es blank."
5053 ic=1
5055 ifom<>37orge(17)<>0then5060
5056 print"Der Tote hat einen Schluessel und eine  aktivierte ZEITBOMBE ";
5057 print"bei sich !":ge(17)=zn:ge(18)=zn:ic=1:zb=50
5060 ifgm<>18then5065
5062 print"Auf der Zeitbombe ist ein Zaehler ange- bracht der momentan den ";
5063 print"Wert";zb;"hat !":ic=1
5065 ifom<>43then5070
5066 print"Am Boden des Brunnens strahlt ein hellesLicht-Die QUELLE{$a0}DER{$a0}MACHT !"
5067 ic=1
5070 ifgm=8thenprint"In der Flasche ist eine Schriftrolle.":ic=1
5075 ifgm=16thenprint"Der Anzug schuezt vor radioaktiver      Strahlung.":ic=1
5500 ific=0thenprint"Ich entdecke nichts besonderes."
5999 :
6000 rem nichtspielerpersonen ----------
6010 rem ********** loewe
6015 ifzn=71andpa(3)<>-1then6035
6020 ifzn<6orzn>13orpa(3)=-1orint(10*rnd(1))+1<6orpa(4)then6100
6035 pa(3)=pa(3)+1:ifpa(3)<6thenprint"Im Gebuesch raschelt etwas !":rem  61010
6050 ifpa(3)=6thenprint"Ein riessiger Loewe springt aus dem Ge- buesch hervor !"
6051 ifpa(3)=6thenpe(3)=zn
6055 ifpa(3)=7andzn=71thenprint"Der Loewe springt am Baumstamm hoch !"
6060 ifpa(3)=8thenprint"Der Loewe faellt mich an !":goto8000
6100 rem ********** roboter
6105 ifzn<38orma=0then6200
6110 mw=mw+1:ma=ma(mw):ifma=-1thenmw=0:goto6110
6130 ic=0:fori=1to10:ifri(i)=mathenic=1
6135 next:ificthenprint"Ich hoere Schritte in der Naehe !"
6136 ifma<>ge(14)orfa+fs<>2then6140
6137 ma=0:pe(4)=ge(14):sc=sc+7
6138 ifpe(4)<>znthenprint"Ich hoere ein lautes Krachen !":goto6140
6139 print"Der Roboter laueft ueber das Drahtgitterund verschmort !"
6140 ifma<>znthen6150
6145 print"Ein riessiger Roboter erscheint !"
6146 print"Aus den Augen des Roboters schiesst ein Lichtstrahl auf mich ....."
6147 print"Ich werde muede ..... sehr muede ....."
6148 ri(1)=39:ri=1:pa(8)=1:poke198,0:wait198,1
6150 :
6200 gosub room+20:goto1000
7000 rem verloren
8000 print"Ich bin tot."
8010 print"{wht}Sie haben";sc;"% dieses Adventures geloest."
8020 fori=1to3000:next:poke198,0:wait198,1:run
10000 rem die landkarte ----------------
10100 data,,,,,,,,,,,:print"Gemuetlich eingerichtete Wohnstube."
10102 print"In einem offenen Kamin knistert ein be- hagliches Feuer."
10109 iftu(2)=0thenri(1)=2
10120 ifve=1andom=1thenprint"Ok.":tu(1)=0
10125 ifve=2andom=1thenprint"Ok.":tu(1)=1
10127 ifve=1andom=2orom=5thenprint"Ok.":tu(2)=0:ri(1)=2
10128 ifve=2andom=2orom=5thenprint"Ok.":tu(2)=1:ri(1)=0
10129 ifve<>8orom<>1then10140
10130 iftu(1)thenprint"Der Schrank ist geschlossen !":goto10140
10131 ifge(g1)=-1thenprint"Ok.":ge(g1)=-2:rem goto
10140 ifve=8andom=10andgm=1thenprint"Die Seekarte verbrennt.":ge(1)=0
10150 return
10200 data3,,,,,,,,,,,:print"Breite Strasse die zum Hafen fuehrt."
10203 print"Mr Bolings Haus.
10205 iftu(2)=0thenri(2)=1
10220 ifve=1andom=5thenprint"Ok.":tu(2)=0:ri(2)=1
10221 ifve=2andom=5thenprint"Ok.":tu(2)=1:ri(2)=0
10230 return
10300 data,2,,,,,,,,:print"Am grossen Hafen. Ein grosses Handels-  schiff, ";
10305 print"die 'Queen Mary' wird gerade    beladen."
10320 ifve=13andob=3thenri(1)=4:ri=1:ti$="000000"
10330 return
10400 data,,,,,,,,,,:print"Auf der Queen Mary."
10410 ifpa(0)then10419
10411 print"Kaeptan Graubart sagt : 'Hallo, willkom-men an Bord Mr Bolings ! ";
10412 print"Navigator an   Deck, hievt die Segel, holt den Anker   ein!'{down}"
10413 pa(0)=1
10419 return
10420 ifve=13andob=3thenri(1)=3:ri=1
10424 pa(0)=pa(0)+1:ifpa(0)>3thenpa(0)=3
10425 ifpa(0)=3thenprint"{yel}Das Schiff befindet sich auf hoher See."
10426 ifti$>"000300"then10440
10427 ifge(1)<>-1then10430
10428 ifve+pe+g1=18thenprint"{down}Der Navigator nimmt die Karte.":pa(1)=1:ge(1)=0
10429 ifve+pe+g1=18thensc=sc+2.5
10430 ifpa(1)thenpa(1)=pa(1)+1
10431 ifpa(1)=4thenprint"Ein Schiffsjunge ruft 'Land in Sicht !'.":ti$="000300"
10432 ifti$>"000030"andpa(2)=0thenprint"Ein schwerer Sturm bricht aus !":pa(2)=1
10433 return
10440 print"Ein starker Ruck zuckt ploetzlich durch das Schiff !"
10441 fori=1to4000:next
10445 print"Ein Matrose ruft 'Wir sind auf ein Riff aufgefahren und haben ein ";
10446 print"Leck......wir sinken....."
10450 poke198,0:wait198,1
10460 ifpa(1)=0thenprint"Ich ertrinke....":goto8000
10470 ri(1)=5:ri=1:return
10500 data,,,,,,6,,,:print"Am Inselstrand."
10502 print"Im Wasser in Strandnaehe treiben einige Schiffswrackteile.":return
10510 return
10520 ifve<>19oroo(4)thenifpa(3)<>5then10523
10521 print"Eine riessige Holztruhe wird ploetzlich an den Strand getrieben.
10522 oo(4)=5:pa(3)=6
10523 pa(3)=pa(3)+1
10530 ifve=1andom=4thenprint"Ok.":tu(3)=0:o$(4)="Offene Truhe"
10531 ifve=2andom=4thenprint"Ok.":tu(3)=1:o$(4)="Grosse Seemannstruhe"
10535 ifve=8andom=4andtu(3)=0andge(g1)=-1thenprint"Ok.":ge(g1)=-3
10540 return
10600 data,13,,,,5,12,,,:print"In dichtem Dschungel."
10620 return
10700 data,10,,,8,,9,,,:print"In dichtem Dschungel."
10720 return
10800 data,9,,,,,,7,,:print"In dichtem Dschungel."
10820 ifve=23andom=7thenprint"Die Mauer ist viel zu hoch dazu !"
10825 ifve=8andgm=5andom=7thenprint"Das Seil ist leider zu kurz !"
10830 return
10900 data8,8,,10,,7,,,,:print"In dichtem Dschungel."
10920 return
11000 data,11,9,,,,,11,,:print"Offene Lichtung im Dschungel.":return
11020 ifve=23andom=6thenri(1)=71:ri=1
11030 return
11100 data10,,,,,12,,,,:print"In dichtem Dschungel."
11120 ifve=26thenprint"Die Krokodile lassen das nicht zu !"
11122 ifve<>27then11134
11124 ifge(12)<>-1thenprint"Wie denn ?":goto11150
11130 ifpa(4)=0andge(12)=-1thenpa(4)=1:print"Ok.Ich befinde mich auf dem Fluss."
11132 return
11134 ifpa(4)<>1then11138
11135 print"Zahlreiche Krokodile kommen herbeige-   schwommen !"
11136 print"Ein besonders wildes Krokodil klettert  auf das kleine Floss !"
11137 pa(4)=2:return
11138 ifpa(4)=2thenprint"Das Krokodil kommt bedrohlich naeher !":pa(4)=3:return
11140 ifpa(4)=3thenprint"Das Krokodil hat mich gefressen.":goto8000
11150 ifpa(4)=-1thenprint"Die uebrigen Krokodile fressen es."
11152 ifpa(4)=-1thenri(1)=14:ri=1:print"Ich habe das andere Ufer erreicht."
11154 ifpa(4)=-1thenprint"Das Floss treibt auf{$a0}dem Fluss davon.":ge(12)=0
11155 ifpa(4)=-1thenpoke198,0:wait198,1
11160 return
11200 data,,,13,10,6,11,,,:print"In dichtem Dschungel."
11205 print"In der Naehe rauscht Wasser."
11220 ifve<>24orom<>11orge(10)<>-1orge(11)<>0then11230
11225 print"Ok.":o$(11)="Gefaellter Baum":ge(11)=zn
11230 return
11300 data6,,12,,,,,,,:print"In dichtem Dschungel."
11320 return
11400 data,16,,17,,,,,,:print"In dichtem Dschungel."
11420 return
11600 data14,,,17,,,,,,:print"In dichtem Dschungel"
11620 return
11700 data14,,16,,,,,18,,:print"In dichtem Dschungel am Gebirgsrand."
11720 return
11800 data,19,,,17,,,,,:print"Sehr steiler Gebirgspfad."
11820 return
11900 data18,20,,,,,,,,:print"Sehr steiler Gebirgspfad."
11920 return
12000 data19,23,,21,,,,,,:print"Im hohen Gebirge."
12020 return
12100 data0,24,20,,,,23,,,:print"Im hohen Gebirge."
12120 return
12200 data,25,,,,,,,,:print"In einer trockenen Hoehle."
12220 ifve<>28orom<>16then12250
12224 print"Die Schrift lautet :"
12225 print"Ich bin dem Geheimnis der Macht auf der Spur......."
12226 print".. Codewort ....{$a0}NAHOC....
12230 print"Achtung vor den Robo.....
12235 print"....Dr. GORDON....
12240 print"Mehr kann man leider nicht entziffern !"
12250 return
12300 data20,26,,,,21,25,,,:print"Im hohen Gebirge."
12320 return
12400 data21,,,,,,26,,,:print"Im hohen Gebirge."
12420 return
12500 data,,,26,,23,27,,,:print"Im hohen Gebirge."
12520 ifve=13andob=13thenri(1)=22:ri=1
12530 return
12600 data23,28,25,,,24,28,30,,:print"Im hohen Gebirge."
12620 return
12700 data,,,,,25,,,,:print"Im hohen Gebirge auf einem Felsplateau."
12710 print"Ca 10 Meter unter mir ist ein Spalt in  der Gebirgswand."
12715 ifge(5)=-4thenprint"Ein am Ring befestigtes Seil haengt hin-ab."
12720 ifom=18andgm=5andve=31thenge(5)=-4:print"Ok."
12725 ifve=23andge(5)<>-4thenprint"Die Wand ist zu steil !"
12730 ifve=23andge(5)=-4thenprint"Ok.":ri(1)=31:ri=1:ge(5)=31:sc=sc+8
12740 return
12800 data,,,26,,26,,29,,:print"Im hohen Gebirge."
12820 return
12900 data,,,,29,30,,,,:print"Im hohen Gebirge."
12920 return
13000 data,,,,26,,29,,,:print"Im hohen Gebirge."
13020 return
13100 data,,,,,,,,,:print"Auf einem Felsvorsprung an einer steilen";
13110 print"Gebirgswand."
13120 ifve=13andom=19thenri(1)=32:ri=1
13130 return
13200 data33,,31,,,,,,,:print"In einer Grotte."
13220 return
13300 data,33,,34,,,,,,:print"Schmaler Gang in der Grotte."
13320 return
13400 data36,,,35,,,,,,:print"Enger Durchgang."
13401 ifpa(5)thenprint"Durch Steine verschuetteter Ausgang."
13405 ifpa(5)<>0then13420
13406 print"Hinter mir bricht eine Steinlawine aus  und verschuettet den Aus";
13407 print"gang zum Spalt  gaenzlich !":pa(5)=1
13420 return
13500 data,,34,,,,,,,:print"Feuchte Grotte."
13520 return
13600 data,34,,,,,,,,:print"In einer Grotte."
13601 print"In der Wand ist eine Stahltuer eingelas-sen.":ifpa(6)<>0then13620
13602 print"Hinter den Felsen schnellen Stahlgreif- arme hervor und halten mi";
13603 print"ch fest."
13604 print"Ein kleiner Apparat schwebt direkt vor  mein Gesicht.":pa(6)=1
13605 return
13620 ifpa(6)<>1then13640
13621 print"Eine synthetische Stimme aus dem Apparatfragt :";
13622 print"'Wie lautet das Codewort ?'.":gosub50000
13625 ifve=34thenpa(6)=-1
13630 ifpa(6)=1thenprint"Ein Laserstrahl schiesst aus dem Apparat.":goto8000
13632 pa(6)=-1:print"Die synthetische Stimme sagt : 'CodewortAkzeptiert !'."
13633 print"Die Greifarme lassen mich wieder frei,  der Apparat schwebt davon."
13634 print"Die Stahltuer oeffnet sich mit einem    leisen Surren.":oo(22)=36
13635 o$(21)="Offene Stahltuer"
13640 ifve=13andom=22thenri(1)=37:ri=1
13650 return
13700 data,36,,,,,,,,:print"In einem Aufzug.":return
13720 ifve<>35orom<>23orpa(7)=3then13730
13721 print"Die Stahltuer schliesst sich mit einem  leisen Surren.
13722 ifpa(7)=0thenprint"Die rote Taste blinkt kurz hell auf."
13723 ifpa(7)=0thenprint"Seltsam - Die Stahltuer oeffnet sich    wieder !"
13724 ifpa(7)=0orpa(7)=3then13730
13725 print"Der Aufzug bewegt sich leise nach unten.";:sc=sc+9.5
13726 print"Nach ca 2 Minuten bleibt er stehen !"
13727 print"Die Stahltuer oeffnet sich.":pa(7)=3:ri(2)=38
13730 ifve=1andom=24thenprint"Der Schaltkasten ist verriegelt !"
13735 ifve<>37orom<>24then13750
13737 ifgm=0thenprint"Doch nicht etwa mit meinen blossen Haen-den !"
13739 ifgm=3thenprint"Mit dem Saebel schaffe ich das nicht !"
13740 ifgm<>10then13750
13741 print"Mit lautem Krachen faellt die Blechab-  deckung des Schaltkastens";
13742 print" auf den Boden.":ge(13)=37
13743 oo(25)=37:o$(24)="Aufgebrochener Schaltkasten"
13750 ifve=31orve=42thenifom=25thenprint"Ok.":pa(7)=1
13751 ifpa(7)<>1then13760
13752 print"Die rote Taste leuchtet hell auf."
13753 o$(23)="Hell leuchtende rote Taste":pa(7)=2
13754 o$(25)="Im Schaltkasten sind zwei miteinander kurzgeschlossene rote Kabel"
13760 return
13800 data,,42,,,,,,,:print"Schwach beleuchteter Raum."
13820 ifve=1andom=33thenprint"Ich kann die Stahltuer nicht oeffnen."
13825 return
13900 data,,,,,,,,,:print"Raum mit verriegelter Stahltuer.":return
13920 ifpa(8)thenprint"Langsam verschwindet meine Muedigkeit   wieder."
13921 ifpa(8)thenprint"Ich bin gefangen !":pa(8)=0
13925 ifve<>13orom<>27then13940
13930 ifge(14)=0thenprint"Ein Drahtgitter verschliesst den Zugang zum Schacht."
13932 ifge(14)<>0thenri(1)=72:ri=1
13940 ifve<>37orom<>35then13950
13942 ifgm=0thenprint"Womit denn ?":goto13950
13943 ifgm<>10then13950
13944 print"Ok. Das Drahtgitter faellt herrunter undgibt den Ein";:sc=sc+5
13945 print"gang zum Schacht frei."
13946 oo(35)=0:ge(14)=39:ge$(14)="Drahtgitter"
13950 return
14000 data,41,51,,,,,,,:print"Nordende eines Korridors."
14020 return
14100 data40,42,43,39,,,,,,:print"Langer Korridor."
14120 return
14200 data41,,44,38,,,,,,:print"Suedende eines Korridors."
14220 return
14243 print"Ok.":ge(gm)=-4
14250 next
14300 data,,,41,,,,,,:print"Aussruestungsraum."
14320 ifve=13andom=29thenprint"Dazu bin ich zu gross."
14322 ifve>2orom<>29then14340
14325 iftu(4)<>2then14330
14326 ifge(17)<>-1thenprint"Der Schrank ist verriegelt !"
14327 ifge(17)<>-1thenprint"Ich habe auch keinen Schluessel !"
14330 ifve=1andge(17)=-1thenprint"Ok.":tu(4)=0
14335 ifve=2andtu(4)=0thenprint"Ok.":tu(4)=2
14340 ifve<>8orom<>29orgm=0then14350
14341 iftu(5)=0thenprint"Der Schrank ist nicht offen.":goto14350
14343 print"Ok.":ge(gm)=-4
14350 return
14400 data,45,49,42,,,,,,:print"Raum."
14420 return
14500 data44,46,48,,,,,,,:print"Korridor."
14520 return
14600 data45,,,,,,,,,:print"Elektrizitaets-Labor."
14620 return
14700 data,,,,,,,,48,:print"Grosse Halle."
14710 ifytthenyt=1:sc=sc+5
14720 return
14800 data,,,45,,,,,,47:print"Gekachelter Raum."
14820 return
14900 data50,,,44,,,,,,:print"Kleiner Korridor."
14920 return
15000 data,49,,,,,,,,:print"Grosses antik eingerichtetes Wohnzimmer.";
15020 ifve<>47orom<>38thenreturn
15021 ifyathenya=1:sc=sc+5
15022 print"Ok.":print"Das Licht im Raum geht ploetzlich aus   und ein ";
15023 print"heller rechteckiger Fleck er-   scheint an der Zimmerwand."
15024 print"Ein versteckter Projektor beginnt zu    laufen !"
15025 print"An der Wand erscheint das Bild eines    Wesens das halb Mensch ";
15026 print"und halb Roboter ist und ein Tonband beginnt zu laufen........"
15027 poke198,0:wait198,1
15030 print"Hier spricht Professor Cohan !          Mein Experiment, eine bes";
15031 print"sere kuenstli- che Menschheit zu schafen ist fehlge-   schlagen."
15032 print"Meine Roboter haben sich gegen mich ge- wendet."
15033 print"Bei einem Kampf wurde meine mechanische Koerperhaelfte zerstoert !"
15035 print"Ich habe nur noch kurze Zeit zu leben."
15036 print"Ich versuche nun die Verbotene Zone zu  erreichen und die Quelle ";
15037 print"der Macht mit  einer Zeitbombe zu zerstoeren um die be-vorstehende";
15038 print" Roboterinvasion auf die Men-schheit zu verhindern."
15040 print"Moege Gott mir mein Verbrechen vergeben......."
15045 poke198,0:wait198,1
15050 print"Das Bild an der Wand verschwindet und   das Licht geht wieder an."
15099 return
15100 data,,,40,,,,,,:print"Kleiner weiss gekachelter Raum."
15120 ifve<>45andve<>35orom<>36then15130
15122 print"Die Schleusse oeffnet sich.":o$(28)="Offene Schleusse":tu(5)=0
15123 ifybthenyb=1:sc=sc+2.5
15124 print"Eine synthetische Stimme ruft 'ALARM !  Schleusse zur verbotenen";
15126 print"{$a0}Zone ist akti- viert worden !'."
15130 ifve=13andom=28andtu(5)=0thenri(1)=52:ri=1
15140 return
15200 data,51,,,53,,,,,:print"Enger Gang im Inneren des Gebirges."
15205 print"Der Boden strahlt in einem seltsamen    violetten Licht."
15220 ifge(16)<>-1thenpa(9)=1
15230 return
15300 data54,,,,,,56,52,,:print"Hoehlensystem."
15320 return
15400 data,53,,,,,55,,,:print"Hoehlensystem."
15420 return
15500 data59,56,57,,,54,57,,,:print"Hoehlensystem."
15520 return
15600 data55,58,57,,59,53,,,,:print"Hoehlensystem."
15620 return
15700 data55,,,56,,55,,,,:print"Hoehlensystem."
15720 return
15800 data56,,,,57,,,,,:print"Hoehlensystem."
15820 return
15900 data,,,55,,,,56,60,0:print"Hoehlensystem."
15920 return
16000 data,,,,,,,,61,59:print"Hoehlensystem."
16020 return
16100 data,,,,,,,,,60:print"Am Ende des Weges.
16101 print"Vor mir liegt ein tiefer, ca 10 Meter   breiter Abgrund der in ";
16102 print"Dunkelheit ge-   huellt ist."
16103 print"Auf der anderen Seite des Abgrunds setztsich der Weg fort."
16104 print"An der Felswand auf der anderen Seite   ist ein rot leuchtender";
16105 print" Druckknopf ange-bracht."
16120 ifve=35andom=39thenprint"Meine Arme sind nicht 10 Meter lang !"
16130 ifbr<>1then16135
16131 print"Ein lautes Rattern ertoent !":sc=sc+10
16132 print"Eine Bruecke aus Stahl wird ueber den   Abgrund hinweg herrueber";
16133 print" geschoben.":br=2:oo(40)=61:oo(41)=63
16135 ifve=13andom=40thenri(1)=62:ri=1
16140 ifve<>8orgm<>6orom<>39then16150
16141 ifbr<>-1thenprint"Die Pistole faellt hinab.":ge(6)=0:goto16150
16142 print"Ok.":print"Die Pistole trifft den Druckknopf mit   voler Wucht !"
16143 ge(6)=63:br=1:goto16130
16150 return
16200 data63,61,,,,,,,,:print"Auf einer Stahlbruecke die ueber einen ";
16210 print" tiefen, dunklen Abgrund fuehrt."
16220 return
16300 data,,,64,0,0,0,0,0,0:print"Hoehlenweg am Rande eines Abgrunds."
16320 ifve=13andom=41thenri(1)=62:ri=1
16325 ifve=35andom=42thenprint"Ok.":print"Es passiert nichts."
16330 return
16400 data,,63,,,,,65,,:print"Hoehlensystem."
16420 return
16500 data,,,,64,,,,66,:print"Feuchte Grotte."
16501 print"Eine breite unregelmaessige Steintreppe fuehrt nach oben."
16520 return
16600 data,,,67,,,,,,65:print"Riessiger prunkvoller Tempelraum."
16620 return
16700 data,69,66,68,,,,,,:print"Grosser runder Raum."
16720 ifve<>8orom<>43then16740
16725 ifg1<>18andge(g1)=-1thenprint"Ok.":ge(g1)=0
16727 ifg1<>18then16740
16730 print"Eine synthetische Stimme aus der Zeit-  bombe spricht :":ge(18)=-9
16732 print"'Mission beendet. Detonation erfolgt in ";zb;"Zeiteinheiten !'"
16733 sc=sc+10
16740 return
16800 data,,67,,,,,,,:print"Altarraum."
16820 return
16900 data67,,,,,,,,,:print"Ausserhalb des Tempels."
16920 ifve=23andom=44thenprint"Die Mauer ist viel zu hoch und zu steil."
16925 ifve=13orve=26orve=48thenri(1)=75:ri=1:sc=sc+5
16930 return
17100 data,,,,,,,,,10:print"Hoch oben auf einem Affenbrotbaum."
17110 ifpa(3)<>-1thenpa(3)=5
17120 return
17200 data39,45,,,,,,,,:print"In einem Belueftungsschacht."
17220 return
17500 data,,,,,,,,,:print"Ich schwimme unter der Mauer durch und  treibe nun";
17501 print" auf dem Fluss......"
17520 poke198,0:wait198,1
17525 :print"{clr}Und so endete das Abenteuer des         Mr Bolings :"
17530 print"Mit letzter Kraft erreichte er den      Inselstrand, wo er ";
17532 print"von einem vorbeifah- renden Handelsschiff entdeckt und in ";
17533 print"   seine Heimat zurueckgebracht wurde."
17540 ifge(18)<>-9then17550
17545 print"Als die Zeitbombe explodierte versank   die gesamte Insel spurlos";
17546 print" im Meer......"
17550 ifge(18)=-9then17560
17552 print"Was mit den Robotern geschah blieb      BISHER unbekannt......
17560 print"{wht}Sie haben";sc;"% dieses Adventures geloest."
17564 print"{down}{down}{lred}Mit freundlichen Gruessen,
17565 print"{down}{down}              Michael Nickles
17566 poke198,0:wait198,1:run
50000 rem ****************************
50050 ifud=1then50220
50055 tt=0
50060 fori=1to10:be$(i)="":next:poke198,0:be$=""
50061 print"{grn}Was soll ich nun machen ?":print"{gry2}{down}{CBM-@}";
50080 getx$:tt=tt+1:iftt>1500thenprint"{up}{grn}":goto50140
50085 ifx$=""then50080
50086 tt=0
50090 ifpeek(203)=1orlen(be$)>75thenifbe$<>""thenprint"{left}.{grn}":goto50140
50100 i=asc(x$):ifi<65ori>90thenifi<>32andi<>20andi<>34then50080
50110 ifi=20andlen(be$)=0then50080
50120 ifi=20thenprint"{left}{left}  {left}{left}{CBM-@}";:be$=left$(be$,len(be$)-1):goto50080
50130 be$=be$+chr$(i):i=i+128:print"{left}";chr$(i);"{CBM-@}";:goto50080
50140 be$=be$+" ":fori=1to10:be$(i)="":next:wz=1:fori=1tolen(be$)
50150 :ifmid$(be$,i,1)=" "thengosub50190:goto50180
50160 :ifwz>19thenprint"Eingabe ist zu lang !":i=len(be$)+1:goto50180
50170 :be$(wz)=be$(wz)+mid$(be$,i,1)
50180 nexti:goto50220
50190 ic=0:fori1=1toaz:ifbe$(wz)=au$(i1)thenic=1
50200 nexti1:ific=0thenwz=wz+1:return
50210 be$(wz)="":return
50220 ifud=1thenud=0:goto50240
50230 wz=1:ve=0:ob=0:om=0:pe=0
50240 ic=0:g1=0:g2=0:gm=0
50241 b$=be$(wz):ifb$=""thenreturn
50242 ifb$="supermike"thenprint"0937210682":ic=1:goto50370
50245 fori=1to10:ifb$=ri$(i)thenri=i
50246 nexti:ifri<>0thenreturn
50260 fori=1tovz:ifb$=left$(ve$(i),len(b$))thenve=i-val(right$(ve$(i),1)):ic=1
50261 nexti:ificthen50370
50270 fori=1togz
50275 ifmid$(b$,2,len(b$)-1)<>mid$(ge$(i),2,len(ge$(i))-1)then50300
50280 ic=1:ifg1=0theng1=i:ifge(g1)=-1thengm=i
50290 g2=i:ifg2=g1theng2=0
50300 nexti:ificthen50370
50310 fori=1tooz:ifb$=ob$(i)thenob=i:ic=1:ifoo(i)=znthenom=i
50320 nexti:ificthen50370
50329 rem     iflen(b$)<3then50350
50330 fori=1topz
50331 ifmid$(b$,2,len(b$)-1)=mid$(pe$(i),2,len(pe$(i))-1)thenpe=i:ic=1
50332 ifpe=iandpe(i)=znthenpm=pe:ic=2
50340 nexti:ificthen50370
50350 ifb$="und"thenud=1:ic=1
50360 ific=0andri=0thenprint"Ich kenne ";b$;" nicht !":goto50000
50370 wz=wz+1:ifwz>10orbe$(wz)=""orud=1thenreturn
50380 ic=0:goto50241
51000 rem allgemeine tabellen ----------
51005 restore51000
51010 datan,s,w,o,nw,no,sw,so,rauf,runter:fori=1to10:readri$(i):next
51100 tu(1)=1:rem schrank
51105 tu(2)=1:rem haustuer
51110 tu(3)=1:rem truhe
51115 tu(4)=2:rem schrank
51116 tu(5)=1:rem schleusse
51120 mu=4
51130 dim be$(20)
51200 :
51210 data51,51,51,40,41,42,44,45,48,48,48,45,44,42,41,40,-1
51220 dimma(17):fori=1to17:readma(i):next:ma=1:rem robot aktiv
52000 rem w o r t s c h a t z ----------
52005 restore52000
52010 dataoeffne,schliesse,schaue,untersuche1,nimm,nehme1,hole2,verliere,lege1
52011 datawirf2,werfe3,inventur,gehe
52012 databetrete1,verlasse,gib,gebe1,zeige2,warte,toete,erlege1,schiesse2
52013 dataklettere,faelle,baue,schwimme,ueberquere,lies,lese1,hilfe
52014 databefestige,binde1,verknote2,nahoc,druecke,betaetige1
52015 databreche,brich1,zerschlage2,zerstoere3,vernichte4
52016 dataverbinde,kurz1,stecke,ziehe,schiebe1,setze,springe,esse
52040 vz=49:dimve$(vz):fori=1tovz:readve$(i):next
52100 datader,die,das,den,in,auf,nach,vom,zum,dem,aufs,sie,mit,ueber,hoch,weg
52105 dataein,am,an,dich
52120 az=20:dimau$(az):fori=1toaz:readau$(i):next
52200 rem die objekte --------------
52210 data schrank,"Alter Schrank aus Eichenholz",1
52212 data haustuer,"Haustuer",1
52214 data schiff,"Schiff",3
52216 data truhe,"Grosse Seemannstruhe",0
52217 data tuer,"Haustuer",2
52218 databaum,"Hoher Affenbrotbaum",10
52219 datamauer,"Sehr hohe, breite Mauer aus Felsbrocken",8
52220 datafluss,"Breiter reissender Fluss",11
52221 datakrokodil,"Viele Krokodile lauern im Fluss",11
52222 datakamin,"Kamin",1
52223 databaum,"Duenne Holzbaume",12
52224 datafluss,"Breiter reissender Fluss",14
52225 datahoehle,"Eingang zu einer Hoehle",25
52226 datahoehlenwand,"Hoehlenwand",22
52227 datastein,"Spitzer Kreidestein",0
52228 dataschrift,"Schwer lesbare Schrift",0
52229 dataskelett,"In einer Ecke liegt ein menschliches Skelett",22
52230 dataeisenring,"Am Boden ist ein Eisenring befestigt",27
52231 dataspalt,"Ca 1 Meter breiter Spalt in der Gebirgswand",31
52232 datatropfsteine,"Von der Decke haengen Gebilde aus Tropfsteinen",35
52233 datastahltuer,"Stahltuer",36
52234 dataaufzug,"Die Stahltuer gibt den Zugang zu einem Aufzug frei",0
52235 datataste,"Rote Taste",37
52236 dataschaltkasten,"An der Wand haengt ein Schaltkasten",37
52237 datakabel,"Im Schaltkasten sind zwei rote Kabel mit blanken Enden",0
52238 datasteckdose,"In der Wand ist eine Steckdose",41
52239 dataschacht,"In der Wand ist ein Belueftungsschacht",39
52240 dataschleusse,"Schleusse aus Stahl",51
52241 dataschrank,"Schrank aus Stahl",43
52242 dataschacht,"In der Wand ist ein Belueftungschacht",45
52244 datatreppe,"Wendeltreppe die nach unten fuehrt",48
52245 datatreppe,"Wendeltreppe die nach oben fuehrt",47
52246 datastahltuer,"Verschlossene Stahltuer",38
52247 datakampfroboter,"Riessiges regungsloses Kampfroboterheer",47
52248 datadrahtgitter,"Vor dem Schacht ist ein Drahtgitter",39
52249 dataschalthebel,"Neben der Schleusse ist ein roter Schalthebel",51
52250 datatoten,"Am Boden liegt ein Toter - halb Mensch halb Roboter",51
52252 datasessel,"In der Mitte des Raums steht ein antiker Sessel",50
52253 datadruckknopf,"Leuchtender Druckknopf",61
52254 databruecke,"Bruecke aus Stahl",0
52255 databruecke,"Bruecke aus Stahl",0
52256 datadruckknopf,"Leuchtender Druckknopf in der Felswand",63
52257 databrunnen,"In der Mitte des Raums ist eine Art von Brunnen",67
52258 datamauer,"Sehr hohe, breite Mauer aus Felsbrocken",69
52259 datafluss,"Breiter Fluss, der unter der Mauer durchfliesst",69
52260 oz=45:dimob$(oz):dimo$(oz):dimoo(oz)
52262 fori=1tooz:readob$(i):reado$(i):readoo(i):next
52300 data "Seekarte",0,"Muscheln",5
52302 data"Saebel",-3,"Schiffszwieback",-3,"Seil",-3,"Pistole",-3
52303 data"Munition",-3,"Flasche",-2,"Buch",0,"Axt",-3,"Holz",0
52305 data"Floss",0,"Blechdeckel",0,"Draht",0,"Stromkabel",46
52306 data"Schutzanzug",-4,"Schluessel",0,"Zeitbombe",0
52330 gz=18:dimge$(gz):dimge(gz):fori=1togz:readge$(i):readge(i):next
52400 data"Navigator",4,"Kaepten Graubard",4,"Loewe",0,"Verbrannter Roboter",0
52410 pz=4:dimpe$(pz):dimpe(pz):fori=1topz:readpe$(i):readpe(i):next
53000 return
60000 rem mp
60004 fori=49152to49206:reada:pokei,a:next:sys49152:sys49191:sp=49152
60010 data160,0,177,122,201,44,240,1,96,32,115,0,32,49,192,165,20,32,23,192
60020 data76,0,192,41,63,141,1,221,9,64,141,1,221,173,1,221,48,251,96,169,127
60025 data141,3,221,169,0,76,23,192,32,138,173,76,247,183
60045 return:remsys49152,6,3,26,0,16,4,4,39,7,21,2,19,4
61000 rem speakeasy-saetze
61010 remsyssp,19,37,4,57,23,3,63,7,4,23,44,41,55,13:return
61020 remsyssp,33,7,44,41,4,33,30,8,4,16,26,62,4,11,59,8,3,3,4:return
61030 remsyssp,27,26,62,45,53,4,4,4,19,37,4,27,6,55,55,7,4,4,16,19,55,17,52,4
61031 remsyssp,63,31,45,19,11,4:return

  0 REM ********************************* 
  2 REM *    C O H A N ' S   L A N D    * 
  4 REM *      COPYRIGHT 1984 BY        * 
  5 REM * SUPERMIKE'S FANTASY PRODUCTS  * 
  7 REM ********************************* 
  8 POKE 53280,0:POKE 53281,0:PRINTCHR$ (14):SYS 65499:PRINT"{CLR,YELLOW} 
  9 ZN=1:RO=10000+ZN*100 
 11 DATA 76,24,1,177,251,145,251,200,208,249,230,252,202,208,244,96,120,160 
 12 DATA 0,169,160,132,251,133,252,162,32,32,11,1,169,224,132,251,133,252 
 13 DATA 162,32,32,11,1,169,53,133,1,88,96:FOR I=264 TO310:READ A:POKE I,A:NEXT 
 15 SYS 264:A=710:FOR I=A TOA+20:READ X:POKE I,X:NEXT 
 16 DATA 208,3,76,29,168,32,192,2,32,19,166,56,165,95,233,1,164,96,76,36,168 
 18 POKE 40996,197:POKE 40997,2:POKE 1,54:A=43168:FOR I=A TOA+2:READ X:POKE I,X:NEXT 
 20 A=704:FOR I=A TOA+5:READ X:POKE I,X:NEXT :DATA 32,192,2,32,138,173,76,247,183 
 25 GOSUB 51000 
 30 PRINT"{CLR,6DOWN}";CHR$ (142) 
 36 PRINT,"{YELLOW}NT NPNP@ NPNM GN NT 
 37 PRINT,"LPMP@N N OPN MG{2SPACE}YP 
 38 PRINT,"{17SPACE}TT 
 39 PRINT,"{4SPACE}H{2SPACE}NPNM HOM 
 40 PRINT,"{4SPACE}LP OPN MHLN 
 42 PRINT,"{3DOWN,LIG.RED,LEFT}EIN ABENTEUERSPIEL VON 
 43 PRINT,"{DOWN,LIG.RED,2SPACE}MICHAEL NICKLES":POKE 198,0:WAIT 198,1 
 50 PRINT"{CLR}";CHR$ (14) 
 55 REM GE$(14)="DRAHTGITTER":GE(15)=-1:MA=0:GE(10)=-1:GE(16)=-1:GE(6)=-1 
 56 REM   GE(1)=-1:ZB=10 
 57 REM FORI=1TOGZ:GE(I)=-1:NEXT 
 60 GOTO 1040 
 1000 REM ACTIONMODUL ------------------- 
 1001 IF RI THEN1015 
 1002 GOSUB 50000 
 1010 IF RI=0 THEN2000 
 1015 IF RI(RI)=0 THENPRINT"KEIN WEG IN DIESE RICHTUNG !":RI=0:GOTO 2000 
 1016 VE=0:OM=0:OB=0:PE=0:PM=0:REM GE=0 
 1020 RO=10000+100*RI(RI):ZN=RI(RI):RI=0 
 1040 RESTORE RO:FOR I=1 TO10:READ RI(I):NEXT 
 1041 IF PA(7)AND ZN=37 THENRI(2)=38 
 1050 PRINT"{CLR,YELLOW}";:GOSUB ROOM 
 1100 REM ***** SIE SEHEN 
 1700 SE$="":IC=0:FOR I=1 TOPZ:IF PE(I)=ZN THENPRINTPE$(I)". ";:IC=1 
 1710 NEXT :IF IC THENPRINT 
 1820 FOR I=1 TOOZ:IF OO(I)=ZN THENSE$=SE$+O$(I)+". ":IC=1 
 1822 NEXT 
 1830 FOR I=1 TOGZ:IF GE(I)=ZN THENSE$=SE$+GE$(I)+". ":IC=1 
 1831 IF GE(I)=-2AND ZN=1AND TU(1)=0 THENSE$=SE$+GE$(I)+". ":IC=1 
 1832 IF GE(I)=-3AND ZN=5AND TU(3)=0 THENSE$=SE$+GE$(I)+". ":IC=1 
 1833 IF GE(I)=-4AND ZN=43AND TU(4)=0 THENSE$=SE$+GE$(I)+". ":IC=1 
 1834 NEXT I 
 1835 IF SE$="" THEN1900 
 1840 IF LEN (SE$)<41 THENPRINTSE$:GOTO 1900 
 1850 I$=LEFT$ (SE$,39) 
 1860 IM=0:FOR I=1 TOLEN (I$) 
 1865 :IF MID$ (I$,I,1)=" " THENIM=I 
 1868 NEXT I 
 1870 I$=LEFT$ (I$,IM):PRINTI$ 
 1880 SE$=RIGHT$ (SE$,LEN (SE$)-IM) 
 1890 GOTO 1840 
 1900 PRINT"MOEGLICHE RICHTUNGEN : "; 
 1910 IC=0:FOR I=1 TO10:IF RI(I) THENPRINTRI$(I)",";:IC=1 
 1920 NEXT :IF IC=0 THENPRINT"KEINE "; 
 1930 PRINT"{LEFT,SPACE,DOWN}" 
 2000 REM REAGIEREN AUF BEFEHLE --------- 
 2005 REM FEHLERMELDUNGEN ************** 
 2010 IF OBAND OM=0 THENPRINT"DAS GEHT HIER NICHT .... NOCH NICHT !" 
 2015 IF PEAND PM=0 THENPRINT"ICH SEHE DIESE PERSON HIER NICHT !" 
 2019 IF VE=16 THEN2100 
 2020 IF VE<>5AND VE<>8AND G1AND GM=0AND G1<>12 THENPRINT"ICH HABE DAS NICHT !" 
 2100 REM EINWORT-BEFEHLE ************** 
 2105 IF VE=3AND OB=0AND GM=0 THENVE=0:GOTO 1050:REM LOOK 
 2110 IF VE<>12 THEN2130:REM INVENTUR 
 2111 SE$="ICH HABE: ":IC=0:FOR I=1 TOGZ:IF GE(I)=-1 THENSE$=SE$+GE$(I)+", ":IC=1 
 2112 NEXT I:IF IC=0 THENSE$=SE$+" NICHTS. " 
 2113 SE$=LEFT$ (SE$,LEN (SE$)-1) 
 2116 IF LEN (SE$)<41 THENPRINTSE$:GOTO 2130 
 2117 I$=LEFT$ (SE$,39) 
 2118 IM=0:FOR I=1 TOLEN (I$) 
 2119 :IF MID$ (I$,I,1)=" " THENIM=I 
 2120 NEXT I 
 2121 I$=LEFT$ (I$,IM):PRINTI$ 
 2122 SE$=RIGHT$ (SE$,LEN (SE$)-IM) 
 2123 GOTO 2116 
 2130 IF VE=19 THENPRINT"ZEIT VERGEHT......." 
 2200 REM NIMM/VERLIER ROUT. *********** 
 2205 IF VE<>5AND VE<>8OR G1=0OR OB THEN2237 
 2220 IF VE=5AND GE(G1)=-1 THENPRINT"ICH HABE DAS BEREITS !":GOTO 2300 
 2222 IF VE=8AND GE(G1)<>-1 THENPRINT"ICH HABE DAS NICHT !" 
 2229 IF ZN=27AND VE=5AND GE(5)=-4 THENGE(5)=-1:PRINT"OK.":GOTO 2300 
 2230 IF VE=5AND GE(G1)=ZN THENPRINT"OK.":GE(G1)=-1:GOTO 2250 
 2231 IF VE=8AND GE(G1)=-1 THENPRINT"OK.":GE(G1)=ZN 
 2232 IF VE=5AND GE(G1)=-2AND TU(1)=0 THENPRINT"OK.":GE(G1)=-1:GOTO 2250 
 2233 IF VE=5AND GE(G1)=-3AND TU(3)=0 THENPRINT"OK.":GE(G1)=-1:GOTO 2250 
 2234 IF VE=5AND GE(G1)=-4AND TU(4)=0 THENPRINT"OK.":GE(G1)=-1:GOTO 2250 
 2237 IF G1AND VE=5AND GE(G1)<>ZN THENPRINT"ICH SEHE DAS HIER NICHT !" 
 2238 IF VE=5AND G1=0AND OB<>0 THENPRINT"DAZU BIN ICH NICHT STARK GENUG !" 
 2250 IF G1=15AND FS=1 THENFS=0 
 2252 IF G1=14AND FA+FS=2 THEN2625 
 2254 IF VE=5AND G1=16 THENPRINT"ICH ZIEHE DEN SCHUTZANZUG AM BESTEN SO- FORT AN !" 
 2300 REM TOETE ************************ 
 2310 IF VE<>20 THEN2400 
 2315 IF G1=0 THENPRINT"WIE ? DOCH NICHT MIT MEINEN BLOSSEN{5SPACE}HAENDEN !":GOTO 2400 
 2320 IF GM=3 THENPRINT"ICH GREIFE MIT DEM SAEBEL AN !" 
 2322 IF GM=10 THENPRINT"ICH GREIFE MIT DER AXT AN !" 
 2324 IF GM=6AND MU=0 THENPRINT"ICH HABE KEINE MUNITION MEHR !":GE(7)=0:GOTO 2400 
 2326 IF GM=6AND MU THENPRINT"ICH SCHIESSE MIT DER PISTOLE !":MU=MU-1 
 2330 IF PA(3)<6 THEN2340 
 2332 IF ZN<>71OR GM<>6 THEN2340 
 2334 PRINT"DER LOEWE BRICHT TOT ZUSAMMEN.":PE$(3)="TOTER LOEWE":PA(3)=-1 
 2335 PE(3)=10:SC=SC+7.5 
 2340 IF GM<>6AND GM<>3AND GM<>10OR PA(4)<1 THEN2350 
 2342 PRINT"DAS KROKODIL STUERZT BLUTEND INS WASSER.":PA(4)=-1:SC=SC+3.5 
 2350 IF ZN<>61OR OM<>39OR GM<>6 THEN2360 
 2352 I=INT (100*RND (1))+1 
 2354 IF I>50OR BR=2 THENPRINT"DIE KUGEL VERFEHLT DEN DRUCKKNOPF KNAPP.":BR=-1 
 2356 IF I<=50AND BR<>2 THENPRINT"DIE KUGEL TRIFFT DEN DRUCKKNOPF EXAKT !":BR=1 
 2360 : 
 2400 REM BAUE FLOSS ****************** 
 2410 IF VE<>25OR G1<>12 THEN2500 
 2420 IF GE(11)<>-1 THENPRINT"ICH HABE KEIN HOLZ !":GOTO 2500 
 2430 PRINT"OK.":GE(11)=0:GE(12)=-1 
 2500 IF VE<>31AND VE<>42 THEN2600: REM VERBINDE ****************** 
 2505 IF G1+G2<>29 THEN2600 
 2510 IF GE(14)<>-1 THENPRINT"ICH HABE DAS DRAHTGITTER NICHT !":GOTO 2600 
 2520 IF GE(15)<>-1 THEN2600 
 2530 IF FA=1 THENPRINT"DAS HABE ICH BEREITS.":GOTO 2600 
 2535 PRINT"OK.":FA=1:REM IFFS=1THEN2625 
 2600 IF VE<>44AND VE<>42 THEN2700:REM STECKE ************** 
 2610 IF OM<>26 THEN2700 
 2620 IF FS=0 THENPRINT"OK.":GE(15)=ZN:FS=1 
 2622 IF FA<>1OR GE(14)<>-1 THEN2630 
 2625 PRINT"DAS DRAHTGITTER GLUEHT AUF UND VERABREI-CHT MIR EINEN ELEKTROSCHOCK"; 
 2626 PRINT" VON MEHRERENTAUSEND VOLT.":GOTO 8000 
 2630 IF FS=0AND GE(15)=-1 THENPRINT"OK.":GE(15)=ZN:FS=1 
 2700 REM SPEZIAL ACTION SCENARIO 
 2710 IF ZN=43OR ZN=51 THENIF MA<>0 THEN6145 
 2715 IF GE(18)=-1AND ZB=11 THENPRINT"DIE ZEITBOMBE BEGINNT PLOETZLICH ZU{5SPACE}TICKEN !" 
 2716 IF ZB<11AND GE(18)=-1 THENPRINT"DIE ZEITBOMBE TICKT IMMER SCHNELLER !" 
 2720 IF ZB THENZB=ZB-1:IF ZB=0 THENPRINT"DIE ZEITBOMBE EXPLODIERT.":GOTO 8000 
 2730 I=PA(9): REM STRAHLENVERSEUCHUNG 
 2735 IF I=1 THENPRINT"MIR WIRD GANZ KOMISCH VON DEM VIOLETTEN LICHT !" 
 2740 IF I THENPA(9)=PA(9)+1:I=PA(9) 
 2745 IF I=5 THENPRINT"ICH WERDE PLOETZLICH GANZ SCHWACH !" 
 2746 IF I=8 THENPRINT"ICH WERDE IMMER SCHWAECHER !" 
 2747 IF I=10 THENPRINT"MEINE KRAEFTE VERLASSEN MICH .....":GOTO 8000 
 2800 IF VE=28AND GM=1 THENPRINT"ICH BIN KEIN SCHIFFSNAVIGATOR !" 
 2810 IF VE<>37OR GM<>8OR GE$(8)="GLASSCHERBEN" THEN2820 
 2815 PRINT"DIE FLASCHE ZERSPRINGT IN GLASSCHERBEN. EINE SEEKARTE FAELLT AUF "; 
 2816 PRINT"DEN BODEN.":GE$(8)="GLASSCHERBEN":GE(8)=ZN:GE(1)=ZN:SC=SC+2.5 
 2820 IF VE<>49 THEN2830 
 2822 IF GE(2)<>-1AND GE(4)<>-1 THENPRINT"ICH HABE KEINEN HUNGER.":GOTO 2830 
 2824 PRINT"OK.":GE(2)=0:GE(4)=0:SC=SC+2.5 
 2830 : 
 4000 REM HILFE *********************** 
 4010 IF VE<>30 THEN5000 
 4999 REM  GOSUB61020 
 5000 REM U N T E R S U C H E ----------- 
 5001 IF VE<>3OR OM=0AND GM=0 THEN5999 
 5010 IC=0:IF OM=7 THENPRINT"DIE MAUER IST UNUEBERWINDBAR HOCH.":IC=1 
 5015 IF OM=14AND OO(16)<>22 THENSC=SC+6.5 
 5020 IF OM=14 THENPRINT"EINE SCHRIFT IST IN DIE WAND GERITZT.":OO(16)=22:IC=1 
 5030 IF OM<>17 THEN5035 
 5031 PRINT"DIE RECHTE HAND DES SKELETTS UMKLAMMERT EINEN SPITZEN KREIDESTEIN." 
 5032 IC=1:OO(15)=22 
 5035 IF OM<>20 THEN5037 
 5036 PRINT"IN EINEM TROPFSTEIN IST EINGERITZT :{4SPACE}POWERPETER{SHIFT-SPACE}WAR HIER !":IC=1 
 5037 IF OM=24OR OM=1 THENVE=0:GOTO 1050 
 5040 IF GM=7 THENPRINT"ICH HABE NOCH";MU;"SCHUSS !":IC=1 
 5050 IF GM<>15 THEN5055 
 5051 PRINT"DAS KABEL IST CA 50M LANG. AM EINEN ENDEHAT ES EINEN STECKER, AM "; 
 5052 PRINT"ANDEREN ENDE{3SPACE}IST ES BLANK." 
 5053 IC=1 
 5055 IF OM<>37OR GE(17)<>0 THEN5060 
 5056 PRINT"DER TOTE HAT EINEN SCHLUESSEL UND EINE{2SPACE}AKTIVIERTE ZEITBOMBE "; 
 5057 PRINT"BEI SICH !":GE(17)=ZN:GE(18)=ZN:IC=1:ZB=50 
 5060 IF GM<>18 THEN5065 
 5062 PRINT"AUF DER ZEITBOMBE IST EIN ZAEHLER ANGE- BRACHT DER MOMENTAN DEN "; 
 5063 PRINT"WERT";ZB;"HAT !":IC=1 
 5065 IF OM<>43 THEN5070 
 5066 PRINT"AM BODEN DES BRUNNENS STRAHLT EIN HELLESLICHT-DIE QUELLE{SHIFT-SPACE}DER{SHIFT-SPACE}MACHT !" 
 5067 IC=1 
 5070 IF GM=8 THENPRINT"IN DER FLASCHE IST EINE SCHRIFTROLLE.":IC=1 
 5075 IF GM=16 THENPRINT"DER ANZUG SCHUEZT VOR RADIOAKTIVER{6SPACE}STRAHLUNG.":IC=1 
 5500 IF IC=0 THENPRINT"ICH ENTDECKE NICHTS BESONDERES." 
 5999 : 
 6000 REM NICHTSPIELERPERSONEN ---------- 
 6010 REM ********** LOEWE 
 6015 IF ZN=71AND PA(3)<>-1 THEN6035 
 6020 IF ZN<6OR ZN>13OR PA(3)=-1OR INT (10*RND (1))+1<6OR PA(4) THEN6100 
 6035 PA(3)=PA(3)+1:IF PA(3)<6 THENPRINT"IM GEBUESCH RASCHELT ETWAS !":REM  61010 
 6050 IF PA(3)=6 THENPRINT"EIN RIESSIGER LOEWE SPRINGT AUS DEM GE- BUESCH HERVOR !" 
 6051 IF PA(3)=6 THENPE(3)=ZN 
 6055 IF PA(3)=7AND ZN=71 THENPRINT"DER LOEWE SPRINGT AM BAUMSTAMM HOCH !" 
 6060 IF PA(3)=8 THENPRINT"DER LOEWE FAELLT MICH AN !":GOTO 8000 
 6100 REM ********** ROBOTER 
 6105 IF ZN<38OR MA=0 THEN6200 
 6110 MW=MW+1:MA=MA(MW):IF MA=-1 THENMW=0:GOTO 6110 
 6130 IC=0:FOR I=1 TO10:IF RI(I)=MA THENIC=1 
 6135 NEXT :IF IC THENPRINT"ICH HOERE SCHRITTE IN DER NAEHE !" 
 6136 IF MA<>GE(14)OR FA+FS<>2 THEN6140 
 6137 MA=0:PE(4)=GE(14):SC=SC+7 
 6138 IF PE(4)<>ZN THENPRINT"ICH HOERE EIN LAUTES KRACHEN !":GOTO 6140 
 6139 PRINT"DER ROBOTER LAUEFT UEBER DAS DRAHTGITTERUND VERSCHMORT !" 
 6140 IF MA<>ZN THEN6150 
 6145 PRINT"EIN RIESSIGER ROBOTER ERSCHEINT !" 
 6146 PRINT"AUS DEN AUGEN DES ROBOTERS SCHIESST EIN LICHTSTRAHL AUF MICH ....." 
 6147 PRINT"ICH WERDE MUEDE ..... SEHR MUEDE ....." 
 6148 RI(1)=39:RI=1:PA(8)=1:POKE 198,0:WAIT 198,1 
 6150 : 
 6200 GOSUB ROOM+20:GOTO 1000 
 7000 REM VERLOREN 
 8000 PRINT"ICH BIN TOT." 
 8010 PRINT"{WHITE}SIE HABEN";SC;"% DIESES ADVENTURES GELOEST." 
 8020 FOR I=1 TO3000:NEXT :POKE 198,0:WAIT 198,1:RUN 
 10000 REM DIE LANDKARTE ---------------- 
 10100 DATA ,,,,,,,,,,,:PRINT"GEMUETLICH EINGERICHTETE WOHNSTUBE." 
 10102 PRINT"IN EINEM OFFENEN KAMIN KNISTERT EIN BE- HAGLICHES FEUER." 
 10109 IF TU(2)=0 THENRI(1)=2 
 10120 IF VE=1AND OM=1 THENPRINT"OK.":TU(1)=0 
 10125 IF VE=2AND OM=1 THENPRINT"OK.":TU(1)=1 
 10127 IF VE=1AND OM=2OR OM=5 THENPRINT"OK.":TU(2)=0:RI(1)=2 
 10128 IF VE=2AND OM=2OR OM=5 THENPRINT"OK.":TU(2)=1:RI(1)=0 
 10129 IF VE<>8OR OM<>1 THEN10140 
 10130 IF TU(1) THENPRINT"DER SCHRANK IST GESCHLOSSEN !":GOTO 10140 
 10131 IF GE(G1)=-1 THENPRINT"OK.":GE(G1)=-2:REM GOTO 
 10140 IF VE=8AND OM=10AND GM=1 THENPRINT"DIE SEEKARTE VERBRENNT.":GE(1)=0 
 10150 RETURN 
 10200 DATA 3,,,,,,,,,,,:PRINT"BREITE STRASSE DIE ZUM HAFEN FUEHRT." 
 10203 PRINT"MR BOLINGS HAUS. 
 10205 IF TU(2)=0 THENRI(2)=1 
 10220 IF VE=1AND OM=5 THENPRINT"OK.":TU(2)=0:RI(2)=1 
 10221 IF VE=2AND OM=5 THENPRINT"OK.":TU(2)=1:RI(2)=0 
 10230 RETURN 
 10300 DATA ,2,,,,,,,,:PRINT"AM GROSSEN HAFEN. EIN GROSSES HANDELS-{2SPACE}SCHIFF, "; 
 10305 PRINT"DIE 'QUEEN MARY' WIRD GERADE{4SPACE}BELADEN." 
 10320 IF VE=13AND OB=3 THENRI(1)=4:RI=1:TI$="000000" 
 10330 RETURN 
 10400 DATA ,,,,,,,,,,:PRINT"AUF DER QUEEN MARY." 
 10410 IF PA(0) THEN10419 
 10411 PRINT"KAEPTAN GRAUBART SAGT : 'HALLO, WILLKOM-MEN AN BORD MR BOLINGS ! "; 
 10412 PRINT"NAVIGATOR AN{3SPACE}DECK, HIEVT DIE SEGEL, HOLT DEN ANKER{3SPACE}EIN!'{DOWN}" 
 10413 PA(0)=1 
 10419 RETURN 
 10420 IF VE=13AND OB=3 THENRI(1)=3:RI=1 
 10424 PA(0)=PA(0)+1:IF PA(0)>3 THENPA(0)=3 
 10425 IF PA(0)=3 THENPRINT"{YELLOW}DAS SCHIFF BEFINDET SICH AUF HOHER SEE." 
 10426 IF TI$>"000300" THEN10440 
 10427 IF GE(1)<>-1 THEN10430 
 10428 IF VE+PE+G1=18 THENPRINT"{DOWN}DER NAVIGATOR NIMMT DIE KARTE.":PA(1)=1:GE(1)=0 
 10429 IF VE+PE+G1=18 THENSC=SC+2.5 
 10430 IF PA(1) THENPA(1)=PA(1)+1 
 10431 IF PA(1)=4 THENPRINT"EIN SCHIFFSJUNGE RUFT 'LAND IN SICHT !'.":TI$="000300" 
 10432 IF TI$>"000030"AND PA(2)=0 THENPRINT"EIN SCHWERER STURM BRICHT AUS !":PA(2)=1 
 10433 RETURN 
 10440 PRINT"EIN STARKER RUCK ZUCKT PLOETZLICH DURCH DAS SCHIFF !" 
 10441 FOR I=1 TO4000:NEXT 
 10445 PRINT"EIN MATROSE RUFT 'WIR SIND AUF EIN RIFF AUFGEFAHREN UND HABEN EIN "; 
 10446 PRINT"LECK......WIR SINKEN....." 
 10450 POKE 198,0:WAIT 198,1 
 10460 IF PA(1)=0 THENPRINT"ICH ERTRINKE....":GOTO 8000 
 10470 RI(1)=5:RI=1:RETURN 
 10500 DATA ,,,,,,6,,,:PRINT"AM INSELSTRAND." 
 10502 PRINT"IM WASSER IN STRANDNAEHE TREIBEN EINIGE SCHIFFSWRACKTEILE.":RETURN 
 10510 RETURN 
 10520 IF VE<>19OR OO(4) THENIF PA(3)<>5 THEN10523 
 10521 PRINT"EINE RIESSIGE HOLZTRUHE WIRD PLOETZLICH AN DEN STRAND GETRIEBEN. 
 10522 OO(4)=5:PA(3)=6 
 10523 PA(3)=PA(3)+1 
 10530 IF VE=1AND OM=4 THENPRINT"OK.":TU(3)=0:O$(4)="OFFENE TRUHE" 
 10531 IF VE=2AND OM=4 THENPRINT"OK.":TU(3)=1:O$(4)="GROSSE SEEMANNSTRUHE" 
 10535 IF VE=8AND OM=4AND TU(3)=0AND GE(G1)=-1 THENPRINT"OK.":GE(G1)=-3 
 10540 RETURN 
 10600 DATA ,13,,,,5,12,,,:PRINT"IN DICHTEM DSCHUNGEL." 
 10620 RETURN 
 10700 DATA ,10,,,8,,9,,,:PRINT"IN DICHTEM DSCHUNGEL." 
 10720 RETURN 
 10800 DATA ,9,,,,,,7,,:PRINT"IN DICHTEM DSCHUNGEL." 
 10820 IF VE=23AND OM=7 THENPRINT"DIE MAUER IST VIEL ZU HOCH DAZU !" 
 10825 IF VE=8AND GM=5AND OM=7 THENPRINT"DAS SEIL IST LEIDER ZU KURZ !" 
 10830 RETURN 
 10900 DATA 8,8,,10,,7,,,,:PRINT"IN DICHTEM DSCHUNGEL." 
 10920 RETURN 
 11000 DATA ,11,9,,,,,11,,:PRINT"OFFENE LICHTUNG IM DSCHUNGEL.":RETURN 
 11020 IF VE=23AND OM=6 THENRI(1)=71:RI=1 
 11030 RETURN 
 11100 DATA 10,,,,,12,,,,:PRINT"IN DICHTEM DSCHUNGEL." 
 11120 IF VE=26 THENPRINT"DIE KROKODILE LASSEN DAS NICHT ZU !" 
 11122 IF VE<>27 THEN11134 
 11124 IF GE(12)<>-1 THENPRINT"WIE DENN ?":GOTO 11150 
 11130 IF PA(4)=0AND GE(12)=-1 THENPA(4)=1:PRINT"OK.ICH BEFINDE MICH AUF DEM FLUSS." 
 11132 RETURN 
 11134 IF PA(4)<>1 THEN11138 
 11135 PRINT"ZAHLREICHE KROKODILE KOMMEN HERBEIGE-{3SPACE}SCHWOMMEN !" 
 11136 PRINT"EIN BESONDERS WILDES KROKODIL KLETTERT{2SPACE}AUF DAS KLEINE FLOSS !" 
 11137 PA(4)=2:RETURN 
 11138 IF PA(4)=2 THENPRINT"DAS KROKODIL KOMMT BEDROHLICH NAEHER !":PA(4)=3:RETURN 
 11140 IF PA(4)=3 THENPRINT"DAS KROKODIL HAT MICH GEFRESSEN.":GOTO 8000 
 11150 IF PA(4)=-1 THENPRINT"DIE UEBRIGEN KROKODILE FRESSEN ES." 
 11152 IF PA(4)=-1 THENRI(1)=14:RI=1:PRINT"ICH HABE DAS ANDERE UFER ERREICHT." 
 11154 IF PA(4)=-1 THENPRINT"DAS FLOSS TREIBT AUF{SHIFT-SPACE}DEM FLUSS DAVON.":GE(12)=0 
 11155 IF PA(4)=-1 THENPOKE 198,0:WAIT 198,1 
 11160 RETURN 
 11200 DATA ,,,13,10,6,11,,,:PRINT"IN DICHTEM DSCHUNGEL." 
 11205 PRINT"IN DER NAEHE RAUSCHT WASSER." 
 11220 IF VE<>24OR OM<>11OR GE(10)<>-1OR GE(11)<>0 THEN11230 
 11225 PRINT"OK.":O$(11)="GEFAELLTER BAUM":GE(11)=ZN 
 11230 RETURN 
 11300 DATA 6,,12,,,,,,,:PRINT"IN DICHTEM DSCHUNGEL." 
 11320 RETURN 
 11400 DATA ,16,,17,,,,,,:PRINT"IN DICHTEM DSCHUNGEL." 
 11420 RETURN 
 11600 DATA 14,,,17,,,,,,:PRINT"IN DICHTEM DSCHUNGEL" 
 11620 RETURN 
 11700 DATA 14,,16,,,,,18,,:PRINT"IN DICHTEM DSCHUNGEL AM GEBIRGSRAND." 
 11720 RETURN 
 11800 DATA ,19,,,17,,,,,:PRINT"SEHR STEILER GEBIRGSPFAD." 
 11820 RETURN 
 11900 DATA 18,20,,,,,,,,:PRINT"SEHR STEILER GEBIRGSPFAD." 
 11920 RETURN 
 12000 DATA 19,23,,21,,,,,,:PRINT"IM HOHEN GEBIRGE." 
 12020 RETURN 
 12100 DATA 0,24,20,,,,23,,,:PRINT"IM HOHEN GEBIRGE." 
 12120 RETURN 
 12200 DATA ,25,,,,,,,,:PRINT"IN EINER TROCKENEN HOEHLE." 
 12220 IF VE<>28OR OM<>16 THEN12250 
 12224 PRINT"DIE SCHRIFT LAUTET :" 
 12225 PRINT"ICH BIN DEM GEHEIMNIS DER MACHT AUF DER SPUR......." 
 12226 PRINT".. CODEWORT ....{SHIFT-SPACE}NAHOC.... 
 12230 PRINT"ACHTUNG VOR DEN ROBO..... 
 12235 PRINT"....DR. GORDON.... 
 12240 PRINT"MEHR KANN MAN LEIDER NICHT ENTZIFFERN !" 
 12250 RETURN 
 12300 DATA 20,26,,,,21,25,,,:PRINT"IM HOHEN GEBIRGE." 
 12320 RETURN 
 12400 DATA 21,,,,,,26,,,:PRINT"IM HOHEN GEBIRGE." 
 12420 RETURN 
 12500 DATA ,,,26,,23,27,,,:PRINT"IM HOHEN GEBIRGE." 
 12520 IF VE=13AND OB=13 THENRI(1)=22:RI=1 
 12530 RETURN 
 12600 DATA 23,28,25,,,24,28,30,,:PRINT"IM HOHEN GEBIRGE." 
 12620 RETURN 
 12700 DATA ,,,,,25,,,,:PRINT"IM HOHEN GEBIRGE AUF EINEM FELSPLATEAU." 
 12710 PRINT"CA 10 METER UNTER MIR IST EIN SPALT IN{2SPACE}DER GEBIRGSWAND." 
 12715 IF GE(5)=-4 THENPRINT"EIN AM RING BEFESTIGTES SEIL HAENGT HIN-AB." 
 12720 IF OM=18AND GM=5AND VE=31 THENGE(5)=-4:PRINT"OK." 
 12725 IF VE=23AND GE(5)<>-4 THENPRINT"DIE WAND IST ZU STEIL !" 
 12730 IF VE=23AND GE(5)=-4 THENPRINT"OK.":RI(1)=31:RI=1:GE(5)=31:SC=SC+8 
 12740 RETURN 
 12800 DATA ,,,26,,26,,29,,:PRINT"IM HOHEN GEBIRGE." 
 12820 RETURN 
 12900 DATA ,,,,29,30,,,,:PRINT"IM HOHEN GEBIRGE." 
 12920 RETURN 
 13000 DATA ,,,,26,,29,,,:PRINT"IM HOHEN GEBIRGE." 
 13020 RETURN 
 13100 DATA ,,,,,,,,,:PRINT"AUF EINEM FELSVORSPRUNG AN EINER STEILEN"; 
 13110 PRINT"GEBIRGSWAND." 
 13120 IF VE=13AND OM=19 THENRI(1)=32:RI=1 
 13130 RETURN 
 13200 DATA 33,,31,,,,,,,:PRINT"IN EINER GROTTE." 
 13220 RETURN 
 13300 DATA ,33,,34,,,,,,:PRINT"SCHMALER GANG IN DER GROTTE." 
 13320 RETURN 
 13400 DATA 36,,,35,,,,,,:PRINT"ENGER DURCHGANG." 
 13401 IF PA(5) THENPRINT"DURCH STEINE VERSCHUETTETER AUSGANG." 
 13405 IF PA(5)<>0 THEN13420 
 13406 PRINT"HINTER MIR BRICHT EINE STEINLAWINE AUS{2SPACE}UND VERSCHUETTET DEN AUS"; 
 13407 PRINT"GANG ZUM SPALT{2SPACE}GAENZLICH !":PA(5)=1 
 13420 RETURN 
 13500 DATA ,,34,,,,,,,:PRINT"FEUCHTE GROTTE." 
 13520 RETURN 
 13600 DATA ,34,,,,,,,,:PRINT"IN EINER GROTTE." 
 13601 PRINT"IN DER WAND IST EINE STAHLTUER EINGELAS-SEN.":IF PA(6)<>0 THEN13620 
 13602 PRINT"HINTER DEN FELSEN SCHNELLEN STAHLGREIF- ARME HERVOR UND HALTEN MI"; 
 13603 PRINT"CH FEST." 
 13604 PRINT"EIN KLEINER APPARAT SCHWEBT DIREKT VOR{2SPACE}MEIN GESICHT.":PA(6)=1 
 13605 RETURN 
 13620 IF PA(6)<>1 THEN13640 
 13621 PRINT"EINE SYNTHETISCHE STIMME AUS DEM APPARATFRAGT :"; 
 13622 PRINT"'WIE LAUTET DAS CODEWORT ?'.":GOSUB 50000 
 13625 IF VE=34 THENPA(6)=-1 
 13630 IF PA(6)=1 THENPRINT"EIN LASERSTRAHL SCHIESST AUS DEM APPARAT.":GOTO 8000 
 13632 PA(6)=-1:PRINT"DIE SYNTHETISCHE STIMME SAGT : 'CODEWORTAKZEPTIERT !'." 
 13633 PRINT"DIE GREIFARME LASSEN MICH WIEDER FREI,{2SPACE}DER APPARAT SCHWEBT DAVON." 
 13634 PRINT"DIE STAHLTUER OEFFNET SICH MIT EINEM{4SPACE}LEISEN SURREN.":OO(22)=36 
 13635 O$(21)="OFFENE STAHLTUER" 
 13640 IF VE=13AND OM=22 THENRI(1)=37:RI=1 
 13650 RETURN 
 13700 DATA ,36,,,,,,,,:PRINT"IN EINEM AUFZUG.":RETURN 
 13720 IF VE<>35OR OM<>23OR PA(7)=3 THEN13730 
 13721 PRINT"DIE STAHLTUER SCHLIESST SICH MIT EINEM{2SPACE}LEISEN SURREN. 
 13722 IF PA(7)=0 THENPRINT"DIE ROTE TASTE BLINKT KURZ HELL AUF." 
 13723 IF PA(7)=0 THENPRINT"SELTSAM - DIE STAHLTUER OEFFNET SICH{4SPACE}WIEDER !" 
 13724 IF PA(7)=0OR PA(7)=3 THEN13730 
 13725 PRINT"DER AUFZUG BEWEGT SICH LEISE NACH UNTEN.";:SC=SC+9.5 
 13726 PRINT"NACH CA 2 MINUTEN BLEIBT ER STEHEN !" 
 13727 PRINT"DIE STAHLTUER OEFFNET SICH.":PA(7)=3:RI(2)=38 
 13730 IF VE=1AND OM=24 THENPRINT"DER SCHALTKASTEN IST VERRIEGELT !" 
 13735 IF VE<>37OR OM<>24 THEN13750 
 13737 IF GM=0 THENPRINT"DOCH NICHT ETWA MIT MEINEN BLOSSEN HAEN-DEN !" 
 13739 IF GM=3 THENPRINT"MIT DEM SAEBEL SCHAFFE ICH DAS NICHT !" 
 13740 IF GM<>10 THEN13750 
 13741 PRINT"MIT LAUTEM KRACHEN FAELLT DIE BLECHAB-{2SPACE}DECKUNG DES SCHALTKASTENS"; 
 13742 PRINT" AUF DEN BODEN.":GE(13)=37 
 13743 OO(25)=37:O$(24)="AUFGEBROCHENER SCHALTKASTEN" 
 13750 IF VE=31OR VE=42 THENIF OM=25 THENPRINT"OK.":PA(7)=1 
 13751 IF PA(7)<>1 THEN13760 
 13752 PRINT"DIE ROTE TASTE LEUCHTET HELL AUF." 
 13753 O$(23)="HELL LEUCHTENDE ROTE TASTE":PA(7)=2 
 13754 O$(25)="IM SCHALTKASTEN SIND ZWEI MITEINANDER KURZGESCHLOSSENE ROTE KABEL" 
 13760 RETURN 
 13800 DATA ,,42,,,,,,,:PRINT"SCHWACH BELEUCHTETER RAUM." 
 13820 IF VE=1AND OM=33 THENPRINT"ICH KANN DIE STAHLTUER NICHT OEFFNEN." 
 13825 RETURN 
 13900 DATA ,,,,,,,,,:PRINT"RAUM MIT VERRIEGELTER STAHLTUER.":RETURN 
 13920 IF PA(8) THENPRINT"LANGSAM VERSCHWINDET MEINE MUEDIGKEIT{3SPACE}WIEDER." 
 13921 IF PA(8) THENPRINT"ICH BIN GEFANGEN !":PA(8)=0 
 13925 IF VE<>13OR OM<>27 THEN13940 
 13930 IF GE(14)=0 THENPRINT"EIN DRAHTGITTER VERSCHLIESST DEN ZUGANG ZUM SCHACHT." 
 13932 IF GE(14)<>0 THENRI(1)=72:RI=1 
 13940 IF VE<>37OR OM<>35 THEN13950 
 13942 IF GM=0 THENPRINT"WOMIT DENN ?":GOTO 13950 
 13943 IF GM<>10 THEN13950 
 13944 PRINT"OK. DAS DRAHTGITTER FAELLT HERRUNTER UNDGIBT DEN EIN";:SC=SC+5 
 13945 PRINT"GANG ZUM SCHACHT FREI." 
 13946 OO(35)=0:GE(14)=39:GE$(14)="DRAHTGITTER" 
 13950 RETURN 
 14000 DATA ,41,51,,,,,,,:PRINT"NORDENDE EINES KORRIDORS." 
 14020 RETURN 
 14100 DATA 40,42,43,39,,,,,,:PRINT"LANGER KORRIDOR." 
 14120 RETURN 
 14200 DATA 41,,44,38,,,,,,:PRINT"SUEDENDE EINES KORRIDORS." 
 14220 RETURN 
 14243 PRINT"OK.":GE(GM)=-4 
 14250 NEXT 
 14300 DATA ,,,41,,,,,,:PRINT"AUSSRUESTUNGSRAUM." 
 14320 IF VE=13AND OM=29 THENPRINT"DAZU BIN ICH ZU GROSS." 
 14322 IF VE>2OR OM<>29 THEN14340 
 14325 IF TU(4)<>2 THEN14330 
 14326 IF GE(17)<>-1 THENPRINT"DER SCHRANK IST VERRIEGELT !" 
 14327 IF GE(17)<>-1 THENPRINT"ICH HABE AUCH KEINEN SCHLUESSEL !" 
 14330 IF VE=1AND GE(17)=-1 THENPRINT"OK.":TU(4)=0 
 14335 IF VE=2AND TU(4)=0 THENPRINT"OK.":TU(4)=2 
 14340 IF VE<>8OR OM<>29OR GM=0 THEN14350 
 14341 IF TU(5)=0 THENPRINT"DER SCHRANK IST NICHT OFFEN.":GOTO 14350 
 14343 PRINT"OK.":GE(GM)=-4 
 14350 RETURN 
 14400 DATA ,45,49,42,,,,,,:PRINT"RAUM." 
 14420 RETURN 
 14500 DATA 44,46,48,,,,,,,:PRINT"KORRIDOR." 
 14520 RETURN 
 14600 DATA 45,,,,,,,,,:PRINT"ELEKTRIZITAETS-LABOR." 
 14620 RETURN 
 14700 DATA ,,,,,,,,48,:PRINT"GROSSE HALLE." 
 14710 IF YT THENYT=1:SC=SC+5 
 14720 RETURN 
 14800 DATA ,,,45,,,,,,47:PRINT"GEKACHELTER RAUM." 
 14820 RETURN 
 14900 DATA 50,,,44,,,,,,:PRINT"KLEINER KORRIDOR." 
 14920 RETURN 
 15000 DATA ,49,,,,,,,,:PRINT"GROSSES ANTIK EINGERICHTETES WOHNZIMMER."; 
 15020 IF VE<>47OR OM<>38 THENRETURN 
 15021 IF YA THENYA=1:SC=SC+5 
 15022 PRINT"OK.":PRINT"DAS LICHT IM RAUM GEHT PLOETZLICH AUS{3SPACE}UND EIN "; 
 15023 PRINT"HELLER RECHTECKIGER FLECK ER-{3SPACE}SCHEINT AN DER ZIMMERWAND." 
 15024 PRINT"EIN VERSTECKTER PROJEKTOR BEGINNT ZU{4SPACE}LAUFEN !" 
 15025 PRINT"AN DER WAND ERSCHEINT DAS BILD EINES{4SPACE}WESENS DAS HALB MENSCH "; 
 15026 PRINT"UND HALB ROBOTER IST UND EIN TONBAND BEGINNT ZU LAUFEN........" 
 15027 POKE 198,0:WAIT 198,1 
 15030 PRINT"HIER SPRICHT PROFESSOR COHAN !{10SPACE}MEIN EXPERIMENT, EINE BES"; 
 15031 PRINT"SERE KUENSTLI- CHE MENSCHHEIT ZU SCHAFEN IST FEHLGE-{3SPACE}SCHLAGEN." 
 15032 PRINT"MEINE ROBOTER HABEN SICH GEGEN MICH GE- WENDET." 
 15033 PRINT"BEI EINEM KAMPF WURDE MEINE MECHANISCHE KOERPERHAELFTE ZERSTOERT !" 
 15035 PRINT"ICH HABE NUR NOCH KURZE ZEIT ZU LEBEN." 
 15036 PRINT"ICH VERSUCHE NUN DIE VERBOTENE ZONE ZU{2SPACE}ERREICHEN UND DIE QUELLE "; 
 15037 PRINT"DER MACHT MIT{2SPACE}EINER ZEITBOMBE ZU ZERSTOEREN UM DIE BE-VORSTEHENDE"; 
 15038 PRINT" ROBOTERINVASION AUF DIE MEN-SCHHEIT ZU VERHINDERN." 
 15040 PRINT"MOEGE GOTT MIR MEIN VERBRECHEN VERGEBEN......." 
 15045 POKE 198,0:WAIT 198,1 
 15050 PRINT"DAS BILD AN DER WAND VERSCHWINDET UND{3SPACE}DAS LICHT GEHT WIEDER AN." 
 15099 RETURN 
 15100 DATA ,,,40,,,,,,:PRINT"KLEINER WEISS GEKACHELTER RAUM." 
 15120 IF VE<>45AND VE<>35OR OM<>36 THEN15130 
 15122 PRINT"DIE SCHLEUSSE OEFFNET SICH.":O$(28)="OFFENE SCHLEUSSE":TU(5)=0 
 15123 IF YB THENYB=1:SC=SC+2.5 
 15124 PRINT"EINE SYNTHETISCHE STIMME RUFT 'ALARM !{2SPACE}SCHLEUSSE ZUR VERBOTENEN"; 
 15126 PRINT"{SHIFT-SPACE}ZONE IST AKTI- VIERT WORDEN !'." 
 15130 IF VE=13AND OM=28AND TU(5)=0 THENRI(1)=52:RI=1 
 15140 RETURN 
 15200 DATA ,51,,,53,,,,,:PRINT"ENGER GANG IM INNEREN DES GEBIRGES." 
 15205 PRINT"DER BODEN STRAHLT IN EINEM SELTSAMEN{4SPACE}VIOLETTEN LICHT." 
 15220 IF GE(16)<>-1 THENPA(9)=1 
 15230 RETURN 
 15300 DATA 54,,,,,,56,52,,:PRINT"HOEHLENSYSTEM." 
 15320 RETURN 
 15400 DATA ,53,,,,,55,,,:PRINT"HOEHLENSYSTEM." 
 15420 RETURN 
 15500 DATA 59,56,57,,,54,57,,,:PRINT"HOEHLENSYSTEM." 
 15520 RETURN 
 15600 DATA 55,58,57,,59,53,,,,:PRINT"HOEHLENSYSTEM." 
 15620 RETURN 
 15700 DATA 55,,,56,,55,,,,:PRINT"HOEHLENSYSTEM." 
 15720 RETURN 
 15800 DATA 56,,,,57,,,,,:PRINT"HOEHLENSYSTEM." 
 15820 RETURN 
 15900 DATA ,,,55,,,,56,60,0:PRINT"HOEHLENSYSTEM." 
 15920 RETURN 
 16000 DATA ,,,,,,,,61,59:PRINT"HOEHLENSYSTEM." 
 16020 RETURN 
 16100 DATA ,,,,,,,,,60:PRINT"AM ENDE DES WEGES. 
 16101 PRINT"VOR MIR LIEGT EIN TIEFER, CA 10 METER{3SPACE}BREITER ABGRUND DER IN "; 
 16102 PRINT"DUNKELHEIT GE-{3SPACE}HUELLT IST." 
 16103 PRINT"AUF DER ANDEREN SEITE DES ABGRUNDS SETZTSICH DER WEG FORT." 
 16104 PRINT"AN DER FELSWAND AUF DER ANDEREN SEITE{3SPACE}IST EIN ROT LEUCHTENDER"; 
 16105 PRINT" DRUCKKNOPF ANGE-BRACHT." 
 16120 IF VE=35AND OM=39 THENPRINT"MEINE ARME SIND NICHT 10 METER LANG !" 
 16130 IF BR<>1 THEN16135 
 16131 PRINT"EIN LAUTES RATTERN ERTOENT !":SC=SC+10 
 16132 PRINT"EINE BRUECKE AUS STAHL WIRD UEBER DEN{3SPACE}ABGRUND HINWEG HERRUEBER"; 
 16133 PRINT" GESCHOBEN.":BR=2:OO(40)=61:OO(41)=63 
 16135 IF VE=13AND OM=40 THENRI(1)=62:RI=1 
 16140 IF VE<>8OR GM<>6OR OM<>39 THEN16150 
 16141 IF BR<>-1 THENPRINT"DIE PISTOLE FAELLT HINAB.":GE(6)=0:GOTO 16150 
 16142 PRINT"OK.":PRINT"DIE PISTOLE TRIFFT DEN DRUCKKNOPF MIT{3SPACE}VOLER WUCHT !" 
 16143 GE(6)=63:BR=1:GOTO 16130 
 16150 RETURN 
 16200 DATA 63,61,,,,,,,,:PRINT"AUF EINER STAHLBRUECKE DIE UEBER EINEN "; 
 16210 PRINT" TIEFEN, DUNKLEN ABGRUND FUEHRT." 
 16220 RETURN 
 16300 DATA ,,,64,0,0,0,0,0,0:PRINT"HOEHLENWEG AM RANDE EINES ABGRUNDS." 
 16320 IF VE=13AND OM=41 THENRI(1)=62:RI=1 
 16325 IF VE=35AND OM=42 THENPRINT"OK.":PRINT"ES PASSIERT NICHTS." 
 16330 RETURN 
 16400 DATA ,,63,,,,,65,,:PRINT"HOEHLENSYSTEM." 
 16420 RETURN 
 16500 DATA ,,,,64,,,,66,:PRINT"FEUCHTE GROTTE." 
 16501 PRINT"EINE BREITE UNREGELMAESSIGE STEINTREPPE FUEHRT NACH OBEN." 
 16520 RETURN 
 16600 DATA ,,,67,,,,,,65:PRINT"RIESSIGER PRUNKVOLLER TEMPELRAUM." 
 16620 RETURN 
 16700 DATA ,69,66,68,,,,,,:PRINT"GROSSER RUNDER RAUM." 
 16720 IF VE<>8OR OM<>43 THEN16740 
 16725 IF G1<>18AND GE(G1)=-1 THENPRINT"OK.":GE(G1)=0 
 16727 IF G1<>18 THEN16740 
 16730 PRINT"EINE SYNTHETISCHE STIMME AUS DER ZEIT-{2SPACE}BOMBE SPRICHT :":GE(18)=-9 
 16732 PRINT"'MISSION BEENDET. DETONATION ERFOLGT IN ";ZB;"ZEITEINHEITEN !'" 
 16733 SC=SC+10 
 16740 RETURN 
 16800 DATA ,,67,,,,,,,:PRINT"ALTARRAUM." 
 16820 RETURN 
 16900 DATA 67,,,,,,,,,:PRINT"AUSSERHALB DES TEMPELS." 
 16920 IF VE=23AND OM=44 THENPRINT"DIE MAUER IST VIEL ZU HOCH UND ZU STEIL." 
 16925 IF VE=13OR VE=26OR VE=48 THENRI(1)=75:RI=1:SC=SC+5 
 16930 RETURN 
 17100 DATA ,,,,,,,,,10:PRINT"HOCH OBEN AUF EINEM AFFENBROTBAUM." 
 17110 IF PA(3)<>-1 THENPA(3)=5 
 17120 RETURN 
 17200 DATA 39,45,,,,,,,,:PRINT"IN EINEM BELUEFTUNGSSCHACHT." 
 17220 RETURN 
 17500 DATA ,,,,,,,,,:PRINT"ICH SCHWIMME UNTER DER MAUER DURCH UND{2SPACE}TREIBE NUN"; 
 17501 PRINT" AUF DEM FLUSS......" 
 17520 POKE 198,0:WAIT 198,1 
 17525 :PRINT"{CLR}UND SO ENDETE DAS ABENTEUER DES{SPACE,8SPACE}MR BOLINGS :" 
 17530 PRINT"MIT LETZTER KRAFT ERREICHTE ER DEN{6SPACE}INSELSTRAND, WO ER "; 
 17532 PRINT"VON EINEM VORBEIFAH- RENDEN HANDELSSCHIFF ENTDECKT UND IN "; 
 17533 PRINT"{3SPACE}SEINE HEIMAT ZURUECKGEBRACHT WURDE." 
 17540 IF GE(18)<>-9 THEN17550 
 17545 PRINT"ALS DIE ZEITBOMBE EXPLODIERTE VERSANK{3SPACE}DIE GESAMTE INSEL SPURLOS"; 
 17546 PRINT" IM MEER......" 
 17550 IF GE(18)=-9 THEN17560 
 17552 PRINT"WAS MIT DEN ROBOTERN GESCHAH BLIEB{6SPACE}BISHER UNBEKANNT...... 
 17560 PRINT"{WHITE}SIE HABEN";SC;"% DIESES ADVENTURES GELOEST." 
 17564 PRINT"{2DOWN,LIG.RED}MIT FREUNDLICHEN GRUESSEN, 
 17565 PRINT"{2DOWN,14SPACE}MICHAEL NICKLES 
 17566 POKE 198,0:WAIT 198,1:RUN 
 50000 REM **************************** 
 50050 IF UD=1 THEN50220 
 50055 TT=0 
 50060 FOR I=1 TO10:BE$(I)="":NEXT :POKE 198,0:BE$="" 
 50061 PRINT"{GREEN}WAS SOLL ICH NUN MACHEN ?":PRINT"{GREY2,DOWN}@"; 
 50080 GET X$:TT=TT+1:IF TT>1500 THENPRINT"{UP,GREEN}":GOTO 50140 
 50085 IF X$="" THEN50080 
 50086 TT=0 
 50090 IF PEEK (203)=1OR LEN (BE$)>75 THENIF BE$<>"" THENPRINT"{LEFT}.{GREEN}":GOTO 50140 
 50100 I=ASC (X$):IF I<65OR I>90 THENIF I<>32AND I<>20AND I<>34 THEN50080 
 50110 IF I=20AND LEN (BE$)=0 THEN50080 
 50120 IF I=20 THENPRINT"{2LEFT,2SPACE,2LEFT}@";:BE$=LEFT$ (BE$,LEN (BE$)-1):GOTO 50080 
 50130 BE$=BE$+CHR$ (I):I=I+128:PRINT"{LEFT}";CHR$ (I);"@";:GOTO 50080 
 50140 BE$=BE$+" ":FOR I=1 TO10:BE$(I)="":NEXT :WZ=1:FOR I=1 TOLEN (BE$) 
 50150 :IF MID$ (BE$,I,1)=" " THENGOSUB 50190:GOTO 50180 
 50160 :IF WZ>19 THENPRINT"EINGABE IST ZU LANG !":I=LEN (BE$)+1:GOTO 50180 
 50170 :BE$(WZ)=BE$(WZ)+MID$ (BE$,I,1) 
 50180 NEXT I:GOTO 50220 
 50190 IC=0:FOR I1=1 TOAZ:IF BE$(WZ)=AU$(I1) THENIC=1 
 50200 NEXT I1:IF IC=0 THENWZ=WZ+1:RETURN 
 50210 BE$(WZ)="":RETURN 
 50220 IF UD=1 THENUD=0:GOTO 50240 
 50230 WZ=1:VE=0:OB=0:OM=0:PE=0 
 50240 IC=0:G1=0:G2=0:GM=0 
 50241 B$=BE$(WZ):IF B$="" THENRETURN 
 50242 IF B$="SUPERMIKE" THENPRINT"0937210682":IC=1:GOTO 50370 
 50245 FOR I=1 TO10:IF B$=RI$(I) THENRI=I 
 50246 NEXT I:IF RI<>0 THENRETURN 
 50260 FOR I=1 TOVZ:IF B$=LEFT$ (VE$(I),LEN (B$)) THENVE=I-VAL (RIGHT$ (VE$(I),1)):IC=1 
 50261 NEXT I:IF IC THEN50370 
 50270 FOR I=1 TOGZ 
 50275 IF MID$ (B$,2,LEN (B$)-1)<>MID$ (GE$(I),2,LEN (GE$(I))-1) THEN50300 
 50280 IC=1:IF G1=0 THENG1=I:IF GE(G1)=-1 THENGM=I 
 50290 G2=I:IF G2=G1 THENG2=0 
 50300 NEXT I:IF IC THEN50370 
 50310 FOR I=1 TOOZ:IF B$=OB$(I) THENOB=I:IC=1:IF OO(I)=ZN THENOM=I 
 50320 NEXT I:IF IC THEN50370 
 50329 REM     IFLEN(B$)<3THEN50350 
 50330 FOR I=1 TOPZ 
 50331 IF MID$ (B$,2,LEN (B$)-1)=MID$ (PE$(I),2,LEN (PE$(I))-1) THENPE=I:IC=1 
 50332 IF PE=IAND PE(I)=ZN THENPM=PE:IC=2 
 50340 NEXT I:IF IC THEN50370 
 50350 IF B$="UND" THENUD=1:IC=1 
 50360 IF IC=0AND RI=0 THENPRINT"ICH KENNE ";B$;" NICHT !":GOTO 50000 
 50370 WZ=WZ+1:IF WZ>10OR BE$(WZ)=""OR UD=1 THENRETURN 
 50380 IC=0:GOTO 50241 
 51000 REM ALLGEMEINE TABELLEN ---------- 
 51005 RESTORE 51000 
 51010 DATA N,S,W,O,NW,NO,SW,SO,RAUF,RUNTER:FOR I=1 TO10:READ RI$(I):NEXT 
 51100 TU(1)=1:REM SCHRANK 
 51105 TU(2)=1:REM HAUSTUER 
 51110 TU(3)=1:REM TRUHE 
 51115 TU(4)=2:REM SCHRANK 
 51116 TU(5)=1:REM SCHLEUSSE 
 51120 MU=4 
 51130 DIM BE$(20) 
 51200 : 
 51210 DATA 51,51,51,40,41,42,44,45,48,48,48,45,44,42,41,40,-1 
 51220 DIM MA(17):FOR I=1 TO17:READ MA(I):NEXT :MA=1:REM ROBOT AKTIV 
 52000 REM W O R T S C H A T Z ---------- 
 52005 RESTORE 52000 
 52010 DATA OEFFNE,SCHLIESSE,SCHAUE,UNTERSUCHE1,NIMM,NEHME1,HOLE2,VERLIERE,LEGE1 
 52011 DATA WIRF2,WERFE3,INVENTUR,GEHE 
 52012 DATA BETRETE1,VERLASSE,GIB,GEBE1,ZEIGE2,WARTE,TOETE,ERLEGE1,SCHIESSE2 
 52013 DATA KLETTERE,FAELLE,BAUE,SCHWIMME,UEBERQUERE,LIES,LESE1,HILFE 
 52014 DATA BEFESTIGE,BINDE1,VERKNOTE2,NAHOC,DRUECKE,BETAETIGE1 
 52015 DATA BRECHE,BRICH1,ZERSCHLAGE2,ZERSTOERE3,VERNICHTE4 
 52016 DATA VERBINDE,KURZ1,STECKE,ZIEHE,SCHIEBE1,SETZE,SPRINGE,ESSE 
 52040 VZ=49:DIM VE$(VZ):FOR I=1 TOVZ:READ VE$(I):NEXT 
 52100 DATA DER,DIE,DAS,DEN,IN,AUF,NACH,VOM,ZUM,DEM,AUFS,SIE,MIT,UEBER,HOCH,WEG 
 52105 DATA EIN,AM,AN,DICH 
 52120 AZ=20:DIM AU$(AZ):FOR I=1 TOAZ:READ AU$(I):NEXT 
 52200 REM DIE OBJEKTE -------------- 
 52210 DATA SCHRANK,"ALTER SCHRANK AUS EICHENHOLZ",1 
 52212 DATA HAUSTUER,"HAUSTUER",1 
 52214 DATA SCHIFF,"SCHIFF",3 
 52216 DATA TRUHE,"GROSSE SEEMANNSTRUHE",0 
 52217 DATA TUER,"HAUSTUER",2 
 52218 DATA BAUM,"HOHER AFFENBROTBAUM",10 
 52219 DATA MAUER,"SEHR HOHE, BREITE MAUER AUS FELSBROCKEN",8 
 52220 DATA FLUSS,"BREITER REISSENDER FLUSS",11 
 52221 DATA KROKODIL,"VIELE KROKODILE LAUERN IM FLUSS",11 
 52222 DATA KAMIN,"KAMIN",1 
 52223 DATA BAUM,"DUENNE HOLZBAUME",12 
 52224 DATA FLUSS,"BREITER REISSENDER FLUSS",14 
 52225 DATA HOEHLE,"EINGANG ZU EINER HOEHLE",25 
 52226 DATA HOEHLENWAND,"HOEHLENWAND",22 
 52227 DATA STEIN,"SPITZER KREIDESTEIN",0 
 52228 DATA SCHRIFT,"SCHWER LESBARE SCHRIFT",0 
 52229 DATA SKELETT,"IN EINER ECKE LIEGT EIN MENSCHLICHES SKELETT",22 
 52230 DATA EISENRING,"AM BODEN IST EIN EISENRING BEFESTIGT",27 
 52231 DATA SPALT,"CA 1 METER BREITER SPALT IN DER GEBIRGSWAND",31 
 52232 DATA TROPFSTEINE,"VON DER DECKE HAENGEN GEBILDE AUS TROPFSTEINEN",35 
 52233 DATA STAHLTUER,"STAHLTUER",36 
 52234 DATA AUFZUG,"DIE STAHLTUER GIBT DEN ZUGANG ZU EINEM AUFZUG FREI",0 
 52235 DATA TASTE,"ROTE TASTE",37 
 52236 DATA SCHALTKASTEN,"AN DER WAND HAENGT EIN SCHALTKASTEN",37 
 52237 DATA KABEL,"IM SCHALTKASTEN SIND ZWEI ROTE KABEL MIT BLANKEN ENDEN",0 
 52238 DATA STECKDOSE,"IN DER WAND IST EINE STECKDOSE",41 
 52239 DATA SCHACHT,"IN DER WAND IST EIN BELUEFTUNGSSCHACHT",39 
 52240 DATA SCHLEUSSE,"SCHLEUSSE AUS STAHL",51 
 52241 DATA SCHRANK,"SCHRANK AUS STAHL",43 
 52242 DATA SCHACHT,"IN DER WAND IST EIN BELUEFTUNGSCHACHT",45 
 52244 DATA TREPPE,"WENDELTREPPE DIE NACH UNTEN FUEHRT",48 
 52245 DATA TREPPE,"WENDELTREPPE DIE NACH OBEN FUEHRT",47 
 52246 DATA STAHLTUER,"VERSCHLOSSENE STAHLTUER",38 
 52247 DATA KAMPFROBOTER,"RIESSIGES REGUNGSLOSES KAMPFROBOTERHEER",47 
 52248 DATA DRAHTGITTER,"VOR DEM SCHACHT IST EIN DRAHTGITTER",39 
 52249 DATA SCHALTHEBEL,"NEBEN DER SCHLEUSSE IST EIN ROTER SCHALTHEBEL",51 
 52250 DATA TOTEN,"AM BODEN LIEGT EIN TOTER - HALB MENSCH HALB ROBOTER",51 
 52252 DATA SESSEL,"IN DER MITTE DES RAUMS STEHT EIN ANTIKER SESSEL",50 
 52253 DATA DRUCKKNOPF,"LEUCHTENDER DRUCKKNOPF",61 
 52254 DATA BRUECKE,"BRUECKE AUS STAHL",0 
 52255 DATA BRUECKE,"BRUECKE AUS STAHL",0 
 52256 DATA DRUCKKNOPF,"LEUCHTENDER DRUCKKNOPF IN DER FELSWAND",63 
 52257 DATA BRUNNEN,"IN DER MITTE DES RAUMS IST EINE ART VON BRUNNEN",67 
 52258 DATA MAUER,"SEHR HOHE, BREITE MAUER AUS FELSBROCKEN",69 
 52259 DATA FLUSS,"BREITER FLUSS, DER UNTER DER MAUER DURCHFLIESST",69 
 52260 OZ=45:DIM OB$(OZ):DIM O$(OZ):DIM OO(OZ) 
 52262 FOR I=1 TOOZ:READ OB$(I):READ O$(I):READ OO(I):NEXT 
 52300 DATA "SEEKARTE",0,"MUSCHELN",5 
 52302 DATA "SAEBEL",-3,"SCHIFFSZWIEBACK",-3,"SEIL",-3,"PISTOLE",-3 
 52303 DATA "MUNITION",-3,"FLASCHE",-2,"BUCH",0,"AXT",-3,"HOLZ",0 
 52305 DATA "FLOSS",0,"BLECHDECKEL",0,"DRAHT",0,"STROMKABEL",46 
 52306 DATA "SCHUTZANZUG",-4,"SCHLUESSEL",0,"ZEITBOMBE",0 
 52330 GZ=18:DIM GE$(GZ):DIM GE(GZ):FOR I=1 TOGZ:READ GE$(I):READ GE(I):NEXT 
 52400 DATA "NAVIGATOR",4,"KAEPTEN GRAUBARD",4,"LOEWE",0,"VERBRANNTER ROBOTER",0 
 52410 PZ=4:DIM PE$(PZ):DIM PE(PZ):FOR I=1 TOPZ:READ PE$(I):READ PE(I):NEXT 
 53000 RETURN 
 60000 REM MP 
 60004 FOR I=49152 TO49206:READ A:POKE I,A:NEXT :SYS 49152:SYS 49191:SP=49152 
 60010 DATA 160,0,177,122,201,44,240,1,96,32,115,0,32,49,192,165,20,32,23,192 
 60020 DATA 76,0,192,41,63,141,1,221,9,64,141,1,221,173,1,221,48,251,96,169,127 
 60025 DATA 141,3,221,169,0,76,23,192,32,138,173,76,247,183 
 60045 RETURN :REM SYS49152,6,3,26,0,16,4,4,39,7,21,2,19,4 
 61000 REM SPEAKEASY-SAETZE 
 61010 REM SYSSP,19,37,4,57,23,3,63,7,4,23,44,41,55,13:RETURN 
 61020 REM SYSSP,33,7,44,41,4,33,30,8,4,16,26,62,4,11,59,8,3,3,4:RETURN 
 61030 REM SYSSP,27,26,62,45,53,4,4,4,19,37,4,27,6,55,55,7,4,4,16,19,55,17,52,4 
 61031 REM SYSSP,63,31,45,19,11,4:RETURN