MPS 801 sieht bunt
Jetzt kommt Farbe ins Leben Ihres MPS 801. Hochauflösende Grafiken lassen sich ohne viel Aufwand in drei Farben drucken. Das ganze Geheimnis sind ein ausgefeiltes Programm und Kohlepapier.
Das Programm »Colorprint« druckt zusammen mit dem MPS 802 farbige Hardcopies vom HiRes-Bildschirm. Um den Farbdruck zu ermöglichen, benötigen Sie zwei farbige Kohlepapiere (Durchpauspapier). Die Farben werden nacheinander aufs Papier gebracht. Der Reihenfolge nach wird zuerst in der Farbe des Farbbandes (meistens schwarz) und dann nacheinander mit dem Kohlepapier gedruckt.
Da der MPS 801 keine Papierrückzug-Option besitzt, muß das Papier nach jeder Farbe vollständig herausgedreht und wieder (mit dem nächsten Kohlepapier) eingefädelt werden. Um eine exakte Positionierung zu ermöglichen, wird vor dem ersten Druck auf der rechten Seite des Blattes direkt über dem Metallstreifen (unterhalb des Druckkopfes) ein Strich gezogen. Beim nächsten Einzug wird dann das Blatt vorsichtig bis zum Erscheinen des Striches gedreht. Damit steht dem Farbdruck nichts mehr im Weg.
Eingabehinweise. Geben Sie Colorprint (Listing 1) mit dem Checksummer ein. Dazu kommen noch fünf Maschinenprogramme, die Sie bitte mit dem MSE eingeben. Sie werden von Colorprint nachgeladen und müssen sich auf der gleichen Diskette befinden.
Nach dem Programmstart durch RUN werden zuerst die fünf Maschinenroutinen nachgeladen. Anschließend meldet sich der Computer mit dem Hauptmenü. Mit den Cursortastenund <RETURN> kann man das gewünschte Untermenü aufrufen. Das Interessanteste ist wohl das Druck-Menü. Eseerscheint zuerst die Frage, ob man das Bild invertiert drucken möchte. Das heißt, die Farben Schwarz und Weiß, Blau und Rot werden vertauscht.
Um einen Farbdruck mit einem Drucker zu ermöglichen, der eigentlich gar nicht für Farbdruck vorgesehen ist, muß man einen kleinen Trick anwenden. Dazu braucht man zwei gewöhnliche Kohlepapiere (am besten rot und blau), die normalerweise zum Durchpausen von Zeichnungen etc. verwendet werden.
Gedruckt wird im Overlayverfahren. Das heißt, die Farben werden nacheinander auf das Blatt gebracht. Ein weiteres Problem ist, daß der Drucker MPS 801 keine Papierrückzugoption besitzt. Also muß auch hier ein kleiner Trick helfen: Das Blatt (am besten nimmt man immer nur ein einzelnes Blatt) wird ganz normal in den Traktor eingefädelt. Nun zieht man direkt über dem Metallstreifen (unterhalb des Druckkopfes) am rechten Papierrand einen Strich (Bild 1).
Billige Alternative
Dieser Strich ermöglicht es, das Blatt wieder genau in dem Drucker zu positionieren. Wenn der Computer die Farbe Schwarz vorschlägt, kann man das Blatt gleich eingefädelt lassen. Auf Tastendruck wird der Ausdruck begonnen (mit dem normalen, schwarzen Farbband). Nach Beendigung des ersten Drucks muß das Blatt ganz herausgedreht werden. Nun wird das vorgeschlagene Kohlepapier (rot oder blau) deckungsgleich auf das Blatt mit dem ersten Ausdruck gelegt und vorsichtig in den Drucker eingefädelt (Bild 2, 3). Anschließend wird das Blatt bis zum Erscheinen des Strichs weitergedreht. Auf Tastendruck startet der zweite Ausdruck. Mit dem dritten Druckvorgang wird genauso verfahren.
Der Farbdruck funktioniert also folgendermaßen: Wenn der Druckkopf auf das Kohlepapier druckt, gibt das Kohlepapier seine Farbe an das (noch) weiße Blatt ab. Ganz einfach, oder? Man ist also auch nicht an die Farben Rot und Blau gebunden.
Nach dreimaligem Druck kann man sein Meisterwerk begutachten und bewundern. Die Qualität der Bilder kann sich sehen lassen, der Aufwand lohnt sich. Man braucht also nicht gleich einen Farbdrucker zu kaufen, wenn man ein paar Bilder farbig haben möchte. Auch sind die Kohlepapiere ein billiger Ersatz für die Farbbänder von Farbdruckern. Eine weitere Anwendung der »Farbbänder« wäre folgendes: Man nehme einen Drucker mit einer höheren Auflösung, welcher dann einen Mischfarbdruck ermöglicht. Damit steht diese Alternative professionellen Farbdruckern in nichts mehr nach. Auch ist man in der Farbwahl nur durch das Angebot von farbigen Kohlepapieren begrenzt.
Die Besonderheiten
Die Hardcopy-Routine muß folgendes bewirken:
- Nur die Codes 11 werden direkt zum Drucker gesendet. Alle anderen Codes werden auf 00 gesetzt.
- Die Codes 01 beziehungsweise 10 (je nachdem, welche Farbe gerade gedruckt werden soll) werden auf 11 gesetzt; die anderen Codes werden wieder auf 00 gesetzt.
Ein Beispiel:
Der Code 11 soll schwarz gedruckt werden;
01 blau und
10 rot.
Bei der Farbe Schwarz sieht dann die Zahl 11010010 so aus:
11000000
Bei Blau: 00110000
Bei Rot: 00000011
Der Code 00 wird auf dem Papier weiß gelassen. Er kann aber ebenfalls farbig gedruckt werden! Dazu werden die Codes 00 auf 11 gesetzt und die übrigen auf 00.
Nun noch eine Beschreibung der übrigen Menüs:
Diskwork: Im Diskwork-Menü kann man das Directory der Diskette ansehen. Es wird links unten in einem Fenster eingeblendet.
Es werden alle Multicolor-Bilder geladen. Die Startadresse liegt automatisch bei $2000.
Farbwechsel: In diesem Menü kann man die Farben, die später nacheinander gedruckt werden, ansehen und ändern. Die Punkte, die weiß gezeigt werden, werden später mit der gewünschten Farbe gedruckt.
Bild zeigen: Hier kann man das Bild im Speicher betrachten. Mit den Funktionstasten werden die Farben geändert. Diese Farbeinstellung hat keinen Einfluß auf den späteren Druck.
Mit <I> kann man einen Eindruck von einem invertierten Ausdruck gewinnen. Jede andere Taste führt zurück ins Hauptmenü.
Anmerkungen zum Schluß: Die Hardcopy-Routinen beginnen bei Zeile 4000. Die Maschinenroutinen (Listing 2 bis 5) dienen zum Bild laden, zur Directory-Anzeige, zum Farbwechsel, zum Invertieren und zum Kopieren des Basic- und Kernel-ROMs ins RAM.
(Matthias May/og)5 rem ********************************
6 rem *** (c) by matthias may ***
9 rem ********************************
10 ifs=0thens=1:load"print.1",8,1
12 ifs=1thens=2:load"print.2",8,1
14 ifs=2thens=3:load"print.3",8,1
16 ifs=3thens=4:load"print.4",8,1
17 ifs=4thens=5:load"print.5",8,1
18 poke45,1:poke46,64:poke55,0:poke56,128
20 clr
22 sys49664
24 print"{clr}"
26 f$(1)="schwarz":f$(2)="blau":f$(3)="rot"
28 sl$=chr$(13)+"{home}{down} color-print"+chr$(13)
30 sl$=sl$+" {SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}"+chr$(13)
32 sl$=sl$+"{down} (c) by matthias may"
40 print sl$
41 poke53280,11:poke53281,0
42 n$(1)=" diskwork ":n$(2)=" farbwechsel ":n$(3)=" bild zeigen "
43 n$(4)=" druck ":n$(5)=" ende "
45 f=1:s1=9:fm=5:z=6
50 print:print:print:print
55 print" {CBM-A}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-S} "
60 print" B diskwork B "
70 print" B farbwechsel B "
80 print" B bild zeigen B "
90 print" B druck B "
100 print" B ende B "
105 print" {CBM-Z}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-X} "
106 print" "
107 print" "
109 gosub 550
110 getx$:if x$="" then 110
120 if x$="{down}" then gosub500
130 if x$="{up}" then gosub600
135 if x$=chr$(13) then 150
140 goto 110
150 on f goto 1000,2000,3000,4000,10000
500 if f=fm then return
510 f=f+1
550 poke 214,s1+f-1:poke211,z:sys58640:printn$(f-1)
560 poke 214,s1+f :poke211,z:sys58640:print"{rvon}"n$(f)"{rvof}"
570 return
600 if f=1 then return
610 f=f-1
650 poke 214,s1+f+1:poke211,z:sys58640:printn$(f+1)
660 poke 214,s1+f :poke211,z:sys58640:print"{rvon}"n$(f)"{rvof}"
670 return
1000 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}"
1001 n$(1)=" directory "
1002 n$(2)=" load-pic "
1003 n$(3)=" menu "
1004 f=1:s1=13:fm=3:z=12
1010 print:print:print:print
1015 printtab(11)"{CBM-A}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-S}"
1020 printtab(11)"B directory B"
1030 printtab(11)"B load-pic B"
1035 print" B menu B "
1040 print" {$a0}{$a0}{$a0} {CBM-Z}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-X} "
1041 print" "
1042 print" "
1045 print" "
1046 print" "
1047 print" "
1048 print" "
1049 gosub 550
1050 getx$:if x$="" then 1050
1055 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
1060 if x$="{down}" then gosub 500
1070 if x$="{up}" then gosub 600
1075 if x$<>chr$(13) then 1050
1080 on f goto 1100,1200,40
1090 goto 1050
1100 poke59639,18:poke1,53
1105 print"{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-S}"
1106 print" B"
1110 sys49921
1120 getx$:if x$="" then 1120
1130 poke1,55:goto 1000
1200 print" {CBM-A}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-S}"
1210 print" Bload .................B{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}":t=0
1211 print" {CBM-Z}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-X}"
1215 poke214,17:poke211,15:sys58640
1220 poke198,0:wait 198,1:geta$
1230 if a$=chr$(20) then t=t-1:print"{left}.{left}";:goto 1220
1240 poke 36864+t,asc(a$):printa$;
1245 if a$<>chr$(13) then t=t+1:goto 1220
1250 if t>18 then t=18:print"{left}";:goto 1220
1260 poke36889,t
1270 sys36896
1280 open1,8,15
1290 get#1,a,b$,c,d:printa;b$;c;d
1295 close1
1300 goto 1000
2000 c0=0:c1=0:c2=0:c3=3:for u=1 to 3:print"{clr}"
2010 gosub 15000
2040 poke51238,c3:poke51237,c2:poke51236,c1:poke53281,c0
2045 sys32928
2050 getx$:if x$="" then 2050
2055 gosub 17000
2060 print"{clr}"
2070 print"{down}{down}{down}{down}{down}{down}{down}{down}"
2080 printtab(14)"{CBM-A}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-S}"
2090 printtab(14)"B B{left}{left}{left}{left}{left}{left}{left}{left}"f$(1)
2100 printtab(14)"B B{left}{left}{left}{left}{left}{left}{left}{left}"f$(2)
2110 printtab(14)"B B{left}{left}{left}{left}{left}{left}{left}{left}"f$(3)
2120 printtab(14)"{CBM-Z}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-X}"
2130 n$(1)=f$(1)
2140 n$(2)=f$(2)
2150 n$(3)=f$(3)
2160 f=1:fm=3:s1=10:z=15
2170 gosub 550
2180 getx$:if x$="" then 2180
2190 if x$="{down}" then gosub 500
2200 if x$="{up}" then gosub 600
2210 if x$<>chr$(13) then 2180
2220 a$(u)=f$(f)
2230 if c0=0 and c1=0 and c2=0 then c1=3:c3=0:goto 2250
2240 if c0=0 and c2=0 and c3=0 then c2=3:c1=0
2250 nextu
2260 f$(1)=a$(1)
2270 f$(2)=a$(2)
2280 f$(3)=a$(3)
2290 print"{clr}":goto 40
3000 print"{clr}"
3010 gosub 15000
3035 sys32928
3040 getx$:if x$="" then 3040
3041 if x$="{f1}" then poke 53281,(peek(53281)+1)and15:goto 3035
3042 if x$="{f3}" then poke 51236,(peek(51236)+1)and15:goto 3035
3043 if x$="{f5}" then poke 51237,(peek(51237)+1)and15:goto 3035
3044 if x$="{f7}" then poke 51238,(peek(51238)+1)and15:goto 3035
3046 if x$="i" then sys32768:forg=1 to 1000:next:sys32768:goto 3035
3050 gosub 17000
3080 print"{clr}":goto 40
4000 printtab(8)"{CBM-A}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-S}"
4005 printtab(8)"B invertiert j/n B"
4010 printtab(8)"{CBM-Z}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-X}"
4015 get x$:if x$="" then 4015
4020 if x$="j" then sys32768
4050 print"{home}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}"
4051 poke 59639,18:poke1,53
4052 open4,4:print#4,chr$(8);
4053 print"{CBM-A}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{CBM-S}"
4054 print"Bbitte blatt plazieren B"
4055 print"Bund markieren ! B"
4056 print"Bfarbe : B{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}"f$(1)
4057 print"B B"
4058 print"B B"
4059 print"B B{up}{up}{up}"
4060 getx$:ifx$="" then 4060
4061 print"Bstart ..."
4065 x=312
4070 p=8192
4090 for h=0 to 7
4100 a=peek(p+h+x):if a=0 then a=128:goto 4700
4101 if a=255 then 4700
4110 if (aand1)=1 and (aand2)=2 then 4115
4112 a=aand255-1-2
4115 if (aand4)=4 and (aand8)=8 then 4125
4120 a=aand255-4-8
4125 if (aand16)=16 and (aand32)=32 then4135
4130 a=aand255-16-32
4135 if (aand64)=64 and (aand128)=128 then 4150
4140 a=aand255-64-128
4150 a=int(a/2):a=aor128
4700 a$=a$+chr$(a)
4710 next h:print#4,a$;:a$=""
4720 p=p+320:if p<16384-192 then 4090
4730 print#4
4740 x=x-8
4750 if x>-8 then 4070
4800 print"Bbitte blatt plazieren B"
4810 print"Bfarbe : B{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}";f$(2)
4811 print"B B"
4812 print"B B"
4813 print"B B"
4814 print"B B{up}{up}{up}{up}"
4820 getx$:if x$="" then 4820
4830 print"Bstart ..."
4840 x=312
4850 p=8192
4990 for h=0 to 7
5000 a=peek(p+h+x):if a=0 then a=128:goto 5060
5001 if a=255 then a=128:goto5060
5010 if (aand1)=1 and (aand2)<>2 then a=a+2:goto 5012
5011 a=aand255-1-2
5012 if (aand4)=4 and (aand8)<>8 then a=a+8:goto 5014
5013 a=aand255-4-8
5014 if (aand16)=16 and (aand32)<>32 then a=a+32:goto 5016
5015 a=aand255-16-32
5016 if (aand64)=64 and (aand128)<>128 then a=a+128:goto 5050
5017 a=aand255-64-128
5050 a=int(a/2):a=aor128
5060 a$=a$+chr$(a)
5070 next h:print#4,a$;:a$=""
5080 p=p+320:if p<16384-192 then 4990
5090 print#4
5100 x=x-8
5110 if x>-8 then 4850
5120 print"Bbitte blatt plazieren B"
5130 print"Bfarbe : B{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}{left}"f$(3)
5131 print"B B"
5132 print"B B"
5133 print"B B"
5134 print"B B{up}{up}{up}{up}"
5140 getx$:if x$="" then 5140
5150 print"Bstart ..."
5160 x=312
5170 p=8192
5190 for h=0 to 7
5200 a=peek(p+h+x):if a=0 then a=128:goto 5260
5201 if a=255 then a=128:goto 5260
5210 if (aand2)=2 and (aand1)<>1 then a=a+1:goto 5212
5211 a=aand255-1-2
5212 if (aand8)=8 and (aand4)<>4 then a=a+4:goto 5214
5213 a=aand255-4-8
5214 if (aand32)=32 and (aand16)<>16 then a=a+16:goto 5216
5215 a=aand255-16-32
5216 if (aand128)=128 and (aand64)<>64 then a=a+64:goto 5250
5217 a=aand255-64-128
5250 a=int(a/2):a=aor128
5260 a$=a$+chr$(a)
5270 next h:print#4,a$;:a$=""
5280 p=p+320:if p<16384-192 then5190
5290 print#4
5300 x=x-8
5310 if x>-8 then 5170
5320 close4
5330 goto 24
10000 end
15000 poke 53265,peek(53265)or176
15010 poke 53270,peek(53270)or16
15020 poke 53272,peek(53272)or8
15030 return
17000 poke 53265,peek(53265)and159
17010 poke 53270,peek(53270)and255-16
17020 poke 53272,peek(53272)and255-8
17030 return
PROGRAMM : PRINT.1 C200 C24D ----------------------------------- C200 : A9 00 A2 00 A0 00 A9 00 03 C208 : 85 B7 A9 A0 85 B8 B1 B7 3C C210 : 91 B7 C8 98 C9 00 D0 F6 90 C218 : E6 B8 A5 B8 C9 C0 F0 05 4B C220 : A0 00 4C 0E C2 A9 00 A2 54 C228 : 00 A0 00 A9 00 85 B7 A9 0C C230 : E0 85 B8 B1 B7 91 B7 C8 B0 C238 : 98 C9 00 D0 F6 E6 B8 A5 A4 C240 : B8 C9 00 F0 05 A0 00 4C E9 C248 : 33 C2 60 00 C3 27
PROGRAMM : PRINT.2 C300 C361 ----------------------------------- C300 : 24 EA EA EA EA EA A9 01 60 C308 : 85 B7 A9 01 85 B8 A9 00 B8 C310 : 85 B9 A9 08 85 BA A9 00 B2 C318 : 85 BB A9 C3 85 BC 20 C0 9E C320 : FF A2 01 20 C6 FF 20 3E 1E C328 : F1 20 3E F1 20 3E F1 20 F3 C330 : 3E F1 20 3E F1 48 20 3E 95 C338 : F1 A8 68 AA 98 20 CD BD 2A C340 : 20 3E F1 20 CA F1 C9 00 63 C348 : D0 F6 A9 0D 20 CA F1 20 00 C350 : 3E F1 C9 00 D0 D9 20 CC EF C358 : FF A9 01 20 C3 FF 60 20 6E C360 : 90 E2
PROGRAMM : PRINT.3 9020 903D ----------------------------------- 9020 : A2 08 A0 00 20 BA FF A2 0C 9028 : 00 A0 90 AD 19 90 20 BD 64 9030 : FF A9 00 A2 00 A0 20 20 1E 9038 : D5 FF 60 00 80 C6
PROGRAMM : PRINT.4 8000 8026 ----------------------------------- 8000 : A9 00 85 FB A9 20 85 FC 36 8008 : A2 00 A0 00 A9 00 B1 FB 2C 8010 : 49 FF EA 91 FB C8 98 C9 42 8018 : 00 D0 F3 E6 FC A5 FC C9 DE 8020 : 40 D0 EB 60 A0 80 78
PROGRAMM : PRINT.5 80A0 80EA ----------------------------------- 80A0 : EA EA EA EA EA EA EA EA 9F 80A8 : EA EA EA AD 24 C8 0A 0A 3C 80B0 : 0A 0A 0D 25 C8 A2 00 86 56 80B8 : A4 86 A6 A2 04 86 A5 A2 EE 80C0 : D8 86 A7 AE 12 D0 E0 3A 3B 80C8 : D0 F9 AE 11 D0 30 F4 A0 06 80D0 : 00 A2 08 91 A4 48 AD 26 E5 80D8 : C8 91 A6 68 C8 D0 F4 E6 D4 80E0 : A5 E6 A7 E4 A5 D0 EC 60 D4 80E8 : 00 2A F8
Diesen Artikel als PDF herunterladen
Diesen Artikel auf Mastodon teilen